Hive Partition简介

怼烎@ 2022-03-28 17:38 172阅读 0赞

一、背景

1、在Hive Select查询中一般会扫描整个表内容，会消耗很多时间做没必要的工作。有时候只需要扫描表中关心的一部分数据，因此建表时引入了partition概念。

2、分区表指的是在创建表时指定的partition的分区空间。

3、如果需要创建有分区的表，需要在create表的时候调用可选参数partitioned by，详见表创建的语法结构。

二、技术细节

1、一个表可以拥有一个或者多个分区，每个分区以文件夹的形式单独存在表文件夹的目录下。

2、表和列名不区分大小写。

3、分区是以字段的形式在表结构中存在，通过describe table命令可以查看到字段存在，但是该字段不存放实际的数据内容，仅仅是分区的表示。

4、建表的语法（建分区可参见PARTITIONED BY参数）：

CREATE \[EXTERNAL\] TABLE \[IF NOT EXISTS\] table\_name \[(col\_name data\_type \[COMMENT col\_comment\], ...)\] \[COMMENT table\_comment\] \[PARTITIONED BY (col\_name data\_type \[COMMENT col\_comment\], ...)\] \[CLUSTERED BY (col\_name, col\_name, ...) \[SORTED BY (col\_name \[ASC|DESC\], ...)\] INTO num\_buckets BUCKETS\] \[ROW FORMAT row\_format\] \[STORED AS file\_format\] \[LOCATION hdfs\_path\]

5、分区建表分为2种，一种是单分区，也就是说在表文件夹目录下只有一级文件夹目录。另外一种是多分区，表文件夹下出现多文件夹嵌套模式。

a、单分区建表语句：create table day\_table (id int, content string) partitioned by (dt string);单分区表，按天分区，在表结构中存在id，content，dt三列。

b、双分区建表语句：create table day\_hour\_table (id int, content string) partitioned by (dt string, hour string);双分区表，按天和小时分区，在表结构中新增加了dt和hour两列。

表文件夹目录示意图（多分区表）：

6、添加分区表语法（表已创建，在此基础上添加分区）：

ALTER TABLE table\_name ADD partition\_spec \[ LOCATION 'location1' \] partition\_spec \[ LOCATION 'location2' \] ... partition\_spec: : PARTITION (partition\_col = partition\_col\_value, partition\_col = partiton\_col\_value, ...)

用户可以用 ALTER TABLE ADD PARTITION 来向一个表中增加分区。当分区名是字符串时加引号。例：

ALTER TABLE day\_table ADD PARTITION (dt='2008-08-08', hour='08') location '/path/pv1.txt' PARTITION (dt='2008-08-08', hour='09') location '/path/pv2.txt';

7、删除分区语法：

ALTER TABLE table\_name DROP partition\_spec, partition\_spec,...

用户可以用 ALTER TABLE DROP PARTITION 来删除分区。分区的元数据和数据将被一并删除。例：

ALTER TABLE day\_hour\_table DROP PARTITION (dt='2008-08-08', hour='09');

8、数据加载进分区表中语法：

LOAD DATA \[LOCAL\] INPATH 'filepath' \[OVERWRITE\] INTO TABLE tablename \[PARTITION (partcol1=val1, partcol2=val2 ...)\]

例：

LOAD DATA INPATH '/user/pv.txt' INTO TABLE day\_hour\_table PARTITION(dt='2008-08- 08', hour='08'); LOAD DATA local INPATH '/user/hua/\*' INTO TABLE day\_hour partition(dt='2010-07- 07');

当数据被加载至表中时，不会对数据进行任何转换。Load操作只是将数据复制至Hive表对应的位置。数据加载时在表下自动创建一个目录，文件存放在该分区下。

9、基于分区的查询的语句：

SELECT day\_table.\* FROM day\_table WHERE day\_table.dt>= '2008-08-08';

10、查看分区语句：

hive> show partitions day\_hour\_table; OK dt=2008-08-08/hour=08 dt=2008-08-08/hour=09 dt=2008-08-09/hour=09

三、总结

1、在 Hive 中，表中的一个 Partition 对应于表下的一个目录，所有的 Partition 的数据都存储在最字集的目录中。

2、总的说来partition就是辅助查询，缩小查询范围，加快数据的检索速度和对数据按照一定的规格和条件进行管理。

——————————————————————————————————————

