WMI 入门

淩亂°似流年 2022-05-20 04:36 291阅读 0赞

转载自：https://blog.csdn.net/qq\_16072507/article/details/54970830

## 什么是 WMI？ ##

WMI最初于 1998 年作为一个附加组件与 Windows NT 4.0 Service Pack 4 一起发行，是内置在 Windows 2000、Windows XP 和 Windows Server 2003 系列操作系统中核心的管理支持技术。基于由 Distributed Management Task Force (DMTF) 所监督的业界标准，WMI 是一种规范和基础结构，通过它可以访问、配置、管理和监视所有的 — 几乎所有的 Windows 资源。

要掌握 WMI 的强大功能和范围，需要考虑以前（或者现在）如何管理并监视 Windows 工作站和服务器。您可能用过或仍在使用众多的图形化管理工具来管理 Windows 资源 — 例如磁盘、事件日志、文件、文件夹、文件系统、网络组件、操作系统设置、性能数据、打印机、进程、注册表设置、安全性、服务、共享、用户、组等等。

尽管图形化工具提供了一种功能管理解决方案，它们所共有的东西是什么呢？一种答案是，在 WMI 之前，所有的 Windows 图形化管理工具都依赖于 Win32 应用程序编程接口（Application Programming Interfaces，APIs）来访问和管理 Windows 资源。为什么？因为在 WMI 之前，能够以编程方式访问 Windows 资源的惟一方法就是通过 Win32 API。这种情况使 Windows 系统管理员无法通过一种简便的方法利用常见的脚本语言来自动化常用的系统管理任务，因为大多数脚本语言都不能直接调用 Win32 API。通过提供一致的模型和框架，WMI 改变了这种情况 — 通过模型和框架，所有的 Windows 资源均被描述并公开给外界。最好的一点是，系统管理员可以使用 WMI 脚本库创建系统管理脚本，从而管理任何通过 WMI 公开的 Windows 资源！

使用 Windows Script Host 和 Microsoft Visual Basic Scripting Edition (VBScript)，或任何支持 COM 自动化的脚本语言（例如，ActiveState Corporation 的 ActivePerl），可以编写脚本来管理和自动化企业系统、应用程序和网络的下列方面：

## 快速启动到 WMI 脚本 ##

为了让您对 WMI 脚本是什么有一些概念，让我们来看看一个表面看来不怎么重要的任务 — 检索安装在基于 Windows 的远程计算机中的物理内存的总量。在 WMI 之前，如果没有另外的第三方工具，是不能通过一个脚本来轻松完成这个任务的。实际上，在 WMI 之前，使用包括操作系统工具的工具确定安装在计算机中内存数量的惟一方法是通过系统属性对话框。今天，如果目标计算机上安装了 WMI，并且有计算机的管理员访问权限，您就可以使用一个 WMI 脚本来检索在远程 Windows 计算机上安装的物理内存量，如清单 1 中所示的一样简单。

清单 1：使用 WMI 和 VBScript 检索总物理内存

strComputer = "atl-dc-01"
    
    Set wbemServices = Getobject("winmgmts:\\" & strComputer)
    Set wbemObjectSet = wbemServices.InstancesOf("Win32_LogicalMemoryConfiguration")
    
    For Each wbemObject In wbemObjectSet
         WScript.Echo "Total Physical Memory (kb): " & wbemObject.TotalPhysicalMemory
    Next

要运行清单 1 中的示例脚本，将其复制并粘贴到您最常用的文本编辑器中（notepad.exe 也可以），将分配给 strComputer 变量的值更改为域中一个有效的启用 WMI 的计算机，保存脚本（扩展名为 .vbs），并如图 1 所示运行脚本。

![scripting06112002\_fig1][scripting06112002_fig1]

图 1：GetMemory.vbs 输出

有点不可思议，无须任何录入，您应该会看到目标计算机的物理内存量回显到控制台。

现在，在你说“天哪！真的用六行脚本来检索一台计算机中的内存数量？”之前，让我们先礼貌地插几句话，因为至今尚不明显的是，您可以使用与在清单 1 中所演示的相同的基本步骤，从任何通过 WMI 公开的 Windows 资源检索配置和状态信息。

