CO02生产订单修改记录

我会带着你远行 2022-04-11 07:57 515阅读 0赞

记录修改

CMOD   PPCO0001

EXIT  EXIT\_SAPLCOBT\_001

INCLUDE ZXCO1U01

\*&---------------------------------------------------------------------\*  
\*& 包含               ZXCO1U01  
\*&---------------------------------------------------------------------\*  
  
  TABLES:caufv,resb.  
  DATA: BEGIN OF old\_resb OCCURS 0, "更改后未保存之RESB.  
          aufnr LIKE resb-aufnr,  
          posnr LIKE resb-posnr,  
          matnr LIKE resb-matnr,  
          rsnum LIKE resb-rsnum,  
          rspos LIKE resb-rspos,  
          xloek LIKE resb-xloek,  
          bdmng LIKE resb-bdmng,  
          objnr LIKE resb-objnr,  
        END OF old\_resb.  
  DATA: BEGIN OF new\_resb OCCURS 0. "数据库中的RESB.  
      INCLUDE STRUCTURE old\_resb.  
  DATA: END OF new\_resb.  
  DATA: BEGIN OF obj\_resb OCCURS 0. "插入的RESB  
      INCLUDE STRUCTURE old\_resb.  
  DATA: END OF obj\_resb.  
  DATA: i\_zpco02 LIKE zpco002 OCCURS 0 WITH HEADER LINE.  
  DATA: i\_temp LIKE zpco002 OCCURS 0 WITH HEADER LINE.  
  DATA: iporg     LIKE msxxlist-hostadr,  
        ipdec(16) TYPE c,  
        host(18)  TYPE c.  
  DATA:char1(20) TYPE c,  
       char2(20) TYPE c.  
  DATA: inst\_flg TYPE c VALUE 'N',  
        chan\_had TYPE c VALUE  'N'.  
  
  
  CHECK sy-tcode EQ 'CO02'.  
\*\* Get user IP,hostname  
  CALL FUNCTION 'TH\_USER\_INFO'  " Get user IP,hostname  
    EXPORTING  
      client   = sy-mandt  
      user     = sy-uname  
    IMPORTING  
      hostaddr = iporg  
      terminal = host  
    EXCEPTIONS  
      OTHERS   = 1.  
\*\*"Conv.IP addr to format "xxx.xxx.xxx.xxx"  
  CALL FUNCTION 'GWY\_IPADR2STRING'   "Conv.IP addr  
    EXPORTING  
      ipadr  = iporg  
    IMPORTING  
      string = ipdec.  
