linux内核启动第一阶段分析

忘是亡心i 2022-03-26 14:07 311阅读 0赞

**linux内核启动第一阶段分析**

http://blog.csdn.net/aaronychen/article/details/2838341 
本文的很多内容是参考了网上某位大侠的文章写的<<>>，有些东西是直接从他那copy过来的。

本文从kernel的第一条指令开始分析,一直分析到进入start\_kernel()函数，也就是kernel启动的汇编部分，我们把它称之为第一部分，以后有时间在把启动的第二部分在分析一下。当前以linux-3.0内核版本来分析,本文中所有的代码前面都会加上行号以便于讲解。

由于启动部分有一些代码是平台相关的,虽然大部分的平台所[实现][Link 1]的功能都比较类似,但是为了更好的对code进行说明,对于平台相关的代码,我们选择smdk2410平台, CPU是s3c2410(arm核是arm920T)进行分析。  
   另外,本文是以未压缩的kernel来分析的.对于内核解压缩部分的code,在 arch/arm/boot/compressed中,本文不做讨论。

**一. 启动[条件][Link 2]**  
    通常从系统上电执行的boot loader的代码，而要从boot loader跳转到linux kernel的第一条指令处执行需要一些特定的条件。关于对boot loader的分析请看我的另一篇文档u-boot源码分析。  
    这里讨论下进入到linux kernel时必须具备的一些条件,这一般是boot loader在跳转到kernel之前要完成的:  
   1. CPU必须处于SVC(supervisor)模式,并且IRQ和FIQ中断都是禁止的;  
   2. MMU(内存[管理][Link 3]单元)必须是关闭的, 此时[虚拟][Link 4]地址就是物理地址;  
   3. 数据cache(Data cache)必须是关闭的  
   4. 指令cache(Instruction cache)可以是打开的,也可以是关闭的,这个没有强制要求;  
   5. CPU 通用寄存器0 (r0)必须是 0;  
   6. CPU 通用寄存器1 (r1)必须是 ARM Linux machine type (关于machine type, 我们后面会有讲解)  
   7. CPU 通用寄存器2 (r2) 必须是 kernel parameter list 的物理地址(parameter list 是由boot loader传递给kernel,用来描述设备信息属性的列表)。

更详细的关于启动arm linux之前要做哪些准备工作可以参考,“Booting ARM Linux"文档

** **

**二. starting kernel**

首先，我们先对几个重要的宏进行说明(我们针对有MMU的情况)：

<table style="border-bottom:medium none; border-left:medium none; border-collapse:collapse; border-top:medium none; border-right:medium none"> 
 <tbody> 
 <tr> 
 <td style="border-bottom:windowtext 1pt solid; border-left:windowtext 1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:windowtext 1pt solid; border-right:windowtext 1pt solid; padding-top:0cm"> 宏 </td> 
 <td style="border-bottom:windowtext 1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:windowtext 1pt solid; border-right:windowtext 1pt solid; padding-top:0cm"> 位置 </td> 
 <td style="border-bottom:windowtext 1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:windowtext 1pt solid; border-right:windowtext 1pt solid; padding-top:0cm"> 默认值 </td> 
 <td style="border-bottom:windowtext 1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:windowtext 1pt solid; border-right:windowtext 1pt solid; padding-top:0cm"> 说明 </td> 
 </tr> 
 <tr> 
 <td style="border-bottom:1pt solid; border-left:1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> KERNEL_RAM_ADDR </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> arch/arm/kernel/head.S +26 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 0xc0008000 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> kernel在RAM中的虚拟地址 </td> 
 </tr> 
 <tr> 
 <td style="border-bottom:1pt solid; border-left:1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> PAGE_OFFSET </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> include/asm-arm/memeory.h +50 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 0xc0000000 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 内核空间的起始虚拟地址 </td> 
 </tr> 
 <tr> 
 <td style="border-bottom:1pt solid; border-left:1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> TEXT_OFFSET </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> arch/arm/Makefile +131 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 0x00008000 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 内核在RAM中起始位置相对于 RAM起始地址的偏移 </td> 
 </tr> 
 <tr> 
 <td style="border-bottom:1pt solid; border-left:1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> TEXTADDR </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> arch/arm/kernel/head.S +49&nbsp; </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 0xc0008000&nbsp; </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> kernel的起始<a href="http://clk.qunsee.com/click/click.php?cpid=1021&amp;ads_id=1090&amp;pid=99005765&amp;cid=5794&amp;url=http%3A/www.chanet.com.cn/click.cgi%3Fa%3D59068%26d%3D41911%26u%3D%26e%3D&amp;k=%u865A%u62DF&amp;s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_2.html&amp;rn=672977&amp;v=1&amp;ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699.html&amp;province=%u4E0A%u6D77&amp;city=%u4E0A%u6D77" rel="nofollow">虚拟</a>地址 </td> 
 </tr> 
 <tr> 
 <td style="border-bottom:1pt solid; border-left:1pt solid; padding-bottom:0cm; padding-left:5.4pt; width:87pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> PHYS_OFFSET </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:152.4pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> include/asm-arm/arch- *** /memory.h </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:72pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> 平台相关 </td> 
 <td style="border-bottom:1pt solid; border-left:medium none; padding-bottom:0cm; padding-left:5.4pt; width:181.3pt; padding-right:5.4pt; border-top:medium none; border-right:1pt solid; padding-top:0cm"> RAM的起始物理地址，对于s3c2410来说在include/asm-arm/arch-s3c2410/memory.h下定义，值为0x30000000(ram接在片选6上) </td> 
 </tr> 
 </tbody> 
</table>

PLAT\_PHYS\_OFFSET     arch/arm/mach-s3c2410/include/mach/memory.h   值为0x30000000

arm linux boot的主线可以概括为以下几个步骤:  
1. 确定 processor type  
2. 确定 machine type  
3.检查参数合法性  
4. 创建页表    
5. 调用平台特定的\_\_cpu\_flush函数        (在struct proc\_info\_list中)                          
6. 开启mmu  
7. 切换数据  
最终跳转到start\_kernel (在\_\_switch\_data的结束的时候,调用了 b start\_kernel)

内核的入口是stext,这是在arch/arm/kernel/vmlinux.lds.S中定义的:  
        31 ENTRY(stext)  
    对于vmlinux.lds.S,这是ld script文件,此文件的格式和汇编及C程序都不同,本文不对ld script作过多的介绍,只对内核中用到的内容进行讲解,关于ld的详细内容可以参考ld.info  
    这里的ENTRY(stext) 表示程序的入口是在符号stext.  
    而符号stext是在arch/arm/kernel/head.S中定义的:

下面我们将arm linux boot的主要代码列出来进行一个概括的介绍,然后,我们会逐个的进行详细的讲解.

在arch/arm/kernel/head.S中 74 - 94 行,是arm linux boot的主代码:

74         \_\_HEAD 
 75 ENTRY(stext) 
 76         setmode PSR\_F\_BIT | PSR\_I\_BIT | SVC\_MODE, r9 @ 确保进入管理（svc)模式 
 77                                               @ 并且禁止中断 
 78         mrc     p15, 0, r9, c0, c0              @ 读取CPU ID，存入r9寄存器 
 79         bl      \_\_lookup\_processor\_type      @ 调用函数，输入参数r9=cpuid， 
                                                  @ 返回值r5=procinfo 
 80         movs    r10, r5                       @ 如果不支持当前CPU，则返回 (r5=0) 
 81  THUMB( it      eq )            @ force fixup-able long branch encoding 
 82         beq     \_\_error\_p                       @ 如果r5=0，则打印错误 
 
 
 
 
 83 
 84 \#ifndef CONFIG\_XIP\_KERNEL   
  @ 在调用\_\_enable\_mmu前使用的都是物理地址，而内核却是以虚拟地 址连接的，这里进行一次转换 
 85         adr     r3, 2f              ＠ r3＝ 第124行代码的物理地址 
 86         ldmia   r3, \{r4, r8\}         ＠ r4＝ 第124行代码的虚似地址，r8=PAGE\_OFFSET 
 87         sub     r4, r3, r4     @ (PHYS\_OFFSET - PAGE\_OFFSET)即物理地址与虚似地址差值 
 88         add     r8, r8, r4     @ PHYS\_OFFSET r8=PAGE\_OFFSET对应的物理地址 
 89 \#else 
 90         ldr     r8, =PLAT\_PHYS\_OFFSET    @ RAM的起始物理地址，值为0x30000000 
  91 \#endif 
 92 
 93         /\* 
 94          \* r1 = machine no, r2 = atags or dtb, 
 95          \* r8 = phys\_offset, r9 = cpuid, r10 = procinfo 
 96          \*/ 
 97         bl      \_\_vet\_atags  @ 检查bootloader传入的参数列表atags的合法性 
 98 \#ifdef CONFIG\_SMP\_ON\_UP   @ 2410没有定义 
 99         bl      \_\_fixup\_smp 
 100 \#endif 
 101 \#ifdef CONFIG\_ARM\_PATCH\_PHYS\_VIRT  @ 2410没有定义 
 102         bl      \_\_fixup\_pv\_table 
 103 \#endif 
 在2.6.39版本前，还增加了\_\_lookup\_machine\_type板级类型支持的检查，这里已经被取消，却增加了84－91行的代码，并且除第97行外，其它有些是没有的， 
 104         bl      \_\_create\_page\_tables  @创建初始页表 
 
105 
106         /\* 
107          \* The following calls CPU specific code in a position independent 
108          \* manner.  See arch/arm/mm/proc-\*.S for details.  r10 = base of 
109          \* xxx\_proc\_info structure selected by \_\_lookup\_processor\_type 
110          \* above.  On return, the CPU will be ready for the MMU to be 
111          \* turned on, and r0 will hold the CPU control register value. 
112          \*/ 
113         ldr     r13, =\_\_mmap\_switched    @ 将列表\_\_switch\_data存到r13中后面会跳到该列表出 
114                                          @ mmu has been enabled 
115         adr     lr, BSYM(1f)  @ return (PIC) address将程序段 \_\_enable\_mmu的地址存到 lr中。 
116         mov     r8, r4                          @ set TTBR1 to swapper\_pg\_dir 
    @ r10中存放的基地址是从\_\_lookup\_processor\_type中得到的，如上面movs r10, r5 