假设您想要检索安装在一台远程计算机上的所有服务的名称、状态和启动类型。清单 2 中的示例脚本完全使用清单 1 中使用过的相同的基本步骤来完成。

清单 2：使用WMI 和 VBScript 检索服务信息

strComputer = "atl-dc-01"
    
    Set wbemServices = Getobject("winmgmts:\\" & strComputer)
    Set wbemObjectSet = wbemServices.InstancesOf("Win32_Service")
    
    For Each wbemObject In wbemObjectSet
         WScript.Echo "Display Name:   " & wbemObject.DisplayName & vbCrLf & _
                      "    State:       " & wbemObject.State        & vbCrLf & _
                      "    Start Mode: " & wbemObject.StartMode
    Next

运行清单 2 生成如图 2 中所示的输出。

![scripting06112002\_fig2][scripting06112002_fig2]

图 2：GetServices.vbs 输出

假设您对服务不感兴趣，但是需要从 Windows 事件日志检索记录。再次使用清单 1 中的脚本模板，您可以很容易地读取 Windows 事件日志，如清单 3 中所演示。在您运行清单 3 之前我们要指出的是，如果您的事件日志包含数千个记录，示例脚本可能需要用很长的时间运行。

清单 3：读取 Windows 事件日志记录

strComputer = "atl-dc-01"
    
    Set wbemServices = Getobject("winmgmts:\\" & strComputer)
    Set wbemObjectSet = wbemServices.InstancesOf("Win32_NTLogEvent")
    
    For Each wbemObject In wbemObjectSet
         WScript.Echo "Log File:         " & wbemObject.LogFile         & vbCrLf & _
                      "Record Number:    " & wbemObject.RecordNumber    & vbCrLf & _
                      "Type:             " & wbemObject.Type            & vbCrLf & _
                      "Time Generated:   " & wbemObject.TimeGenerated   & vbCrLf & _
                      "Source:           " & wbemObject.SourceName      & vbCrLf & _
                      "Category:         " & wbemObject.Category        & vbCrLf & _
                      "Category String: " & wbemObject.CategoryString & vbCrLf & _
                      "Event:            " & wbemObject.EventCode       & vbCrLf & _
                      "User:             " & wbemObject.User            & vbCrLf & _
                      "Computer:         " & wbemObject.ComputerName    & vbCrLf & _
                      "Message:          " & wbemObject.Message         & vbCrLf
    Next

如果我们仔细检查清单 1、2 和 3，我们会得出关于这三个脚本的两个非常重要的观察结果。第一个观察结果是，所有三个脚本都执行相同的三个步骤：脚本连接到 WMI，检索一个 WMI 托管资源，并回显资源的几个属性。第二个重要的观察结果是，在每个脚本中，惟一的更改是标识目标资源的类名（即分别为 Win32\_LogicalMemoryConfiguration、Win32\_Service 和 Win32\_NTLogEvent），以及资源的相应属性。

脚本中使用的三个步骤，对于任何用于检索 WMI 托管资源信息的 WMI 脚本来说是共同的。让我们稍详细一些地看一下每个步骤。

#### 步骤 1：连接到 WMI 服务 ####

在任何 WMI 脚本中，第一个步骤都是建立一个到目标计算机上的 Windows 管理服务的连接。连接到在本地或远程计算机上的 WMI 与调用 VBScript 的 Getobject 函数并将 WMI 脚本库的名字对象的名称（即“winmgmts:”，后跟目标计算机的名称）传递到 Getobject 一样简单。

用这种方法连接到 WMI，返回一个对 SWbemServices 对象的引用，我们使用清单 1、2、3 中的名为 wbemServices 的变量来引用该对象。SWbemServices 是在 WMI 脚本库中定义的一打左右的对象中的一个。WMI 脚本库提供一组用于访问 WMI 基础结构的通用对象脚本。一旦有一个对 SWbemServices 对象的引用，您就可以调用任何提供了 SWbemServices 的方法；InstancesOf 就是此种方法中的一个。