\*\*\*Common var.  
  MOVE: sy-mandt TO i\_temp-mandt,  
  sy-uname TO i\_temp-aenam,  
  sy-datum TO i\_temp-laeda,  
  sy-uzeit TO i\_temp-times,  
  sy-tcode TO i\_temp-tcode,  
  ipdec TO i\_temp-hostip,  
  host TO i\_temp-host,  
  header\_table-aufnr TO i\_temp-aufnr.  
  
  
  SELECT SINGLE gamng gstrp INTO (caufv-gamng, caufv-gstrp)  
  FROM caufv WHERE aufnr EQ header\_table-aufnr.  
  
  IF header\_table-gamng NE caufv-gamng.  
    MOVE: caufv-gamng TO char1, header\_table-gamng TO char2.  
    MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
    MOVE: '更改工单总数' TO i\_zpco02-filed,  
    'U' TO i\_zpco02-chnid,  
    char1 TO i\_zpco02-value\_old,  
    char2 TO i\_zpco02-value\_new.  
    APPEND i\_zpco02.  
    inst\_flg = 'Y'.  
    chan\_had = 'Y'.  
  ENDIF.  
  
  IF header\_table-gstrp NE caufv-gstrp.  
    MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
    MOVE: '更改开工日期' TO i\_zpco02-filed,  
    'U' TO i\_zpco02-chnid,  
    caufv-gstrp TO i\_zpco02-value\_old,  
    header\_table-gstrp TO i\_zpco02-value\_new.  
    APPEND i\_zpco02.  
    inst\_flg = 'Y'.  
  ENDIF.  
  IF inst\_flg = 'Y'.  
    INSERT zpco002 FROM TABLE i\_zpco02 ACCEPTING DUPLICATE KEYS.  
    inst\_flg = 'N'.  
  ENDIF.  
  
  LOOP AT component\_table WHERE vbkz EQ 'U'  
  OR vbkz EQ 'I'  
  OR vbkz EQ 'D'.  
    CASE component\_table-vbkz.  
      WHEN 'I'.  
        MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
        MOVE: '新增组件' TO i\_zpco02-filed,  
        'I' TO i\_zpco02-chnid,  
        '' TO i\_zpco02-value\_old, "old\_resb-matnr  
        component\_table-matnr TO i\_zpco02-value\_new,  
        '新增的组件' TO i\_zpco02-matnr,  
        component\_table-alpos TO i\_zpco02-alpos,  
        sy-tabix TO i\_zpco02-loopid.  
        APPEND i\_zpco02.  
        inst\_flg = 'Y'.  
      WHEN 'D'.  
        MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
        MOVE: '删除组件' TO i\_zpco02-filed,  
        'D' TO i\_zpco02-chnid,  
        resb-xloek TO i\_zpco02-value\_old,  
        component\_table-xloek TO i\_zpco02-value\_new,  
        component\_table-matnr TO i\_zpco02-matnr,  
        component\_table-alpos TO i\_zpco02-alpos,  
        sy-tabix TO i\_zpco02-loopid.  
        APPEND i\_zpco02.  
        inst\_flg = 'Y'.  
      WHEN 'U'.  
        SELECT SINGLE matnr bdmng INTO (resb-matnr, resb-bdmng)  
        FROM resb WHERE aufnr EQ component\_table-aufnr  
        AND posnr EQ component\_table-posnr  
        AND matnr EQ component\_table-matnr  
        AND rsnum EQ component\_table-rsnum  
        AND rspos EQ component\_table-rspos.  
        IF component\_table-matnr NE resb-matnr.  
          MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
          MOVE: '更改组件' TO i\_zpco02-filed,  
          'U' TO i\_zpco02-chnid,  
          resb-matnr TO i\_zpco02-value\_old,  
          component\_table-matnr TO i\_zpco02-value\_new,  
          '更改的工单组件' TO i\_zpco02-matnr,  
          component\_table-alpos TO i\_zpco02-alpos,  
          sy-tabix TO i\_zpco02-loopid.  
          APPEND i\_zpco02.  
          inst\_flg = 'Y'.  
        ELSEIF component\_table-bdmng NE resb-bdmng.  
          CHECK chan\_had NE 'Y'.  
          MOVE: component\_table-bdmng TO char1, resb-bdmng TO char2.  
          MOVE-CORRESPONDING i\_temp TO i\_zpco02.  
          MOVE: '需求数量' TO i\_zpco02-filed,  
          'U' TO i\_zpco02-chnid,  
          char2 TO i\_zpco02-value\_old,  
          char1 TO i\_zpco02-value\_new,  
          component\_table-matnr TO i\_zpco02-matnr,  
          component\_table-alpos TO i\_zpco02-alpos,  
          sy-tabix TO i\_zpco02-loopid.  
          APPEND i\_zpco02.  
          inst\_flg = 'Y'.  
        ENDIF.  
    ENDCASE.  
  ENDLOOP.  
  IF inst\_flg = 'Y'.  
    INSERT zpco002 FROM TABLE i\_zpco02 ACCEPTING DUPLICATE KEYS.  
    IF sy-subrc EQ 0.  
      inst\_flg = 'N'.  
      chan\_had = 'N'.  
\* MESSAGE ID "ZX" TYPE "W"  
\* NUMBER "000" WITH "SAP系统已记录您的更改!".  
    ENDIF.  
  ENDIF.

查询界面

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70][]

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70 1][]

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70 2][]

\*&---------------------------------------------------------------------\*  
\*& Report ZPPR022  
\*&---------------------------------------------------------------------\*  
\*&  
\*&---------------------------------------------------------------------\*  
REPORT zppr022 MESSAGE-ID zhele.  
  
TABLES:zpco002,afko.  
  