hive中关于partition的操作：  
hive> create table mp (a string) partitioned by (b string, c string);  
OK  
Time taken: 0.044 seconds  
hive> alter table mp add partition (b='1', c='1');  
OK  
Time taken: 0.079 seconds  
hive> alter table mp add partition (b='1', c='2');  
OK  
Time taken: 0.052 seconds  
hive> alter table mp add partition (b='2', c='2');  
OK  
Time taken: 0.056 seconds  
hive> show partitions mp ;  
OK  
b=1/c=1  
b=1/c=2  
b=2/c=2  
Time taken: 0.046 seconds  
hive> explain extended alter table mp drop partition (b='1');  
OK  
ABSTRACT SYNTAX TREE:  
  (TOK\_ALTERTABLE\_DROPPARTS mp (TOK\_PARTSPEC (TOK\_PARTVAL b '1')))

STAGE DEPENDENCIES:  
  Stage-0 is a root stage

STAGE PLANS:  
  Stage: Stage-0  
      Drop Table Operator:  
        Drop Table  
          table: mp

Time taken: 0.048 seconds  
hive> alter table mp drop partition (b='1');  
FAILED: Error in metadata: table is partitioned but partition spec is not specified or tab: \{b=1\}  
FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask  
hive> show partitions mp ;  
OK  
b=1/c=1  
b=1/c=2  
b=2/c=2  
Time taken: 0.044 seconds  
hive> alter table mp add   partition ( b='1', c = '3') partition ( b='1' , c='4');  
OK  
Time taken: 0.168 seconds  
hive> show partitions mp ;  
OK  
b=1/c=1  
b=1/c=2  
b=1/c=3  
b=1/c=4  
b=2/c=2  
b=2/c=3  
Time taken: 0.066 seconds  
hive>insert overwrite table mp partition (b='1', c='1') select cnt from tmp\_et3 ;

hive>alter table mp add columns (newcol string);

location指定目录结构  
hive> alter table alter2 add partition (insertdate='2008-01-01') location '2008/01/01';

hive> alter table alter2 add partition (insertdate='2008-01-02') location '2008/01/02';

hive中简单介绍分区表(partition table)，含动态分区(dynamic partition)与静态分区(static partition)  
hive中创建分区表没有什么复杂的分区类型(范围分区、列表分区、hash分区、混合分区等)。  
分区列也不是表中的一个实际的字段，而是一个或者多个伪列。意思是说在表的数据文件中实际上并不保存分区列的信息与数据。

下面的语句创建了一个简单的分区表：

create table partition\_test  
(member\_id string,  
name string  
)  
partitioned by (  
stat\_date string,  
province string)  
ROW FORMAT DELIMITED FIELDS TERMINATED BY ',';

这个例子中创建了stat\_date和province两个字段作为分区列。通常情况下需要先预先创建好分区，然后才能使用该分区，例如：

alter table partition\_test add partition (stat\_date='20110728',province='zhejiang');

这样就创建好了一个分区。这时我们会看到hive在HDFS存储中创建了一个相应的文件夹：

$ hadoop fs -ls /user/hive/warehouse/partition\_test/stat\_date=20110728  
Found 1 items  
drwxr-xr-x - admin supergroup 0 2011-07-29 09:53 /user/hive/warehouse/partition\_test/stat\_date=20110728/province=zhejiang

每一个分区都会有一个独立的文件夹，下面是该分区所有的数据文件。在这个例子中stat\_date是主层次，province是副层次，所有stat\_date='20110728'，  
而province不同的分区都会在/user/hive/warehouse/partition\_test/stat\_date=20110728 下面，而stat\_date不同的分区都会在/user/hive/warehouse/partition\_test/  
下面，如：

$ hadoop fs -ls /user/hive/warehouse/partition\_test/  
Found 2 items  
drwxr-xr-x - admin supergroup 0 2011-07-28 19:46 /user/hive/warehouse/partition\_test/stat\_date=20110526  
drwxr-xr-x - admin supergroup 0 2011-07-29 09:53 /user/hive/warehouse/partition\_test/stat\_date=20110728

注意，因为分区列的值要转化为文件夹的存储路径，所以如果分区列的值中包含特殊值，如 '%', ':', '/', '\#',它将会被使用%加上2字节的ASCII码进行转义，如：