#### 步骤 2：检索 WMI 托管资源的实例 ####

普遍认为，第二个步骤主要取决于要执行的任务。在检索 WMI 托管资源的信息中，步骤 2 与调用 SWbemServices 对象的 InstancesOf 方法一样简单。正如方法名所示，InstancesOf 返回由资源的类名标识的托管资源的所有实例。InstancesOf 以一个 SWbemObjectSet 集合的形式返回所需的资源，通过使用名为 wbemObjectSet 的变量我们在清单 1、2、3 中引用它。SWbemObjectSet 是 WMI 脚本库中定义的另一个脚本对象。

#### 步骤 3：显示 WMI 托管资源的属性 ####

最后一个步骤是枚举 SWbemObjectSet 集合的内容。SWbemObjectSet 中的每个项都是一个 SWbemObject（WMI 脚本库中的另外一个对象） — 表示所需资源的一个单个实例。使用 SWbemObject 来访问托管资源类定义中定义的方法和属性。

那么，如果从 WMI 检索信息的脚本编写步骤都是相同的，Win32\_LogicalMemoryConfiguration、Win32\_Service 和 Win32\_NTLogEvent 类是什么呢？此外，它们来自哪里？哪些其他的类是可用的？还有，如何使用它们？这些问题的答案分散在构成 WMI 体系结构的各组件中。让我们来看一下。

### WMI 体系结构 ###

WMI 体系结构由三个主层组成，如图 3 所示：

*  托管资源
 *  WMI 基础结构
 *  使用者

![scripting06112002\_fig3][scripting06112002_fig3]

图 3 ： WMI 体系结构

我们将从最低层开始，因为资源是驻留在那里的。

### 托管资源 ###

托管资源是任意逻辑或物理组件，通过使用 WMI 进行公开和管理。可以使用 WMI 管理的 Windows 资源包括：计算机系统、磁盘、外围设备、事件日志、文件、文件夹、文件系统、网络组件、操作系统子系统、性能计数器、打印机、进程、注册表设置、安全性、服务、共享、SAM 用户和组、Active Directory、Windows 安装程序、Windows 驱动程序模式 (WDM) 设备驱动程序，以及 SNMP 管理信息基 (MIB) 数据等。WMI 托管资源通过一个提供程序与 WMI 通讯。当开始编写脚本来与 WMI 托管资源交互时，您经常会看到一个术语实例，它被用于引用在运行中的脚本中的托管资源的虚拟表示形式。

### WMI 基础结构 ###

中间层是 WMI 基础结构。WMI 由三个主要组件构成：公共信息模型对象管理器（Common Information Model Object Manager，CIMOM）、公共信息模型（Common Information Model，CIM）储存库，以及提供程序。这三个 WMI 组件共同提供通过其定义、公开、访问和检索配置和管理数据的基础结构。虽然小，但是对编写脚本来说绝对不可或缺的第四个组件是 WMI 脚本库。

#### WMI 提供程序 ####

WMI 提供程序在 WMI 和托管资源之间扮演着中间方的角色。提供程序代表使用者应用程序和脚本从 WMI 托管资源请求信息，并发送指令到 WMI 托管资源。例如，清单 1 和清单 2 使用内置 Win32 提供程序来检索内存和服务相关信息。清单 3 使用内置的事件日志提供程序来从 Windows 事件日志检索记录。

通过将托管资源公开给基于 WMI 标准的、统一访问模型的 WMI 基础结构，提供程序隐藏托管资源独有的实现详细信息。WMI 提供程序使用托管资源本机 API 与其相应的托管资源通讯，使用 WMI 编程接口与 CIMOM 通讯。例如，内置的事件日志提供程序调用 Win32 事件日志 API 来访问事件日志。

基于 WMI 的可扩展体系结构，软件开发人员可以开发并集成附加提供程序来公开其产品特有的管理函数。监视 Exchange 连接器状态的 Exchange Server 2000 提供程序就是一个这样的示例。同样，Application Center、Operations Manager、Systems Management Server、Internet Information Server 和 SQL Server 都包含 WMI 提供程序。

