触发器 REFERENCING OLD AS OLD

太过爱你忘了你带给我的痛 2021-06-26 16:06 426阅读 0赞

REFERENCING OLD AS OLD NEW AS NEW FOR EACH Row

CREATE OR REPLACE TRIGGER TRI_DELETE_INFO  
          AFTER DELETE ON T_INFO_2012  
          REFERENCING OLD AS OLD NEW AS NEW  
          FOR EACH ROW  
        DECLARE  
          V_SQLERRM VARCHAR2(200);  
        BEGIN  
          DELETE FROM T_INFO_2013 WHERE CODE = :OLD.CODE;  
          --COMMIT; 触发器中不可以使用COMMIT; 
        EXCEPTION  
          WHEN OTHERS THEN  
            V_SQLERRM := '触发器 TRI_DELETE_INFO 出错：' || SQLERRM;  
            INSERT INTO PROCEDURE_LOG  
              (ERRMSG, ERRDATE)  
            VALUES  
              (V_SQLERRM, SYSDATE);  
        END;

1、`For each row`的意义是：在一次操作表的语句中，每操作成功一行就会触发一次；不写的话，表示是表级触发器，则无论操作多少行，都只触发一次；

2、`REFERENCING OLD` 和 `REFERENCING NEW` 的含义不同，具体取决于触发器是行级还是语句级触发器。对于行级触发器，`REFERENCING OLD` 子句允许引用更新或删除之前行中的值，`REFERENCING NEW` 子句允许引用已插入或更新的值。在 `BEFORE` 和 `AFTER` 触发器中可以引用 `OLD` 和 `NEW` 行。`REFERENCING NEW` 子句允许在插入或更新操作发生之前在 `BEFORE` 触发器中修改新行

3、`：NEW` 和`:OLD`使用方法和意义，`new` 只出现在`insert`和`update`时，`old`只出现在`update`和`delete`时。在`insert`时`new`表示新插入的行数据，`update`时`new`表示要替换的新数据、`old`表示要被更改的原来的数据行，`delete`时`old`表示要被删除的数据。  
`begin`前面出现的`new`，`old`不加冒号，`begin`和`end`之间出现的`new`和`old`都要在前面加上":"。

REFERENCING OLD AS OLD NEW AS NEW

这样写之后就可以在`begin end`直接直接使用别名来引用。

--------------------

## 触发器中的`:NEW` 和 `:OLD`的用法 ##

触发器是数据库发生某个操作时自动运行的一类的程序

用于保持数据的完整性或记录数据库操作信息方面

触发器不能够被直接调用，只能够在某些事件发生时被触发，也就是系统自动进行调用触发器的构建语法

create [or replace] trigger trigger_name 
    before|after 
    event1 [ or event2 or event3 …] 
    on table_name [for each row] 
    begin 
    statement; 
    … 
    end;
    
    CREATE [OR REPLACE] TRIGGER trigger_name
    {BEFORE | AFTER }
    {
       INSERT | DELETE | UPDATE [OF column [, column …]]}
    [OR {
       INSERT | DELETE | UPDATE [OF column [, column …]]}...]
    ON [schema.]table_name | [schema.]view_name
    [REFERENCING {OLD [AS] old | NEW [AS] new| PARENT as parent}]
    [FOR EACH ROW ]
    [WHEN condition]
    PL/SQL_BLOCK | CALL procedure_name;

通常是`insert`、`delete`或`update`等DML操作

### 说明： ###

`For each row`的意义是：在一次操作表的语句中，每操作成功一行就会触发一次；不写的话，表示是表级触发器，则无论操作多少行，都只触发一次；  
`When`条件的出现说明了，在DML操作的时候也许一定会触发触发器，但是触发器不一定会做实际的工作，比如`when` 后的条件不为真的时候，触发器只是简单地跳过了`PL/SQL`块.

触发器分为语句级触发器和行级触发器