hive> alter table partition\_test add partition (stat\_date='2011/07/28',province='zhejiang');  
OK  
Time taken: 4.644 seconds

$hadoop fs -ls /user/hive/warehouse/partition\_test/  
Found 3 items  
drwxr-xr-x - admin supergroup 0 2011-07-29 10:06 /user/hive/warehouse/partition\_test/stat\_date=2011% 2F07% 2F28  
drwxr-xr-x - admin supergroup 0 2011-07-28 19:46 /user/hive/warehouse/partition\_test/stat\_date=20110526  
drwxr-xr-x - admin supergroup 0 2011-07-29 09:53 /user/hive/warehouse/partition\_test/stat\_date=20110728

我使用一个辅助的非分区表partition\_test\_input准备向partition\_test中插入数据：

hive> desc partition\_test\_input;  
OK  
stat\_date string  
member\_id string  
name string  
province string

hive> select \* from partition\_test\_input;  
OK  
20110526 1 liujiannan liaoning  
20110526 2 wangchaoqun hubei  
20110728 3 xuhongxing sichuan  
20110728 4 zhudaoyong henan  
20110728 5 zhouchengyu heilongjiang

然后我向partition\_test的分区中插入数据：

hive> insert overwrite table partition\_test partition(stat\_date='20110728',province='henan') select member\_id,name from partition\_test\_input where stat\_date='20110728' and province='henan';  
Total MapReduce jobs = 2  
...  
1 Rows loaded to partition\_test  
OK

还可以同时向多个分区插入数据，0.7版本以后不存在的分区会自动创建，0.6之前的版本官方文档上说必须要预先创建好分区：

hive>  
> from partition\_test\_input  
> insert overwrite table partition\_test partition (stat\_date='20110526',province='liaoning')  
> select member\_id,name where stat\_date='20110526' and province='liaoning'  
> insert overwrite table partition\_test partition (stat\_date='20110728',province='sichuan')  
> select member\_id,name where stat\_date='20110728' and province='sichuan'  
> insert overwrite table partition\_test partition (stat\_date='20110728',province='heilongjiang')  
> select member\_id,name where stat\_date='20110728' and province='heilongjiang';  
Total MapReduce jobs = 4  
...  
3 Rows loaded to partition\_test  
OK

特别要注意，在其他数据库中，一般向分区表中插入数据时系统会校验数据是否符合该分区，如果不符合会报错。而在hive中，向某个分区中插入什么样的数据完全是由人来控制的，因为分区键是伪列，不实际存储在文件中，如：

hive> insert overwrite table partition\_test partition(stat\_date='20110527',province='liaoning') select member\_id,name from partition\_test\_input;  
Total MapReduce jobs = 2  
...  
5 Rows loaded to partition\_test  
OK

hive> select \* from partition\_test where stat\_date='20110527' and province='liaoning';  
OK  
1 liujiannan 20110527 liaoning  
2 wangchaoqun 20110527 liaoning  
3 xuhongxing 20110527 liaoning  
4 zhudaoyong 20110527 liaoning  
5 zhouchengyu 20110527 liaoning

可以看到在partition\_test\_input中的5条数据有着不同的stat\_date和province，但是在插入到partition(stat\_date='20110527',province='liaoning')这个分区后，5条数据的stat\_date和province都变成相同的了，因为这两列的数据是根据文件夹的名字读取来的，而不是实际从数据文件中读取来的：

$ hadoop fs -cat /user/hive/warehouse/partition\_test/stat\_date=20110527/province=liaoning/000000\_0  
1,liujiannan  
2,wangchaoqun  
3,xuhongxing  
4,zhudaoyong  
5,zhouchengyu

下面介绍一下动态分区，因为按照上面的方法向分区表中插入数据，如果源数据量很大，那么针对一个分区就要写一个insert，非常麻烦。况且在之前的版本中，必须先手动创建好所有的分区后才能插入，这就更麻烦了，你必须先要知道源数据中都有什么样的数据才能创建分区。  
使用动态分区可以很好的解决上述问题。动态分区可以根据查询得到的数据自动匹配到相应的分区中去。  
使用动态分区要先设置hive.exec.dynamic.partition参数值为true，默认值为false，即不允许使用：

hive> set hive.exec.dynamic.partition;  
hive.exec.dynamic.partition=false  
hive> set hive.exec.dynamic.partition=true;  
hive> set hive.exec.dynamic.partition;  
hive.exec.dynamic.partition=true