提供程序通常作为驻留在 %SystemRoot%\\system32\\wbem 目录中的动态链接库 (DLL) 实现。WMI 包括很多针对Windows 2000、Windows XP 以及 Windows Server 2003 系列操作系统的内置提供程序。内置提供程序（也被称为标准提供程序），从已知的操作系统源（如 Win32 子系统、事件日志、性能计数器、注册表等）提供数据和管理函数。表 1 中列出一些包含在 Windows 2000、Windows XP 和 Windows Server 2003 系列操作系统中的 WMI 提供程序。

<table style="border-spacing:0px;color:rgb(51,51,51);font-family:'-apple-system', 'SF UI Text', Arial, 'PingFang SC', 'Hiragino Sans GB', 'Microsoft YaHei', 'WenQuanYi Micro Hei', sans-serif, SimHei, SimSun;font-size:14px;background-color:rgb(255,255,255);"> 
 <tbody> 
 <tr> 
 <th>提供程序</th> 
 <th>DLL</th> 
 <th>命名空间</th> 
 <th>说明</th> 
 </tr> 
 <tr> 
 <td>Active Directory 提供程序</td> 
 <td>dsprov.dll</td> 
 <td>root\directory\ldap</td> 
 <td>将 Active Directory 对象映射到 WMI。</td> 
 </tr> 
 <tr> 
 <td>事件日志提供程序</td> 
 <td>ntevt.dll</td> 
 <td>root\cimv2</td> 
 <td>管理 Windows 事件日志，例如，读取、备份、清除、复制、删除、监视、重命名、压缩、解压缩和更改事件日志设置。</td> 
 </tr> 
 <tr> 
 <td>性能计数器提供程序</td> 
 <td>wbemperf.dll</td> 
 <td>root\cimv2</td> 
 <td>提供对原始性能数据的访问。</td> 
 </tr> 
 <tr> 
 <td>注册表提供程序</td> 
 <td>stdprov.dll</td> 
 <td>root\default</td> 
 <td>读取、写入、枚举、监视、创建、删除注册表项和值。</td> 
 </tr> 
 <tr> 
 <td>SNMP 提供程序</td> 
 <td>snmpincl.dll</td> 
 <td>root\snmp</td> 
 <td>提供对 SNMP MIB 数据的访问，并从 SNMP 托管设备捕获。</td> 
 </tr> 
 <tr> 
 <td>WDM 提供程序</td> 
 <td>wmiprov.dll</td> 
 <td>root\wmi</td> 
 <td>提供对 WDM 设备驱动程序中信息的访问。</td> 
 </tr> 
 <tr> 
 <td>Win32 提供程序</td> 
 <td>cimwin32.dll</td> 
 <td>root\cimv2</td> 
 <td>提供关于计算机、磁盘、外围设备、文件、文件夹、文件系统、网络组件、操作系统、打印机、进程、安全性、服务、共享、SAM 用户及组，以及更多资源的信息。</td> 
 </tr> 
 <tr> 
 <td>Windows 安装程序提供程序</td> 
 <td>msiprov.dll</td> 
 <td>root\cimv2</td> 
 <td>提供对已安装软件信息的访问。</td> 
 </tr> 
 </tbody> 
</table>

Windows XP 和 Windows Server 2003 包含很多附加的标准提供程序。如需标准提供程序的完整列表，参见 WMI Software Developers Kit (SDK) 文档中的[ WMI 提供程序][WMI]参考。

#### CIMOM ####

CIMOM（读作 see-mom）处理使用者和提供程序之间的交互。这一术语是来自于基于 Web 的企业管理软件和由 [Distributed Management Task Force][] 维护的公共信息模型规范。

您可以将 CIMOM 想象为 WMI 信息代理。所有的 WMI 请求和数据都经过 CIMOM。Windows Management Instrumentation 服务 (winmgmt.exe)，在 Windows XP 和 Windows Server 系列操作系统上提供了 CIMOM 角色，在通用服务主机进程 (svchost.exe) 的控制下运行。