117  ARM(   add     pc, r10, \#PROCINFO\_INITFUNC     ) 
118  THUMB( add     r12, r10, \#PROCINFO\_INITFUNC    ) 
119  THUMB( mov     pc, r12                         ) 
120 1:      b       \_\_enable\_mmu 
121 ENDPROC(stext) 
122         .ltorg 
123 \#ifndef CONFIG\_XIP\_KERNEL 
124 2:      .long   .   ＠ "."号表示当前这行代码编译连接后的虚似地址 
125         .long   PAGE\_OFFSET 
126 \#endif 
 
78行: 通过cp15协处理器的c0寄存器来获得processor id的指令. 关于cp15的详细内容可参考相关的arm手册，也可直接参考s3c2410的data sheet。 
79行: 跳转到\_\_lookup\_processor\_type.在\_\_lookup\_processor\_type中,会把找到匹配的processor type 对象存储在r5中。 
80,82行: 判断r5中的processor type是否是0,如果是0,说明系统中没找到匹配当前processor type的对象， 则跳转到\_\_error\_p(出错)。系统中会预先定义本系统支持的processor type 对象集。 
    \_\_lookup\_processor\_type 函数主要是根据从cpu中获得的processor id和系统中预先定义的本系统能支持的proc\_info集进行匹配,看系统能否支持当前的processor, 并将匹配到的proc\_info的基地址存到r5中, 0表示没有找到对应的processor type. 
 
1、检查内核是否支持该架构 
下面我们分析\_\_lookup\_processor\_type函数。 
\_\_lookup\_processor\_type 
/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/ 
在讲解该程序段之前先来看一些相关知识。 
内核做支持的每一种CPU 类型都由结构体 proc\_info\_list来描述。 
该结构体在文件arch/arm/include/asm/procinfo.h 中定义： 
struct proc\_info\_list \{ 
        unsigned int            cpu\_val; 
        unsigned int            cpu\_mask; 
        unsigned long           \_\_cpu\_mm\_mmu\_flags;     /\* used by head.S \*/ 
        unsigned long           \_\_cpu\_io\_mmu\_flags;     /\* used by head.S \*/ 
        unsigned long           \_\_cpu\_flush;            /\* used by head.S \*/ 
        const char              \*arch\_name; 
        const char              \*elf\_name; 
        unsigned int            elf\_hwcap; 
        const char              \*cpu\_name; 
        struct processor        \*proc; 
        struct cpu\_tlb\_fns      \*tlb; 
        struct cpu\_user\_fns     \*user; 
        struct cpu\_cache\_fns    \*cache; 
\}; 
对于 arm920 来说，其对应结构体在文件arch/arm/mm/proc-arm920.S 中初始化。 
493         .section ".proc.info.init", \#alloc, \#execinstr 
494 
495         .type   \_\_arm920\_proc\_info,\#object 
496 \_\_arm920\_proc\_info: 
497         .long   0x41009200 
498         .long   0xff00fff0 
499         .long   PMD\_TYPE\_SECT | \\ 
500                 PMD\_SECT\_BUFFERABLE | \\ 
501                 PMD\_SECT\_CACHEABLE | \\ 
502                 PMD\_BIT4 | \\ 
503                 PMD\_SECT\_AP\_WRITE | \\ 
504                 PMD\_SECT\_AP\_READ 
505         .long   PMD\_TYPE\_SECT | \\ 
506                 PMD\_BIT4 | \\ 
507                 PMD\_SECT\_AP\_WRITE | \\ 
508                 PMD\_SECT\_AP\_READ 
509         b       \_\_arm920\_setup 
510         .long   cpu\_arch\_name 
.section ".proc.info.init"表明了该结构在编译后存放的位置。我们可以看到 \_\_arm920\_proc\_info 被放到了".proc.info.init"段中.对照struct proc\_info\_list,我们可以看到 \_\_cpu\_flush的定义是在509行,即\_\_arm920\_setup.(我们将在"4. 调用平台特定的\_\_cpu\_flush函数"一节中详细分析这部分的内容.) 
在链接文件 arch/arm/kernel/vmlinux.lds 中：  \* SECTIONS 
SECTIONS 
\{ 
 . = 0xC0000000 + 0x00108000; 
 .init : \{ /\* Init code and data                \*/ 
  \_stext = .; 
  \_sinittext = .; 
   \*(.head.text) 
   \*(.init.text) \*(.cpuinit.text) \*(.meminit.text) 
 
  \_einittext = .; 
  \_\_proc\_info\_begin = .; \*(.proc.info.init) \_\_proc\_info\_end = .; 
  \_\_arch\_info\_begin = .; 
   \*(.arch.info.init) 
  \_\_arch\_info\_end = .; 
  \_\_tagtable\_begin = .; 
   \*(.taglist.init) 
  \_\_tagtable\_end = .; 
  \_\_pv\_table\_begin = .; 
   \*(.pv\_table) 
  \_\_pv\_table\_end = .; 
所有CPU类型对应的被初始化的 proc\_info\_list结构体都放在 \_\_proc\_info\_begin和\_\_proc\_info\_end之间。 
下面我们分析\_\_lookup\_processor\_type函数。在arch/arm/kernel/head-common.S中: 
120 /\* 
121  \* This provides a C-API version of \_\_lookup\_processor\_type 
122  \*/ 
123 ENTRY(lookup\_processor\_type) 
124         stmfd   sp!, \{r4 - r6, r9, lr\} 
125         mov     r9, r0 
126         bl      \_\_lookup\_processor\_type 
127         mov     r0, r5 
128         ldmfd   sp!, \{r4 - r6, r9, pc\} 
129 ENDPROC(lookup\_processor\_type) 
131 /\* 
132  \* Read processor ID register (CP\#15, CR0), and look up in the linker-built 
133  \* supported processor list.  Note that we can't use the absolute addresses 
134  \* for the \_\_proc\_info lists since we aren't running with the MMU on 
135  \* (and therefore, we are not in the correct address space).  We have to 
136  \* calculate the offset. 
137  \* 
138  \*      r9 = cpuid 
139  \* Returns: 
140  \*      r3, r4, r6 corrupted 
141  \*      r5 = proc\_info pointer in physical address space 
142  \*      r9 = cpuid (preserved) 
143  \*/ 
144         \_\_CPUINIT 
145 \_\_lookup\_processor\_type: 
146         adr     r3, \_\_lookup\_processor\_type\_data ＠r3存储的是物理地址（由于没有启用 mmu ，所以当前肯定是物理地址） 
147         ldmia   r3, \{r4 - r6\} 
148         sub     r3, r3, r4                      @ 得到虚拟地址和物理地址之间的offset 
149         add     r5, r5, r3                      @ 利用offset ，将 r5 和 r6 中保存的虚拟地址 
150         add     r6, r6, r3                      @ 转变为物理地址 
151 1:      ldmia   r5, \{r3, r4\}                    @ 对照struct proc\_info\_list,可以得知,这句是将当前proc\_info的cpu\_val和cpu\_mask分别存到r3, r4中 
152         and     r4, r4, r9                   @ r9 中存放的是先前读出的 processor ID ，     此处屏蔽不需要的位。 
  
153         teq     r3, r4  查看代码和CPU 硬件是否匹配 
154         beq     2f      如果匹配成功就返回 
155         add     r5, r5, \#PROC\_INFO\_SZ           @ PROC\_INFO\_SZ (proc\_info\_list 结构的长度，在这等于 48) ， 跳到下一个 proc\_info\_list 处 
156         cmp     r5, r6 
157         blo     1b 
如果没有匹配成功就将r5清零，如果匹配成功r5中放的是该CPU类型对应的结构体// proc\_info\_list 的基地址。 
158         mov     r5, \#0                          @ unknown processor 
159 2:      mov     pc, lr    子程序返回。 
160 ENDPROC(\_\_lookup\_processor\_type) 
162 /\* 
163  \* Look in <asm/procinfo.h> for information about the \_\_proc\_info structure. 
164  \*/ 
165         .align  2 
166         .type   \_\_lookup\_processor\_type\_data, %object 
167 \_\_lookup\_processor\_type\_data: 
168         .long   . 
169         .long   \_\_proc\_info\_begin 
170         .long   \_\_proc\_info\_end 
171         .size   \_\_lookup\_processor\_type\_data, . - \_\_lookup\_processor\_type\_data 
     166,167 行是数据域定义，将\_\_lookup\_processor\_type\_data设置为当前代码编译后连接后的虚拟地址，第146行取地址指令,这里将\_\_lookup\_processor\_type\_data地址存入r3. 这里需要注意的是,adr指令取址,获得的是基于pc的一个地址,要格外注意,这个地址是"运行时地址",由于此时MMU还没有打开,也可以理解成物理地址(实地址).(详细内容可参考arm指令手册) 
147行: 因为r3中的地址是168行的位置的物理地址,因而执行完后: 
        r4存的是168处的虚拟地址. 
        r5存的是169行符号 \_\_proc\_info\_begin的地址 
        r6存的是170行符号 \_\_proc\_info\_end的地址 
    这里需要注意链接地址和运行时地址的区别. r3存储的是运行时地址(物理地址),而r6中存储的是链接地址(虚拟地址). 
 
     \_\_proc\_info\_begin和\_\_proc\_info\_end是在arch/arm/kernel/vmlinux.lds.S中:

148行: 从上面的分析我们可以知道r3中存储的是168行处的物理地址,而r4存储的是168处的[虚拟][Link 5]地址,这一行是计算当前程序运行的物理地址和虚拟地址的差值,将其保存到r3中.  
149行: 将r5存储的虚拟地址(\_\_proc\_info\_begin)转换成物理地址  
150行: 将r6存储的虚拟地址(\_\_proc\_info\_end)转换成物理地址  
151行: 对照struct proc\_info\_list,可以得知,这句是将当前proc\_info的cpu\_val和cpu\_mask分别存到r3, r4中  
152行: r9中存储了processor id,与r4的cpu\_mask进行逻辑与得到我们需要的值  
153行: 将152行中得到的值与r3中的cpu\_val进行比较  
154行: 如果相等,说明我们找到了对应的processor type,跳到160行,[返回][Link 6]  
155行: 如果不相等, 将r5指向下一个proc\_info,

156 行: 和r6比较,检查是否到了\_\_proc\_info\_end. 
157行: 如果没有到\_\_proc\_info\_end,表明还有proc\_info配置,返回151行继续查找 
158行: 执行到这里,说明所有的proc\_info都匹配过了,但是没有[找到][Link 7]匹配的,将r5设置成0(unknown processor) 
159行: 返回 
 
2、检查bootloader传入的参数列表atags的合法性 
\_\_vet\_atags // 
/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/ 
关于参数链表： 
内核参数链表的格式和说明可以从内核源代码目录树中的arch/arm/include/asm/setup.h中找到，参数链表必须以ATAG\_CORE  开始，以 ATAG\_NONE 结束。这里的  ATAG\_CORE ，ATAG\_NONE是各个参数的标记，本身是一个 32 位值，例如： ATAG\_CORE=0x54410001 。其它的参数标记还包括： ATAG\_MEM ，  ATAG\_INITRD  ，  ATAG\_RAMDISK  ，ATAG\_COMDLINE 等。每个参数标记就代表一个参数结构体，由各个参数结构体构成了参数链表。参数结构体的定义如下：  
struct tag \{ 
    struct tag\_header hdr; 
    union \{ 
        struct tag\_core        core; 
        struct tag\_mem32    mem; 
        struct tag\_videotext    videotext; 
        struct tag\_ramdisk    ramdisk; 
        struct tag\_initrd    initrd; 
        struct tag\_serialnr    serialnr; 
        struct tag\_revision    revision; 
        struct tag\_videolfb    videolfb; 
        struct tag\_cmdline    cmdline; 
 
        /\* 
         \* Acorn specific 
         \*/ 
        struct tag\_acorn    acorn; 
 
        /\* 
         \* DC21285 specific 
         \*/ 
        struct tag\_memclk    memclk; 
    \} u; 
\}; 
参数结构体包括两个部分，一个是 tag\_header 结构体 , 一个是 u 联合体。 
tag\_header结构体的定义如下： 
struct tag\_header \{ 
    \_\_u32 size; 
    \_\_u32 tag; 
\}; 
其中 size ：表示整个tag结构体的大小 ( 用字的个数来表示，而不是字节的个数 ) ，等于tag\_header的大小加上u联合体的大小，例如，参数结构体 ATAG\_CORE的 size(sizeof(tag->tag\_header)+sizeof(tag->u.core))>>2，一般通过函数  tag\_size(struct \* tag\_xxx)来获得每个参数结构体的 size 。其中  tag ：表示整个  tag  结构体的标记，如： ATAG\_CORE等。 
\_\_vet\_atags函数源码在arch/arm/kernel/head-common.S中定义如下： 
 14 \#define ATAG\_CORE 0x54410001 
 15 \#define ATAG\_CORE\_SIZE ((2\*4 + 3\*4) >> 2) 
 16 \#define ATAG\_CORE\_SIZE\_EMPTY ((2\*4) >> 2) 
 18 \#ifdef CONFIG\_CPU\_BIG\_ENDIAN 
 19 \#define OF\_DT\_MAGIC 0xd00dfeed 
 20 \#else 
 21 \#define OF\_DT\_MAGIC 0xedfe0dd0 /\* 0xd00dfeed in big-endian \*/ 
 22 \#endif 
 
 46 \_\_vet\_atags: 
 47         tst     r2, \#0x3       ＠r2指向该参数链表的起始位置，此处判断它是否字对齐 
 48         bne     1f 
 49 
 50         ldr     r5, \[r2, \#0\]     ＠获取第一个 tag 结构的 size 
 51 \#ifdef CONFIG\_OF\_FLATTREE 
 52         ldr     r6, =OF\_DT\_MAGIC                @ is it a DTB? 
 53         cmp     r5, r6 
 54         beq     2f 
 55 \#endif 
 56         cmp     r5, \#ATAG\_CORE\_SIZE    @ is first tag ATAG\_CORE?判断该 tag 的长度是否合法 
 57         cmpne   r5, \#ATAG\_CORE\_SIZE\_EMPTY 
 58         bne     1f 
 59         ldr     r5, \[r2, \#4\]     ＠获取第一个 tag 结构体的标记 
 60         ldr     r6, =ATAG\_CORE 
 61         cmp     r5, r6     ＠判断第一个 tag 结构体的标记是不是 ATAG\_CORE 
 62         bne     1f 
 63 
 64 2:      mov     pc, lr      @ atag/dtb pointer is ok 正常退出 
 65 
 66 1:      mov     r2, \#0 
 67         mov     pc, lr     ＠参数连表不正确 
 68 ENDPROC(\_\_vet\_atags) 
 
3、创建一级页表 
通过前面的两步,我们已经确定了processor type.和参数列表atags的合法性 
此时,一些特定寄存器的值如下所示: 
r8 = PHYS\_OFFSET       (r8=PAGE\_OFFSET对应的物理地址) 
r9 = cpu id             (通过cp15协处理器获得的cpu id) 
r10 = procinfo          (struct proc\_info\_list的基地址) 
 
创建页表是通过函数 \_\_create\_page\_tables 来实现的. 
这里,我们使用的是arm的L1主页表,L1主页表也称为段页表(section page table)， L1 主页表将4 GB 的地址空间分成若干个1 MB的段(section),因此L1页表包含4096个页表项(section entry). 每个页表项是32 bits(4 bytes)因而L1主页表占用 4096 \*4 = 16k的内存空间. 
 
对于ARM920,其L1 section entry的格式为可参考arm920t TRM): 
[![1.JPG][]][1.JPG] 
B – Write Buffer Bit 
C – Cache Bit 
Data Cache     Data Cache     
Cache Bit     Buffer Bit     Page attribute 
0                0            not cached, not buffered 
0                1            not cached, buffered 
1                0            cached, writethrough 
1                1            cached, writeback 
它的地址翻译过程如下： 
[![2.JPG][]][2.JPG] 
下面我们来分析 \_\_create\_page\_tables 函数: 
 
在 arch/arm/kernel/head.S 中: 
 36 \#define KERNEL\_RAM\_VADDR        (PAGE\_OFFSET + TEXT\_OFFSET) 
 37 \#if (KERNEL\_RAM\_VADDR & 0xffff) != 0x8000 
 38 \#error KERNEL\_RAM\_VADDR must start at 0xXXXX8000 
 39 \#endif 
 40 
 44         .macro  pgtbl, rd, phys 
 45         add     \\rd, \\phys, \#TEXT\_OFFSET - 0x4000 
 46         .endm 
 
 48 \#ifdef CONFIG\_XIP\_KERNEL 
 49 \#define KERNEL\_START    XIP\_VIRT\_ADDR(CONFIG\_XIP\_PHYS\_ADDR) 
 50 \#define KERNEL\_END      \_edata\_loc 
 51 \#else 
 52 \#define KERNEL\_START    KERNEL\_RAM\_VADDR 
 53 \#define KERNEL\_END      \_end 
 54 \#endif 
 
139 \_\_create\_page\_tables: 
140         pgtbl   r4, r8            @ page table address通过宏 pgtbl 将r4设置成页表的基地址(物理地址)，宏pgtbl 在 arch/arm/kernel/head.S第44定义，可以看到,页表是位于 TEXT\_OFFSET下面 16k 的位置，r4 =  0x30004000 这是转换表的物理基地址，最终将写入CP15 的寄存器 2 ， C2 。这个值必须是 16K 对齐的。 
141 
142         /\*下面从145行 - 153行, 是将这16k 的页表清0. 
143          \* Clear the 16K level 1 swapper page table 
144          \*/ 
145         mov     r0, r4    ＠将页表基地址存在r0中 
146         mov     r3, \#0    ＠ 将 r3 置成0 
147         add     r6, r0, \#0x4000  ＠r6  = 页表基地址 + 16k, 可以看到这是页表的尾地址 
   ＠148 - 153行: 循环,从 r0 到 r6 将这16k页表用0填充. 
148 1:      str     r3, \[r0\], \#4 
149         str     r3, \[r0\], \#4 
150         str     r3, \[r0\], \#4 
151         str     r3, \[r0\], \#4 
152         teq     r0, r6 
153         bne     1b 
154 
155         ldr     r7, \[r10, \#PROCINFO\_MM\_MMUFLAGS\] @ mm\_mmuflags 
从 proc\_info\_list结构中获取字段 \_\_cpu\_mm\_mmu\_flags ，该字段包含了存储空间访问权限等,并存储到 r7中,此处指令执行之后 r7=0x00000c1e,(宏PROCINFO\_MM\_MMUFLAGS是在arch/arm/kernel/asm-offsets.c中定义) 
156 
157         /\* 
158          \* Create identity mapping to cater for \_\_enable\_mmu. 
159          \* This identity mapping will be removed by paging\_init(). 
160          \*/ 
161         adr     r0, \_\_enable\_mmu\_loc 
162         ldmia   r0, \{r3, r5, r6\} 
163         sub     r0, r0, r3                      @ virt->phys offset 
164         add     r5, r5, r0                      @ phys \_\_enable\_mmu 
165         add     r6, r6, r0                      @ phys \_\_enable\_mmu\_end 
166         mov     r5, r5, lsr \#20  ＠通过R5值的高12位(右移20位),得到kernel的section基址(从上面的图可以看出),并存储到r6中.因为当前是通过运行时地址得到的kernel的section地址,因而是物理地址. 
167         mov     r6, r6, lsr \#20  
168 
169 1:      orr     r3, r7, r5, lsl \#20             @ r3 = r7 | (r5 << 20);flags + kernel base得到页表中需要设置的值. 
170         str     r3, \[r4, r5, lsl \#2\]            @ identity mapping 
设置页表: mem\[r4 + r5 \* 4\] = r3,这里,因为页表的每一项是32 bits(4 bytes),所以要乘以4(<<2). 
上面这二行,设置了kernel当前运行的section(物理地址所在的page entry)的页表项 
171         teq     r5, r6 
172         addne   r5, r5, \#1                      @ next section 
173         bne     1b 
174 
175         /\* 
176          \* Now setup the pagetables for our kernel direct 
177          \* mapped region. 
178          \*/ 
MMU是通过 C2 中基地址（高 18 位）与虚拟地址的高 12 位组合成物理地址，在转换表中查找地址条目。 R4 中存放的就是这个基地址 0x30004000 。下面通过两次获取虚拟地址KERNEL\_START的高 12 位。 KERNEL\_START 是内核存放的起始地址，为 0X30008000 。 
179         mov     r3, pc 
180         mov     r3, r3, lsr \#20 
181         orr     r3, r7, r3, lsl \#20 
182         add     r0, r4,  \#(KERNEL\_START & 0xff000000) >> 18  ＠r0 = 0x30007000 
183         str     r3, \[r0, \#(KERNEL\_START & 0x00f00000) >> 18\]!  ＠r0 存放的是转换表的起始位置 
184         ldr     r6, =(KERNEL\_END - 1)  ＠获取内核的尾部虚拟地址存于 r6 中 
185         add     r0, r0, \#4  ＠第一个地址条目存放在 0x30007004 处，以后一次递增 
186         add     r6, r4, r6, lsr \#18  ＠计算最后一个地址条目存放的位置 
187 1:      cmp     r0, r6  ＠填充这之间的地址条目 
188         add     r3, r3, \#1 << 20  ＠每一个地址条目代表了 1MB 空间的地址映射。物理地址将从 0x30100000开始映射。0X30000000 开始的 1MB 空间将在下面映射。 
189         strls   r3, \[r0\], \#4 
190         bls     1b 
182--190行: KERNEL\_START是内核的起始虚拟地址(0xc0008000), 这几行是设置kernel起始4M虚拟地址的页表项，每次循环设置1M。 
191 
192 \#ifdef CONFIG\_XIP\_KERNEL 
193         /\*如果是 XIP 就进行以下映射，这只是将内核代码存储的空间重新映射 
194          \* Map some ram to cover our .data and .bss areas. 
195          \*/ 
196         add     r3, r8, \#TEXT\_OFFSET 
197         orr     r3, r3, r7 
198         add     r0, r4,  \#(KERNEL\_RAM\_VADDR & 0xff000000) >> 18 
199         str     r3, \[r0, \#(KERNEL\_RAM\_VADDR & 0x00f00000) >> 18\]! 
200         ldr     r6, =(\_end - 1) 
201         add     r0, r0, \#4 
202         add     r6, r4, r6, lsr \#18 
203 1:      cmp     r0, r6 
204         add     r3, r3, \#1 << 20 
205         strls   r3, \[r0\], \#4 
206         bls     1b 
207 \#endif 
208 
209         /\* 
210          \* Then map boot params address in r2 or 
211          \* the first 1MB of ram if boot params address is not specified. 
212          \*/ 
213         mov     r0, r2, lsr \#20 
214         movs    r0, r0, lsl \#20 
215         moveq   r0, r8 
216         sub     r3, r0, r8 
217         add     r3, r3, \#PAGE\_OFFSET 
218         add     r3, r4, r3, lsr \#18 
219         orr     r6, r7, r0   ＠r7中存储的是mmu flags, 逻辑或上RAM的起始物理地址,得到RAM第一个MB页表项的值. 
220         str     r6, \[r3\]           ＠设置RAM的第一个MB虚拟地址的页表. 
上面这几行是用来设置RAM中第一兆虚拟地址的页表. 之所以要设置这个页表项的原因是RAM的第一兆内存中可能存储着boot params. 
221 
222 \#ifdef CONFIG\_DEBUG\_LL  下面是为了调试而做的相关映射，跳过。 
223 \#ifndef CONFIG\_DEBUG\_ICEDCC 
224         /\* 
225          \* Map in IO space for serial debugging. 
226          \* This allows debug messages to be output 
227          \* via a serial console before paging\_init. 
228          \*/ 
229         addruart r7, r3 
230 
231         mov     r3, r3, lsr \#20 
232         mov     r3, r3, lsl \#2 
233 
234         add     r0, r4, r3 
235         rsb     r3, r3, \#0x4000                 @ PTRS\_PER\_PGD\*sizeof(long) 
236         cmp     r3, \#0x0800                     @ limit to 512MB 
237         movhi   r3, \#0x0800 
238         add     r6, r0, r3 
239         mov     r3, r7, lsr \#20 
240         ldr     r7, \[r10, \#PROCINFO\_IO\_MMUFLAGS\] @ io\_mmuflags 
241         orr     r3, r7, r3, lsl \#20 
242 1:      str     r3, \[r0\], \#4 
243         add     r3, r3, \#1 << 20 
244         teq     r0, r6 
245         bne     1b 
246 
247 \#else /\* CONFIG\_DEBUG\_ICEDCC \*/ 
248         /\* we don't need any serial debugging mappings for ICEDCC \*/ 
249         ldr     r7, \[r10, \#PROCINFO\_IO\_MMUFLAGS\] @ io\_mmuflags 
250 \#endif /\* !CONFIG\_DEBUG\_ICEDCC \*/ 
251 
252 \#if defined(CONFIG\_ARCH\_NETWINDER) || defined(CONFIG\_ARCH\_CATS) 
253         /\* 
254          \* If we're using the NetWinder or CATS, we also need to map 
255          \* in the 16550-type serial port for the debug messages 
256          \*/ 
257         add     r0, r4, \#0xff000000 >> 18 
258         orr     r3, r7, \#0x7c000000 
259         str     r3, \[r0\] 
260 \#endif 
261 \#ifdef CONFIG\_ARCH\_RPC 
262         /\* 
263          \* Map in screen at 0x02000000 & SCREEN2\_BASE 
264          \* Similar reasons here - for debug.  This is 
265          \* only for Acorn RiscPC architectures. 
266          \*/ 
267         add     r0, r4, \#0x02000000 >> 18 
268         orr     r3, r7, \#0x02000000 
269         str     r3, \[r0\] 
270         add     r0, r4, \#0xd8000000 >> 18 
271         str     r3, \[r0\] 
272 \#endif 
273 \#endif 
274         mov     pc, lr   ＠子程序返回。 
275 ENDPROC(\_\_create\_page\_tables) 
276         .ltorg 
277         .align 
278 \_\_enable\_mmu\_loc: 
279         .long   . 
280         .long   \_\_enable\_mmu 
281         .long   \_\_enable\_mmu\_end 
这样,kernel所需要的基本的页表我们都设置完了, 如下图所示: 
[![3.JPG][]][3.JPG] 
4、调用平台特定的 \_\_cpu\_flush 函数 
当 \_\_create\_page\_tables 返回之后 
 
此时,一些特定寄存器的值如下所示: 
r4 = pgtbl              (page table 的物理基地址) 
r8 = PHYS\_OFFSET       (r8=PAGE\_OFFSET对应的物理地址) 
r9 = cpu id             (通过cp15协处理器获得的cpu id) 
r10 = procinfo          (struct proc\_info\_list的基地址) 
 
在我们需要开启mmu之前,做一些必须的工作:清除ICache, 清除 DCache, 清除 Writebuffer, 清除TLB等.这些一般是通过cp15协处理器来实现的,并且是平台相关的. 这就是\_\_cpu\_flush 需要做的工作 
 
在 arch/arm/kernel/head.S中 
113         ldr     r13, =\_\_mmap\_switched           @ address to jump to after 
114                                                 @ mmu has been enabled 
115         adr     lr, BSYM(1f)                    @ return (PIC) address 
116         mov     r8, r4                          @ set TTBR1 to swapper\_pg\_di    r 
117  ARM(   add     pc, r10, \#PROCINFO\_INITFUNC     ) 
118  THUMB( add     r12, r10, \#PROCINFO\_INITFUNC    ) 
119  THUMB( mov     pc, r12                         ) 
120 1:      b       \_\_enable\_mmu 
第113行: 将r13设置为 \_\_mmap\_switched的地址 
第115行: 将lr设置为 \_\_enable\_mmu 的地址 
第117行: r10存储的是procinfo的基地址, PROCINFO\_INITFUNC是在 arch/arm/kernel/asm-offsets.c 中110行定义. 该行将pc设为 proc\_info\_list的 \_\_cpu\_flush 函数的地址,（DEFINE(PROCINFO\_INITFUNC,     offsetof(struct proc\_info\_list, \_\_cpu\_flush)）即下面跳转到该函数.在分析 \_\_lookup\_processor\_type 的时候,我们已经知道,对于 ARM920t 来说,其\_\_cpu\_flush指向的是函数 \_\_arm920\_setup 
 
下面我们来分析函数 \_\_arm920\_setup        
在 arch/arm/mm/proc-arm920.S 中: 
424         \_\_CPUINIT 
425 
426         .type   \_\_arm920\_setup, \#function  ＠定义\_\_arm920\_setup函数。 
427 \_\_arm920\_setup:            ＠定义\_\_arm920\_setup函数。 
428         mov     r0, \#0      ＠设置r0为0。 
429         mcr     p15, 0, r0, c7, c7       ＠使数据cahche, 指令cache无效。 
430         mcr     p15, 0, r0, c7, c10, 4    ＠使write buffer无效。 
431 \#ifdef CONFIG\_MMU 
432         mcr     p15, 0, r0, c8, c7       ＠使数据TLB,指令TLB无效。 
433 \#endif 
434         adr     r5, arm920\_crval       ＠获取arm920\_crval的地址，并存入r5。 
435         ldmia   r5, \{r5, r6\}            ＠获取arm920\_crval地址处的连续8字节分别存入r5,r6。 
436         mrc     p15, 0, r0, c1, c0       ＠获取CP15下控制寄存器的值，并存入r0。 
437         bic     r0, r0, r5    ＠通过查看arm920\_crval的值可知该行是清除r0中相关位，为以后对这些位的赋值做准备。 
438         orr     r0, r0, r6    ＠设置r0中的相关位，即为mmu做相应设置。 
439         mov     pc, lr 
440         .size   \_\_arm920\_setup, . - \_\_arm920\_setup 
 
第434行arm920\_crval在arch/arm/mm/proc-arm920t.c: 
448         .type   arm920\_crval, \#object 
449 arm920\_crval: 
450         crval   clear=0x00003f3f, mmuset=0x00003135, ucset=0x00001130 
由此可知，r5 = 0x00003f3f, r6 = 0x00003135 
 
5. 开启mmu 
   开启mmu是由函数 \_\_enable\_mmu 实现的. 
 
   在进入 \_\_enable\_mmu 的时候, r0中已经存放了控制寄存器c1的一些配置(在上一步中进行的设置), 但是并没有真正的打开mmu, 在 \_\_enable\_mmu 中,我们将打开mmu. 
 
   此时,一些特定寄存器的值如下所示: 
r0 = c1 parameters      (用来配置控制寄存器的参数)        
r4 = pgtbl              (page table 的物理基地址) 
r8 = machine info       (struct machine\_desc的基地址) 
r9 = cpu id             (通过cp15协处理器获得的cpu id) 
r10 = procinfo          (struct proc\_info\_list的基地址) 
 
在 arch/arm/kernel/head.S 中: 
使能MMU之前设置一些普通bit，装载页表地址以及域访问寄存器 
350 \_\_enable\_mmu: 
351 \#ifdef CONFIG\_ALIGNMENT\_TRAP  @根据配置使能或禁止地址对齐错误检测。 
352         orr     r0, r0, \#CR\_A 
353 \#else 
354         bic     r0, r0, \#CR\_A   
355 \#endif 
356 \#ifdef CONFIG\_CPU\_DCACHE\_DISABLE  @根据配置使能或禁止数据cache。 
357         bic     r0, r0, \#CR\_C 
358 \#endif 
359 \#ifdef CONFIG\_CPU\_BPREDICT\_DISABLE 
360         bic     r0, r0, \#CR\_Z 
361 \#endif 
362 \#ifdef CONFIG\_CPU\_ICACHE\_DISABLE  @根据配置使能或禁止指令cache。 
363         bic     r0, r0, \#CR\_I 
364 \#endif 
365         mov     r5, \#(domain\_val(DOMAIN\_USER, DOMAIN\_MANAGER) | \\ 
366                       domain\_val(DOMAIN\_KERNEL, DOMAIN\_MANAGER) | \\ 
367                       domain\_val(DOMAIN\_TABLE, DOMAIN\_MANAGER) | \\ 
368                       domain\_val(DOMAIN\_IO, DOMAIN\_CLIENT))  @配置相应的访问权限并存入r5。 
369         mcr     p15, 0, r5, c3, c0, 0    @ load domain access register把访问权限写入CP15协处理器。设置域访问寄存器C3 
370         mcr     p15, 0, r4, c2, c0, 0    @ load page table pointer把页表地址写入CP15协处理器。设置页表地址c2 
371         b       \_\_turn\_mmu\_on  @跳转到\_\_turn\_mmu\_on来打开MMU。 
372 ENDPROC(\_\_enable\_mmu) 
374 /\* 
375  \* Enable the MMU.  This completely changes the structure of the visible 
376  \* memory space.  You will not be able to trace execution through this. 
377  \* If you have an enquiry about this, \*please\* check the linux-arm-kernel 
378  \* mailing list archives BEFORE sending another post to the list. 
379  \* 
380  \*  r0  = cp\#15 control register 
381  \*  r1  = machine ID 
382  \*  r2  = atags or dtb pointer 
383  \*  r9  = processor ID 
384  \*  r13 = \*virtual\* address to jump to upon completion 
385  \* 
386  \* other registers depend on the function called upon completion 
387  \*/ 
388         .align  5 
389 \_\_turn\_mmu\_on: 
390         mov     r0, r0 
391         mcr     p15, 0, r0, c1, c0, 0           @ write control reg写cp15的控制寄存器c1, 这里是打开mmu的动作,同时会打开cache等(根据r0相应的配置) 
392         mrc     p15, 0, r3, c0, c0, 0           @ read id reg读取id寄存器. 
393         mov     r3, r3   @1个nop. 
394         mov     r3, r13 
395         mov     pc, r3  @取r13到pc中,我们前面已经看到了, r13中存储的是 \_\_mmap\_switched (在arch/arm/kernel/head.S 113行),下面会跳到\_\_mmap\_switched 
396 \_\_enable\_mmu\_end: 
397 ENDPROC(\_\_turn\_mmu\_on) 
 
下面我们就来看\_\_mmap\_switched:注意这些代码就已经跑在了MMU打开的情况下了。无需再进行虚拟地址和物理地址的手工转换，完全由MMU来完成。 
在 arch/arm/kernel/head-common.S 中: 
 70 /\* 
 71  \* The following fragment of code is executed with the MMU on in MMU mode, 
 72  \* and uses absolute addresses; this is not position independent. 
 73  \* 
 74  \*  r0  = cp\#15 control register 
 75  \*  r1  = machine ID 
 76  \*  r2  = atags/dtb pointer 
 77  \*  r9  = processor ID 
 78  \*/ 
 79         \_\_INIT 
 80 \_\_mmap\_switched: 
 81         adr     r3, \_\_mmap\_switched\_data @取\_\_mmap\_switched\_data的地址到r3. 这个地址就是第109行的地址. 
 82 
 83         ldmia   r3!, \{r4, r5, r6, r7\} 
/\*依次取出从第109行到第112行的地址,存储到r4, r5, r6, r7 中. 并且累加r3的值.当执行完后, r3指向了\*    第\*113行的位置.我们可以得知: 
                r4 - \_\_data\_loc  是数据存放的位置 
                r5 - \_sdata   是数据开始的位置 
                r6 - \_\_bss\_start  是bss开始的位置 
                r7 - \_end  是bss结束的位置, 也是内核结束的位置 
这几个符号都是在 arch/arm/kernel/vmlinux.lds.S 和vmlinux.lds 中定义的变量, 
arch/arm/kernel/vmlinux.lds.S 
155 \#ifdef CONFIG\_XIP\_KERNEL 
156         \_\_data\_loc = ALIGN(4);          /\* location in binary \*/ 
157         . = PAGE\_OFFSET + TEXT\_OFFSET; 
158 \#else 
159         . = ALIGN(THREAD\_SIZE); 
160         \_\_data\_loc = .; 
161 \#endif 
162 
163         .data : AT(\_\_data\_loc) \{ 
164                 \_data = .;              /\* address in memory \*/ 
165                 \_sdata = .; 
166 
167                 /\* 
168                  \* first, the init task union, aligned 
169                  \* to an 8192 byte boundary. 
170                  \*/ 
171                 INIT\_TASK\_DATA(THREAD\_SIZE) 
其中对第163行的指令讲解一下: 这里定义了.data 段,后面的AT(\_\_data\_loc) 的意思是这部分的内容是在\_\_data\_loc中存储的(要注意,储存的位置和链接的位置是可以不相同的). 
   关于 AT 详细的信息请参考 ld.info 
\*/ 
 84         cmp     r4, r5            @ Copy data segment if needed比较 \_\_data\_loc 和 \_sdata 
 85 1:      cmpne   r5, r6 
 86         ldrne   fp, \[r4\], \#4 
 87         strne   fp, \[r5\], \#4 
 88         bne     1b 
 89 
 90         mov     fp, \#0                          @ Clear BSS (and zero fp) 
 91 1:      cmp     r6, r7 
 92         strcc   fp, \[r6\],\#4 
 93         bcc     1b 
 94 
 95  ARM(   ldmia   r3, \{r4, r5, r6, r7, sp\}) 
 96  THUMB( ldmia   r3, \{r4, r5, r6, r7\}    ) 
 97  THUMB( ldr     sp, \[r3, \#16\]           ) 
 98         str     r9, \[r4\]    @ Save processor ID 
 99         str     r1, \[r5\]    @ Save machine type 
100         str     r2, \[r6\]    @ Save atags pointer 
101         bic     r4, r0, \#CR\_A  @ Clear 'A' bit 
102         stmia   r7, \{r0, r4\}    @ Save control register values 
103         b       start\_kernel  ＠最终跳转到start\_kernel 
104 ENDPROC(\_\_mmap\_switched) 
其中85－88这几行是判断数据存储的位置和数据的开始的位置是否相等,如果不相等,则需要搬运数据,从 \_\_data\_loc 将数据搬到 \_sdata. 其中 \_\_bss\_start 是bss的开始的位置,也标志了 data 结束的位置,因而用其作为判断数据是否搬运完成. 
其中90－93这几行是清除 bss 段的内容,将其都置成0. 这里使用 \_end 来判断 bss 的结束位置. 
第95行因为在第83行的时候,r3被更新到指向第113行的位置.因而这里取得r4, r5, r6, r7，sp的值分别是: 
        r4 - processor\_id 
        r5 - \_\_machine\_arch\_type 
        r6 - \_\_atags\_pointer 
        r7 - cr\_alignment 
        sp - init\_thread\_union + THREAD\_START\_SP 
 
    processor\_id 和 \_\_machine\_arch\_type 这两个变量是在 arch/arm/kernel/setup.c 中 第79, 81行中定义的. 
    cr\_alignment 是在 arch/arm/kernel/entry-armv.S 中定义的: 
1229         .data 
1230 
1231         .globl  cr\_alignment 
1232         .globl  cr\_no\_alignment 
1233 cr\_alignment: 
1234         .space  4 
1235 cr\_no\_alignment: 
1236         .space  4 
init\_thread\_union 是 init进程的基地址. 在 arch/arm/kernel/init\_task.c 中: 
 
 27 union thread\_union init\_thread\_union \_\_init\_task\_data = 
 28         \{ INIT\_THREAD\_INFO(init\_task) \};     
 
    对照 vmlnux.lds.S 中的 的171行,我们可以知道init task是存放在 .data 段的开始8k, 并且是THREAD\_SIZE(8k)对齐的 
第98行: 将r9中存放的 processor id (在arch/arm/kernel/head.S 78行) 赋值给变量 processor\_id 
第99行: 将r1中存放的 machine id (见"启动条件"一节)赋值给变量　\_\_machine\_arch\_type 
第101行: 清除r0中的 CR\_A 位并将值存到r4中. CR\_A 是在 arch/arm/include/asm/system.h  21行定义, 是cp15控制寄存器c1的Bit\[1\](alignment fault enable/disable) 
第102行: 这一行是存储控制寄存器的值. 
    从上面 arch/arm/kernel/entry-armv.S 的代码我们可以得知. 
    这一句是将r0存储到了 cr\_alignment 中,将r4存储到了 cr\_no\_alignment 中. 
 
105 
106         .align  2 
107         .type   \_\_mmap\_switched\_data, %object 
108 \_\_mmap\_switched\_data: 
109         .long   \_\_data\_loc                      @ r4 
110         .long   \_sdata                          @ r5 
111         .long   \_\_bss\_start                     @ r6 
112         .long   \_end                            @ r7 
113         .long   processor\_id                    @ r4 
114         .long   \_\_machine\_arch\_type             @ r5 
115         .long   \_\_atags\_pointer                 @ r6 
116         .long   cr\_alignment                    @ r7 
117         .long   init\_thread\_union + THREAD\_START\_SP @ sp 
118         .size   \_\_mmap\_switched\_data, . - \_\_mmap\_switched\_data 
第107, 108行: 对象定义。 
第109 - 117行: 为对象里的每个域赋值，例如,第109行存储的是 \_\_data\_loc 的地址,第114行存储的是\_\_machine\_arch\_type的地址 ......

[Link 1]: http://clk.qunsee.com/click/click.php?cpid=12&ads_id=1240&pid=99005765&cid=5794&url=http%3A/www.qunsee.com/agent.php&k=%u5B9E%u73B0&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699.html&rn=863374&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_3.html&province=UNKNOWN&city=UNKNOWN
[Link 2]: http://clk.qunsee.com/click/click.php?cpid=1021&ads_id=1201&pid=99005765&cid=5794&url=http%3A/www.chanet.com.cn/click.cgi%3Fa%3D59068%26d%3D42943%26u%3D%26e%3D&k=%u6761%u4EF6&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699.html&rn=622634&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_3.html&province=UNKNOWN&city=UNKNOWN
[Link 3]: http://clk.qunsee.com/click/click.php?cpid=510&ads_id=46&pid=99005765&cid=5794&url=http%3A/www.qunsee.com/sitepage.php&k=%u7BA1%u7406&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699.html&rn=33745&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_3.html&province=UNKNOWN&city=UNKNOWN
[Link 4]: http://clk.qunsee.com/click/click.php?cpid=1021&ads_id=1090&pid=99005765&cid=5794&url=http%3A/www.chanet.com.cn/click.cgi%3Fa%3D59068%26d%3D41911%26u%3D%26e%3D&k=%u865A%u62DF&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699.html&rn=18107&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_3.html&province=UNKNOWN&city=UNKNOWN
[Link 5]: http://clk.qunsee.com/click/click.php?cpid=1021&ads_id=1090&pid=99005765&cid=5794&url=http%3A/www.chanet.com.cn/click.cgi%3Fa%3D59068%26d%3D41911%26u%3D%26e%3D&k=%u865A%u62DF&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_7.html&rn=417010&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_6.html&province=UNKNOWN&city=UNKNOWN
[Link 6]: http://clk.qunsee.com/click/click.php?cpid=1021&ads_id=1201&pid=99005765&cid=5794&url=http%3A/www.chanet.com.cn/click.cgi%3Fa%3D59068%26d%3D42943%26u%3D%26e%3D&k=%u8FD4%u56DE&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_7.html&rn=441701&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_6.html&province=UNKNOWN&city=UNKNOWN
[Link 7]: http://clk.qunsee.com/click/click.php?cpid=510&ads_id=47&pid=99005765&cid=5794&url=http%3A/www.qunsee.com/adpage.php&k=%u627E%u5230&s=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_8.html&rn=114987&v=1&ref=http%3A/www.chmhome.com/knowledge/linux/20080801/164699_7.html&province=%u4E0A%u6D77&city=%u4E0A%u6D77
[1.JPG]: /images/20220326/91e658edf3c14b88925bd2f0bd9c1990.png
[2.JPG]: /images/20220326/74d261a376134cec8c4d0256729300ff.png
[3.JPG]: /images/20220326/e7f53fded0f04b06a27022b637cc9ab8.png