*  语句级触发器是指每执行一条DML语句，该触发器就执行一次
 *  行级触发器是指每个DML操作影响几条记录，就会触发几次(for each row)
 *  行级触发器中由于涉及到了每条记录的数据变动，所以对于每条记录的数据来说就有新值和旧值之分 （语句级触发器不能用old和new)

### 关键字： ###

`:NEW` 和:`OLD`使用方法和意义，`new` 只出现在`insert`和`update`时，old只出现在update和delete时。在insert时new表示新插入的行数据，update时new表示要替换的新数据、old表示要被更改的原来的数据行，delete时old表示要被删除的数据。

##### 示例(1) #####

--记录操作数据库信息方面 
       --创建一个t_emp2_log表用于存储用户对emp2表所做的操作信息 
       create table t_emp2_log( 
              t_id  number(10) primary key,  --编号 
              t_date  date,     --修改日期 
              t_user  varchar2(20),  --操作用户 
              action varchar(20)   --该用户所做操作 
       );  
       --创建触发器t_emp2，当有用户对表emp2操作的时候，就会触发该触发器，记录改用户对表emp2所做的操作 
       create or replace trigger t_emp2 
              after update or delete or insert on emp2 
       begin 
              if updating then --当执行更新操作时执行 
                 insert into  t_emp2_log values(seq_t_emp2_log.nextval,sysdate, user,    'update'); 
              elsif deleting then --当执行删除操作时执行 
                 insert into t_emp2_log values(seq_t_emp2_log.nextval,sysdate, user,    'delete'); 
              elsif inserting then -- 当执行插入操作时 
                 insert into t_emp2_log values(seq_t_emp2_log.nextval, sysdate, user,           'inserting'); 
              end if;  
       end;

#### 示例(2) ####

--保持数据的完整性... 
     
       create table dept2 as select * from dept; 
       --当存在依赖表时，当主表的信息发生改变时，依赖表的相应信息也会发生改变 
       create or replace trigger tr_emp2 
       --当主表dept2发生改变时, 
              after update on dept2 for each row 
       begin   
       --依赖表也会发生相应的变化，以保持数据的完整性 
              update emp2 e set e.deptno = :NEW.deptno where  e.deptno = :OLD.deptno; 
       end;

#### 示例 (3) ####

两个表 字段完全一样  
例如：`emp` 表 `emp_ copy` 表  
要求 ：写一个触发器  
提示： :NEW :OLD  
功能实现  
当往`emp`表内添加字段且`deptno=10`的时候 往`emp_copy`表`copy`此数据

`emp`表更新数据时且修改`deptno=10` 的时候往`emp_copy`表copy此数据

--向emp_copy表copy新数据 
    --emp_copy可以存在相同的记录 
    CREATE OR replace TRIGGER tr_emp_copy
      AFTER INSERT OR UPDATE ON emp2
      FOR EACH ROW
    BEGIN
        IF inserting THEN
          IF :NEW.deptno = 10
              OR :OLD.deptno = 10 THEN
            INSERT INTO emp_copy
            VALUES     (:NEW.empno,
                        :NEW.ename,
                        :NEW.job,
                        :NEW.mgr,
                        :NEW.hiredate,
                        :NEW.sal,
                        :NEW.comm,
                        :NEW.deptno);
          END IF;
        ELSIF updating THEN
          IF :OLD.deptno = 10 THEN
            INSERT INTO emp_copy
            VALUES     (:NEW.empno,
                        :NEW.ename,
                        :NEW.job,
                        :NEW.mgr,
                        :NEW.hiredate,
                        :NEW.sal,
                        :NEW.comm,
                        :NEW.deptno);
          END IF;
        END IF;
    END;

--注意事项 
       /* 不管是after ,还是 before 在update , insert , delete 时，一定是在事务提交之后才会触发触发器 before 和after的区别: before：insert update 可以对new进行修改。 after :不能对new 进行修改 二者都不能对old 进行修改 */ 
     
       create or replace trigger tri_emp2 
              before update on dept2 for each row 
       begin 
              :NEW.deptno := 80; 
              update emp2 e set e.deptno = :NEW.deptno where e.deptno = :OLD.deptno; 
    end;