DATA: BEGIN OF wa\_item,  
        aufnr     LIKE zpco002-aufnr,  
        matnr     LIKE zpco002-matnr,  
        filed     LIKE zpco002-filed,  
        aenam     LIKE zpco002-aenam,  
        laeda     LIKE zpco002-laeda,  
        chnid     LIKE zpco002-chnid,  
        hostip    LIKE zpco002-hostip,  
        host      LIKE zpco002-host,  
        value\_old LIKE zpco002-value\_old,  
        value\_new LIKE zpco002-value\_new,  
        times     LIKE zpco002-times,  
        name\_last LIKE adrp-name\_last,  
        plnbez    LIKE afko-plnbez,  
      END OF wa\_item.  
DATA:BEGIN OF gs\_afko,  
       aufnr  LIKE afko-aufnr,  
       plnbez LIKE afko-plnbez,  
     END OF gs\_afko.  
  
DATA:gt\_item LIKE TABLE OF wa\_item.  
DATA:gt\_afko LIKE TABLE OF gs\_afko.  
  
SELECT-OPTIONS:s\_aufnr FOR zpco002-aufnr ,  
               s\_plnbez FOR afko-plnbez,  
               s\_aenam FOR zpco002-aenam,  
               s\_laeda FOR zpco002-laeda,  
               s\_filed FOR zpco002-filed.  
  
DATA: it\_fieldcat TYPE slis\_t\_fieldcat\_alv, "lvc\_t\_fcat, "列描述内表，列清单  
      wa\_fieldcat LIKE LINE OF it\_fieldcat,  
      it\_layout   TYPE slis\_layout\_alv. "lvc\_s\_layo. "表格规格属性内表  
CONSTANTS cns\_user\_command TYPE slis\_formname VALUE 'ALV\_USER\_COMMAND' .  
  
INITIALIZATION.  
  
START-OF-SELECTION.  
  
  SELECT \* INTO CORRESPONDING FIELDS OF TABLE gt\_item  
                    FROM zpco002 JOIN usr21 ON zpco002~aenam = usr21~bname  
                    LEFT JOIN adrp ON usr21~persnumber = adrp~persnumber  
                    WHERE aufnr IN s\_aufnr  
                    AND filed IN s\_filed  
                    AND aenam IN s\_aenam  
                    AND laeda IN s\_laeda  
                    ."plnbez  
  IF  gt\_item IS INITIAL.  
  
    MESSAGE '请输入查询条件' TYPE 'I' DISPLAY LIKE 'E'.  
  
  ENDIF.  
  
  IF s\_plnbez\[\] IS NOT INITIAL .  
    DATA: lv\_tabix LIKE sy-tabix.  
    SELECT aufnr plnbez INTO TABLE gt\_afko FROM afko WHERE plnbez IN  s\_plnbez.  
  
    SORT gt\_afko BY aufnr.  
    LOOP AT gt\_item INTO wa\_item.  
      lv\_tabix = sy-tabix.  
      READ TABLE gt\_afko WITH KEY aufnr = wa\_item-aufnr  
                               BINARY SEARCH TRANSPORTING NO FIELDS.  
      IF sy-subrc <> 0.  
        DELETE gt\_item INDEX lv\_tabix.  
        CONTINUE.  
      ENDIF.  
      CLEAR:lv\_tabix.  
    ENDLOOP.  
  
  ENDIF.  
  
  DATA : col\_pos TYPE i VALUE 1.  
  CLEAR:it\_fieldcat,wa\_fieldcat.  
  it\_layout-colwidth\_optimize = 'X'.  
  it\_layout-info\_fieldname = 'COLOR'.  
  
  PERFORM fieldcat\_int USING col\_pos  'AUFNR' '' '订单号' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'MATNR' '' '物料号' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'FILED' '' '字段名' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'AENAM' '' '更改者' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'NAME\_LAST' '' '姓名' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'LAEDA' '' '更改日期' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'TIMES' '' '更改时间' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'VALUE\_OLD' '' '旧值' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'VALUE\_NEW' '' '新值' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'CHNID' '' '更改标识' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'HOST' '' '主机名' '' 'X'  '' '' '' ''.  
  PERFORM fieldcat\_int USING col\_pos  'HOSTIP' '' '主机IP地址' '' 'X'  '' '' '' ''.  
  
  
  CALL FUNCTION 'REUSE\_ALV\_GRID\_DISPLAY'  
    EXPORTING  
      i\_callback\_program       = sy-repid  
      i\_callback\_pf\_status\_set = 'SET\_PF\_STATUS'  
      i\_callback\_user\_command  = cns\_user\_command  
      is\_layout                = it\_layout  
      it\_fieldcat              = it\_fieldcat  
      i\_save                   = 'A'  
    TABLES  
      t\_outtab                 = gt\_item.  
  