动态分区的使用方法很简单，假设我想向stat\_date='20110728'这个分区下面插入数据，至于province插入到哪个子分区下面让数据库自己来判断，那可以这样写：

hive> insert overwrite table partition\_test partition(stat\_date='20110728',province)  
> select member\_id,name,province from partition\_test\_input where stat\_date='20110728';  
Total MapReduce jobs = 2  
...  
3 Rows loaded to partition\_test  
OK

stat\_date叫做静态分区列，province叫做动态分区列。select子句中需要把动态分区列按照分区的顺序写出来，静态分区列不用写出来。这样stat\_date='20110728'的所有数据，会根据province的不同分别插入到/user/hive/warehouse/partition\_test/stat\_date=20110728/下面的不同的子文件夹下，如果源数据对应的province子分区不存在，则会自动创建，非常方便，而且避免了人工控制插入数据与分区的映射关系存在的潜在风险。

注意，动态分区不允许主分区采用动态列而副分区采用静态列，这样将导致所有的主分区都要创建副分区静态列所定义的分区：

hive> insert overwrite table partition\_test partition(stat\_date,province='liaoning')  
> select member\_id,name,province from partition\_test\_input where province='liaoning';  
FAILED: Error in semantic analysis: Line 1:48 Dynamic partition cannot be the parent of a static partition 'liaoning'

动态分区可以允许所有的分区列都是动态分区列，但是要首先设置一个参数hive.exec.dynamic.partition.mode ：

hive> set hive.exec.dynamic.partition.mode;  
hive.exec.dynamic.partition.mode=strict

它的默认值是strick，即不允许分区列全部是动态的，这是为了防止用户有可能原意是只在子分区内进行动态建分区，但是由于疏忽忘记为主分区列指定值了，这将导致一个dml语句在短时间内创建大量的新的分区（对应大量新的文件夹），对系统性能带来影响。  
所以我们要设置：  
hive> set hive.exec.dynamic.partition.mode=nostrick;

再介绍3个参数：  
hive.exec.max.dynamic.partitions.pernode （缺省值100）：每一个mapreduce job允许创建的分区的最大数量，如果超过了这个数量就会报错  
hive.exec.max.dynamic.partitions （缺省值1000）：一个dml语句允许创建的所有分区的最大数量  
hive.exec.max.created.files （缺省值100000）：所有的mapreduce job允许创建的文件的最大数量

当源表数据量很大时，单独一个mapreduce job中生成的数据在分区列上可能很分散，举个简单的例子，比如下面的表要用3个map：  
1  
1  
1  
2  
2  
2  
3  
3  
3

如果数据这样分布，那每个mapreduce只需要创建1个分区就可以了：  
         |1  
map1 --> |1  
         |1

|2  
map2 --> |2  
         |2

|3  
map3 --> |3  
         |3  
但是如果数据按下面这样分布，那第一个mapreduce就要创建3个分区：

|1  
map1 --> |2  
         |3

|1  
map2 --> |2  
         |3

|1  
map3 --> |2  
         |3

下面给出了一个报错的例子：  
hive> set hive.exec.max.dynamic.partitions.pernode=4;  
hive> insert overwrite table partition\_test partition(stat\_date,province)  
> select member\_id,name,stat\_date,province from partition\_test\_input distribute by stat\_date,province;  
Total MapReduce jobs = 1  
...  
\[Fatal Error\] Operator FS\_4 (id=4): Number of dynamic partitions exceeded hive.exec.max.dynamic.partitions.pernode.. Killing the job.  
Ended Job = job\_201107251641\_0083 with errors  
FAILED: Execution Error, return code 2 from org.apache.hadoop.hive.ql.exec.MapRedTask

为了让分区列的值相同的数据尽量在同一个mapreduce中，这样每一个mapreduce可以尽量少的产生新的文件夹，可以借助distribute by的功能，将分区列值相同的数据放到一起：

hive> insert overwrite table partition\_test partition(stat\_date,province)  
> select member\_id,name,stat\_date,province from partition\_test\_input distribute by stat\_date,province;  
Total MapReduce jobs = 1  
...  
18 Rows loaded to partition\_test  
OK

好了，关于hive的分区表先简单介绍到这里，后续版本如果有功能的更新我也会再更新。