注 在运行 Windows 2000 或 Windows NT 4.0 Service Pack 4 的计算机上，WMI 服务作为一个单独的服务进程运行。在运行 Windows Millennium Edition (Me)、Windows 98 或 Windows 95 OSR 2.5 的计算机上，WMI 作为一个标准可执行进程运行。

除了提供公共接口（使用者通过它访问 WMI）之外，CIMOM 还向 WMI 基础结构提供下列核心服务：

*  提供注册。WMI 利用 CIMOM 提供注册位置和功能信息。此信息存储在 CIM 储存库中。
 *  请求传送。CIMOM 使用提供程序注册信息，将使用者请求传送到合适的提供程序。
 *  远程访问。使用者通过连接到远程系统上的 CIMOM 访问启用 WMI 的远程系统。一旦连接建立，使用者可以执行与在本地可以执行的操作相同的操作。
 *  安全性。在本地计算机或是远程计算机上，允许用户在连接到 WMI 之前通过验证每个用户的访问标记，CIMOM 控制对 WMI 托管资源的访问。WMI 并不覆盖或阻止由操作系统提供的安全性。
 *  查询处理。允许使用者使用 WMI 查询语言（WMI Query Language，WQL）发出关于任何 WMI 托管资源的查询。例如，您可以查询所有发生在过去 24 小时的，符合一个特定事件 ID 的事件的事件日志。CIMOM 只在提供程序本身不支持查询操作的情况下执行查询计算。
 *  事件处理。允许使用者订阅表示对 WMI 托管资源更改的事件。例如，您可以订阅表明逻辑磁盘驱动器上的空间何时下降到可接受的阈值以下的事件。CICOM 按一个指定的间隔轮询托管资源，并在满足订阅条件时生成一个事件通知。

管理应用程序、管理工具和脚本调入 CIMOM 以挖掘数据、订阅事件或执行一些其他的与管理相关的任务。CIMOM 获得必需的提供程序和类信息以满足来自 CIM 的使用者的请求。CIMOM 使用从 CIM 获得的信息，将使用者的请求传递到合适的提供程序。

#### CIM 储存库 ####

WMI 的基本思想是 — 可以用一个架构统一表示来自不同源的配置和管理信息。CIM 就是这个架构，还调用了模型化托管环境和定义每个由 WMI 公开的数据块的对象储存库或类存储。该架构基于 [DMTF 公共信息模型标准][DMTF]。

与建立在类概念基础上的 Active Directory 的架构非常相似，CIM 由类 组成。类是一个 WMI 托管资源的一个蓝图。然而，不同于 Active Directory 类表示创建并存储在目录中的对象，CIM 类通常表示动态资源。就是说，资源的实例并不存储在 CIM 中，而是通过基于使用者请求的提供程序动态检索。其原因很简单，大多数 WMI 托管资源的操作状态更改很频繁，因而必须按需读取以确保检索的是最新的信息。

注 在 CIM 的上下文中，储存库这一术语有些被误解。尽管 CIM 是一个储存库，而且能够存储静态数据，但其主要角色是存储托管资源的蓝图。

与 Active Directory 类相似之处还有就是，CIM 类是分级组织的，每一级的子类从父类继承。DMTF 维护一组核心和公共基类，系统和应用程序软件开发人员（如 Microsoft 的那些）从这些类派生和创建系统（或应用程序）特定的扩展类。

类被分组到命名空间 中，命名空间是表示一个特定的管理区域的类逻辑组。例如，命名空间 root\\cimv2 包括大部分表示通常与计算机和操作系统相关联的资源的类。在前面的脚本中使用的类（Win32\_LogicalMemoryConfiguration、Win32\_Service 和Win32\_NTLogEvent）驻留在命名空间 root\\cimv2，它们只是在 CIM 中定义的数百个类中的三个。

CIM 类由属性和方法构成。属性描述 WMI 托管资源的配置和状态，方法是在 WMI 托管资源上执行操作的可执行函数。

注 不要将由 CIM 定义的方法和属性与由 WMI 脚本库中的自动化对象提供的方法和属性相混淆。