FORM set\_pf\_status USING rt\_extab TYPE slis\_t\_extab.  
\*    获取gui状态  
  DATA: wa\_extab TYPE slis\_extab.  
  
\*  AUTHORITY-CHECK OBJECT 'ZE\_ZPPT002'  
\*      ID 'ACTVT' FIELD '01'.  
\*  IF sy-subrc = 0.  
\*    SET PF-STATUS 'OPEN\_01' EXCLUDING rt\_extab.  
\*  ELSE.  
  SET PF-STATUS 'OPEN' EXCLUDING rt\_extab.  
\*  ENDIF.  
  
ENDFORM.  
  
FORM fieldcat\_int  USING   p\_col\_pos         " 1  
                            p\_fieldname       " 2  
                            p\_key             " 3  
                            p\_seltext\_l       " 4  
                            p\_edit  
                            p\_fix  
\*                            p\_checkbox  
                            p\_no\_out  
                            p\_tname  
                            p\_fname  
                            p\_reffi.  
  wa\_fieldcat-col\_pos       = p\_col\_pos.  
  wa\_fieldcat-fieldname     = p\_fieldname.  
  wa\_fieldcat-key           = p\_key.  
\*  wa\_fieldcat-coltext    = p\_seltext\_l.  
  wa\_fieldcat-seltext\_l = p\_seltext\_l.  
  wa\_fieldcat-edit            = p\_edit.  
  wa\_fieldcat-fix\_column        = p\_fix.  
\*  wa\_fieldcat-checkbox     = p\_checkbox.  
  wa\_fieldcat-no\_out      = p\_no\_out.  
\*  wa\_fieldcat-colddictxt       = 'L'.  
  wa\_fieldcat-ref\_tabname    = p\_tname.  
  wa\_fieldcat-ref\_fieldname  = p\_fname.  
  wa\_fieldcat-qfieldname    = p\_reffi.  
  
  APPEND wa\_fieldcat TO it\_fieldcat.  
  p\_col\_pos = p\_col\_pos + 1.  
  CLEAR: wa\_fieldcat.  
  
ENDFORM.  
  
FORM alv\_user\_command USING r\_ucomm LIKE sy-ucomm  
                        rs\_selfield TYPE slis\_selfield.  
  
\*  CREATE OBJECT g\_event\_receiver.  
\*      SET HANDLER g\_event\_receiver->on\_f4 FOR g\_grid.  
  
\*   获取ALV中的鼠标勾选记录  
  DATA: l\_grid TYPE REF TO cl\_gui\_alv\_grid.  
  CALL FUNCTION 'GET\_GLOBALS\_FROM\_SLVC\_FULLSCR'  
    IMPORTING  
      e\_grid = l\_grid.  
  
  CALL METHOD l\_grid->check\_changed\_data.  
  CASE r\_ucomm.  
    WHEN '&IC1' .  
      CASE rs\_selfield-sel\_tab\_field.  
          READ TABLE gt\_item INTO wa\_item INDEX rs\_selfield-tabindex.  
        WHEN '1-AUFNR'.  
          SET PARAMETER ID 'ANR' FIELD rs\_selfield-value.  
          SET PARAMETER ID 'AUFNR' FIELD wa\_item-aufnr.  
          CALL TRANSACTION 'CO03' AND SKIP FIRST SCREEN.  
      ENDCASE.  
  ENDCASE.  
ENDFORM.

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70]: /images/20220411/811894b2fa5e46cface447b0a6a14b75.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70 1]: /images/20220411/762e6320b29f4adc857f8b1de08e7e68.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2l0eWFuZ2ppYQ_size_16_color_FFFFFF_t_70 2]: /images/20220411/163786ce8e05435db19ce0b1ffff4108.png