从物理校对看，CIM 驻留在 %SystemRoot%\\system32\\wbem\\Repository\\FS\\ 目录中，由下列 4 个文件组成：

*  index.btr。二叉树 (btree) 索引文件。
 *  index.map。事务控制文件。
 *  objects.data。存储托管资源定义的 CIM 储存库。
 *  objects.map。事务控制文件。

注 在 Microsoft Windows 2000 和 Windows NT 4.0 Service Pack 4 中，CIM 存储在 %SystemRoot%\\system32\\wbem\\Respository\\cim.rep 中。在 Windows Millennium Edition (Me)、Windows 98 和 Windows 95 OSR 2.5 操作系统中，CIM 存储在 %windir%\\system\\wbem\\Respository\\cim.rep 中。

虽然 CIM 基于面向对象的设计原则，但是您无须成为信息建模或架构设计的专家，就可以有效地使用 WMI 并编写基于 WMI 的脚本。重要的是您了解 CIM 的基础结构和组织，并了解如何浏览和解释它的内容。

#### WMI 脚本库 ####

WMI 脚本库提供自动化对象集，脚本语言（如 VBScript、Jscript 及 ActiveState 的 ActivePerl）利用它访问 WMI 基础结构。

WMI 脚本库中的自动化对象为 WMI 基础结构提供一个一致且统一的脚本模型。如前面所示，一旦您了解如何使用 WMI 脚本库检索一个托管资源类型，您就可以轻松使用相同的步骤来检索其它的 WMI 托管资源。例如，您可以使用前面列出的 3 个脚本中的任何一个，并很容易地修改这个脚本来检索在远程计算机上运行的进程 (Win32\_Process) 信息、处理器 (Win32\_Processor) 信息、操作系统 (Win32\_OperatingSystem) 信息，或者由 WMI 公开的数百个托管资源中的任何一个。

WMI 脚本库在一个名为 wbemdisp.dll 的单个 DLL 中实现，该 DLL 物理驻留于 %SystemRoot%\\system32\\wbem 目录中。WMI 脚本库还包括一个名为 wbemdisp.tlb 的类型库。您可以使用 WMI 脚本类型库来从基于 XML 的 Windows 脚本文件（扩展名为 .wsf 的 WSH 脚本）引用 WML 常数。

#### WMI 使用者 ####

使用者是顶层。使用者是脚本、企业管理应用程序、基于 Web 的应用程序，或其他管理工具，它们通过 WMI 基础结构访问并控制可用信息。

注 很多管理应用程序担当 WMI 使用者和 WMI 提供程序的双重角色。有数种 Microsoft 管理产品都属于这种情况，如 Application Center、Operations Manager 以及 Systems Management Server。

### 浏览 CIM ###

我们已经讨论了相当一部分的内容，但是还留有一个细节没有谈到，那就是如何确定哪些资源是通过 WMI 公开的。幸运的是，您可以使用多种不同工具来浏览 CIM 架构并检查 WMI 托管资源的类定义。

*  WMI 控件。WMI 控件 (wmimgmt.msc) 是一个 Microsoft 管理控制台 (MMC) 管理单元，它允许您在本地或远程计算机上配置 WMI 设置。尽管您不能使用 WMI 控件浏览 CIM，但是可以使用该工具的“安全性”选项卡来确定在本地或远程计算机上可用的 CIM 命名空间。有关更多使用 WMI 控件的信息，参阅 Windows 2000 帮助或 Windows XP 帮助和支持中心内的 WMI 控件概述。
 *  WMI 测试器。WMI 测试器 (wbemtest.exe) 是一个用于与 WMI 基础结构交互的通用、图形化工具。您可以使用 WMI 测试器来浏览 CIM 架构并检查托管资源类定义。WMI 测试器还可用于执行与基于 WMI 的脚本执行的相同的操作，例如检索托管资源的实例和运行查询。WMI 测试器是在所有启用了 WMI 的计算机上默认的 WMI 安装的一部分，因此 wbemtest.exe 是一个出色的 WMI 学习和疑难解答工具。有关使用 WMI 测试器的信息，参阅 Windows XP 帮助和支持中心内的 WMI 测试器概述。
 *  WMI 命令行。作为 Windows XP 的一部分发布的 WMI 命令行工具 (wmic.exe) 提供一个到 WMI 基础结构的命令行接口。可以使用 wmic.exe 执行来自命令行的常见 WMI 任务，包括浏览 CIM 和检查 CIM 类定义。有关使用 WMI 命令行工具的信息，参阅 Windows XP 帮助和支持中心内的“使用 WMI 命令行 (WMIC) 工具”
 *  CIM Studio。作为 WMI SDK 的一部分，CIM Studio 提供一个基于 Web 的界面实现与 WMI 基础结构交互。与 WMI 测试器一样，您可以使用 CIM Studio 来浏览 CIM 架构、查看类定义并检索托管资源的实例。通过 CIM Studio 的超级用户界面可轻松查看类关系和关联，而且 CIM Studio 提供一个基本的搜索工具 — 它们是 WMI 测试器工具所不具备的两个功能。要使用 CIM Studio，您必需下载并安装 WMI SDK。您可以从 [Windows Management Instrumentation (WMI) SDK][Windows Management Instrumentation _WMI_ SDK] 下载 WMI SDK。
 *  EnumClasses.vbs 和 EnumInstances.vbs。Windows 2000 Server 资源工具箱包括很多利用了 WMI 的强大功能的脚本。这里所列出的三个脚本是常见脚本，可用于浏览 CIM 架构、查看类定义以及检索托管资源的实例。

您应该查看的一些附加资源包括：

*  WMI SDK 文档。WMI SDK 包含一个由标准的 WMI 提供程序提供的类的完整列表。您可以访问 MSDN 联机库中的 [WMI SDK 文档][WMI SDK]。
 *  TechNet 脚本中心。如果您愿意，可以把它叫做无用的废物，但是[TechNet 脚本中心][TechNet]包含数百个来自即将推出的 System Administration Scripting Guide 中的基于 WMI 的示例脚本。

#### WMI 测试器 (wbemtest.exe) 演练 ####

现在，您对可用于浏览和查看 CIM 的工具已经有了一些认识，让我们使用 WMI 测试器 (wbemtest.exe) 来检查 Win32\_Process 类定义并修改清单 2，以便从在您的本地计算机上运行的进程检索一些属性。

1.  打开一个命令提示，键入 C:\\>wbemtest.exe，按下 Enter 来开始 WMI 测试器工具。请注意，大部分按钮在主 WMI 测试器窗口上是被禁用的，这说明此时您没有连接到 WMI。
2.  单击 Connect? 连接到本地或远程计算机上的 WMI 服务。显示“连接”对话框，它提供一个标记为 Namespace 的文本输入区域，该区域默认值为 root\\default。将 Namespace 区域的值更改为 root\\cimv2，单击“连接”对话框的 Connect 按钮返回到主 WMI 测试器窗口。
3.  主窗口中左上角的命名空间标识符应该显示为 root\\cimv2。请注意，所有的按钮现在都已启用，这说明在当前凭据环境下，您已经成功连接到本地主机上的 WMI。单击 Enum Classes? 打开“超类信息”对话框。
4.  在“超类信息”对话框中，不要填写 Enter superclass name 区域，单击 Recursive 选项，单击 OK 以枚举 root\\cimv2 名称空间中定义的所有 CIM 类。
    
    此时，您可能应该正在查看一个列出了数百个类定义的“查询结果”对话框。类的数量主要取决于您正在运行的 Windows 的版本。例如，如果使用 Windows 2000，则您应该会看到大约 600 个类定义。如果运行 Windows XP，则您应该会看到大约 900 个类定义。
    
    请注意，列于“查询结果”对话框顶部的类是以两个下划线为开头的。这些是系统类。系统类是预定义的 CIM 类，支持内部 WMI 配置与操作，例如提供程序注册、命名空间安全性及事件通知等。现在，忽略系统类，向下滚动“查询结果”对话框直至看到以 CIM\_ 开头的类。
    
    名称以 CIM\_ 开头的类是由 DMTF 维护的核心与公共基类。继续向下滚动直至到达以 Win32\_ 开头的类。
    
    名称以 Win32\_ 开头的类是 Microsoft 扩展类，表示 Windows 特定的托管资源。如果这是您第一次检查 root\\cimv2 命名空间，您可能希望熟悉 root\\cimv2 命名空间中的类的完整集合，尤其是有 Win32\_ 前缀的类。
5.  向下滚动“查询结果”对话框直至到达 Win32\_Process 类，双击该类名打开 Win32\_Process 对话框的对象编辑器。
6.  “对象编辑器”对话框显示被选定类的定义和实现的详细信息（属性和方法）。回忆一下我们之前讨论的内容 — 类定义是 WMI 可管理资源的蓝图。
    
    选择 Hide System Properties 复选框隐藏系统属性。剩余的 Win32\_Process 属性表示您可以从在本地或远程计算机上运行的进程检索的信息。
    
    要完成您的 WMI 脚本练习，尝试去检索 Name、Handle 和 ProcessID 属性。使用前面的三个清单之一作为模板，试着在进行到第 7 步之前运行脚本。
    
    注 要在本地计算机上运行脚本，将 strComputer 变量的值设置为“.”（引号内的一个单点）。
7.  在运行新创建的 GetProcesses.vbs 脚本之后，您可以用 WIMI 测试器验证脚本的结果。在 Win32\_Process 对话框的对象编辑器中，单击 Instances。产生的查询结果对话框列出在计算机上运行的进程的实例。双击一个指定的进程实例，查看该实例的详细信息。

### 就到这里吧 ###

诚然，我们只是触及了 WMI 脚本撰写的表层。十分坦诚地说，这是有意的。WMI 提供了如此之多的脚本编写的可能性，因此很容易造成“只见树木，不见森林”的结果。不过不要担心，随着本系列内容的展开，我们将填补所有的缺口。此时要提炼出的重要内容是：WMI 是 Windows 中单独的、最重要的管理支持技术，您无需成为开发人员或者脚本编写权威就可以开始编写基于 WMI 的脚本。继续修改您新创建的脚本以检索另外的进程属性，或再进一步 — 检索其他托管资源。在我们下个月见面之前，您可能发现自己有了一个满是自定义的系统管理脚本的工具箱。让我们知道您做得到底怎么样。

清单 4 ： WMI 测试器演练的答案

strComputer = "."   ' Dot (.) equals local computer in WMI  
  
Set wbemServices = Getobject("winmgmts:\\\\" & strComputer)  
Set wbemObjectSet = wbemServices.InstancesOf("Win32\_Process")  
  
For Each wbemObject In wbemObjectSet  
    WScript.Echo "Name:          " & wbemObject.Name      & vbCrLf & \_  
                 "   Handle:     " & wbemObject.Handle    & vbCrLf & \_  
                 "   Process ID: " & wbemObject.ProcessID  
Next

[scripting06112002_fig1]: http://www.microsoft.com/china/MSDN/library/enterprisedevelopment/softwaredev/art/scripting06112002_fig1.gif
[scripting06112002_fig2]: http://www.microsoft.com/china/MSDN/library/enterprisedevelopment/softwaredev/art/scripting06112002_fig2.gif
[scripting06112002_fig3]: /images/20220520/99e55ab97173477d9c4696280b232b21.png
[WMI]: http://msdn.microsoft.com/library/en-us/wmisdk/wmi/wmi_providers.asp
[Distributed Management Task Force]: http://www.dmtf.org/
[DMTF]: http://www.dmtf.org/standards/standard_cim.php
[Windows Management Instrumentation _WMI_ SDK]: http://msdn.microsoft.com/library/default.asp?url=/downloads/list/wmi.asp
[WMI SDK]: http://msdn.microsoft.com/library/en-us/wmisdk/wmi/wmi_start_page.asp
[TechNet]: http://www.microsoft.com/technet/community/scriptcenter/default.mspx