Neo4j：Cypher查询入门

Love The Way You Lie 2022-06-04 04:44 202阅读 0赞

Neo4j使用Cypher查询图形数据，Cypher是描述性的图形查询语言，语法简单，功能强大，由于Neo4j在图形数据库家族中处于绝对领先的地位，拥有众多的用户基数，使得Cypher成为图形查询语言的事实上的标准。本文作为入门级的教程，我不会试图分析Cypher语言的全部内容，本文的目标是循序渐进地使用Cypher语言执行简单的CRUD操作，为了便于演示，本文在Neo4j Browser中执行Cypher示例代码。以下图形包含三个节点和两个关系，本文会一步一步讲解如何利用Cypher语言创建以下图形。

![628084-20170519164108432-1746174343.png][]

我的Neo4j系列的文章收录在：[Neo4j][]

一，easy，热热身

和SQL很相似，Cypher语言的关键字不区分大小写，但是属性值，标签，关系类型和变量是区分大小写的。

1，变量（Variable）

变量用于对搜索模式的部分进行命名，并在同一个查询中引用，在小括号()中命名变量，变量名是区分大小写的，示例代码创建了两个变量：n和b，通过return子句返回变量b；

MATCH (n)-->(b)
    RETURN b

在Cypher查询中，变量用于引用搜索模式（Pattern），但是变量不是必需的，如果不需要引用，那么可以忽略变量。

2，访问属性

在Cypher查询中，通过逗号来访问属性，格式是：Variable.PropertyKey，通过id函数来访问实体的ID，格式是id(Variable)。

match (n)-->(b)
    where id(n)=5 and b.age=18
    return b;

二，创建节点

节点模式的构成：(Variable:Lable1:Lable2\{Key1:Value1,Key2,Value2\})，实际上，每个节点都有一个整数ID，在创建新的节点时，Neo4j自动为节点设置ID值，在整个数据库中，节点的ID值是递增的和唯一的。

下面的Cypher查询创建一个节点，标签是Person，具有两个属性name和born，通过RETURN子句，返回新建的节点：

create (n:Person { name: 'Tom Hanks', born: 1956 }) return n;

![628084-20170519164410228-217751375.png][]

继续创建其他节点：

create (n:Person { name: 'Robert Zemeckis', born: 1951 }) return n;
    create (n:Movie { title: 'Forrest Gump', released: 1951 }) return n;

三，查询节点

通过match子句查询数据库，match子句用于指定搜索的模式（Pattern），where子句为match模式增加谓词（Predicate），用于对Pattern进行约束；

1，查询整个图形数据库

match(n) return n;

在图形数据库中，有三个节点，Person标签有连个节点，Movie有1个节点

![628084-20170519164808260-281608105.png][]

点击节点，查看节点的属性，如图，Neo4j自动为节点设置ID值，本例中，Forrest Gump节点的ID值是5，

![628084-20170519164934416-1792994304.png][]

2，查询born属性小于1955的节点

match(n) 
    where n.born<1955 
    return n;

![628084-20170519165246369-1977734334.png][]

3，查询具有指定Lable的节点

match(n:Movie) 
    return n;

![628084-20170519165345447-1527377171.png][]

4，查询具有指定属性的节点

match(n{name:'Tom Hanks'}) 
    return n;

![628084-20170519165553353-1221761470.png][]

四，创建关系

关系的构成：StartNode \- \[Variable:RelationshipType\{Key1:Value1,Key2:Value2\}\] \-> EndNode，在创建关系时，必须指定关系类型。

1，创建没有任何属性的关系

MATCH (a:Person),(b:Movie)
    WHERE a.name = 'Robert Zemeckis' AND b.title = 'Forrest Gump'
    CREATE (a)-[r:DIRECTED]->(b)
    RETURN r;

![628084-20170519170338713-1562983462.png][]

2，创建关系，并设置关系的属性

MATCH (a:Person),(b:Movie)
    WHERE a.name = 'Tom Hanks' AND b.title = 'Forrest Gump'
    CREATE (a)-[r:ACTED_IN { roles:['Forrest'] }]->(b)
    RETURN r;

![628084-20170519170129228-858101407.png][]

五，查询关系

在Cypher中，关系分为三种：符号“--”，表示有关系，忽略关系的类型和方向；符号“-->”和“<--”，表示有方向的关系；

1，查询整个数据图形

![628084-20170519170741463-1455419525.png][]

2，查询跟指定节点有关系的节点

示例脚本返回跟Movie标签有关系的所有节点

match(n)--(m:Movie) 
    return n;

![628084-20170519170937275-1539723581.png][]

2，查询有向关系的节点

MATCH (:Person { name: 'Tom Hanks' })-->(movie)
    RETURN movie;

![628084-20170519171232978-1077893210.png][]

3，为关系命名，通过\[r\]为关系定义一个变量名，通过函数type获取关系的类型

MATCH (:Person { name: 'Tom Hanks' })-[r]->(movie)
    RETURN r,type(r);

![628084-20170519171440650-613518319.png][]

4，查询特定的关系类型，通过\[Variable:RelationshipType\{Key:Value\}\]指定关系的类型和属性

MATCH (:Person { name: 'Tom Hanks' })-[r:ACTED_IN{roles:'Forrest'}]->(movie)
    RETURN r,type(r);

![628084-20170519171720932-1997305387.png][]

六，更新图形

set子句，用于对更新节点的标签和实体的属性；remove子句用于移除实体的属性和节点的标签；

1，创建一个完整的Path

由于Path是由节点和关系构成的，当路径中的关系或节点不存在时，Neo4j会自动创建；

CREATE p =(vic:Worker:Person{ name:'vic',title:"Developer" })-[:WORKS_AT]->(neo)<-[:WORKS_AT]-(michael:Worker:Person { name: 'Michael',title:"Manager" })
    RETURN p

变量neo代表的节点没有任何属性，但是，其有一个ID值，通过ID值为该节点设置属性和标签

![628084-20170519172644525-1538391137.png][]

2，为节点增加属性

通过节点的ID获取节点，Neo4j推荐通过where子句和ID函数来实现。

match (n)
    where id(n)=7
    set n.name = 'neo'
    return n;

3，为节点增加标签

match (n)
    where id(n)=7
    set n:Company
    return n;

![628084-20170519173517119-1418894728.png][]

4，为关系增加属性

match (n)<-[r]-(m)
    where id(n)=7 and id(m)=8
    set r.team='Azure'
    return n;

![628084-20170519174113244-662479972.png][]

七，Merge子句

Merge子句的作用有两个：当模式（Pattern）存在时，匹配该模式；当模式不存在时，创建新的模式，功能是match子句和create的组合。在merge子句之后，可以显式指定on creae和on match子句，用于修改绑定的节点或关系的属性。

通过merge子句，你可以指定图形中必须存在一个节点，该节点必须具有特定的标签，属性等，如果不存在，那么merge子句将创建相应的节点。

1，通过merge子句匹配搜索模式

匹配模式是：一个节点有Person标签，并且具有name属性；如果数据库不存在该模式，那么创建新的节点；如果存在该模式，那么绑定该节点；

MERGE (michael:Person { name: 'Michael Douglas' })
    RETURN michael;

2，在merge子句中指定on create子句

如果需要创建节点，那么执行on create子句，修改节点的属性；

ERGE (keanu:Person { name: 'Keanu Reeves' })
    ON CREATE SET keanu.created = timestamp()
    RETURN keanu.name, keanu.created

3，在merge子句中指定on match子句

如果节点已经存在于数据库中，那么执行on match子句，修改节点的属性；

MERGE (person:Person)
    ON MATCH SET person.found = TRUE , person.lastAccessed = timestamp()
    RETURN person.name, person.found, person.lastAccessed

4，在merge子句中同时指定on create 和 on match子句

MERGE (keanu:Person { name: 'Keanu Reeves' })
    ON CREATE SET keanu.created = timestamp()
    ON MATCH SET keanu.lastSeen = timestamp()
    RETURN keanu.name, keanu.created, keanu.lastSeen

5，merge子句用于match或create一个关系

MATCH (charlie:Person { name: 'Charlie Sheen' }),(wallStreet:Movie { title: 'Wall Street' })
    MERGE (charlie)-[r:ACTED_IN]->(wallStreet)
    RETURN charlie.name, type(r), wallStreet.title

6，merge子句用于match或create多个关系

MATCH (oliver:Person { name: 'Oliver Stone' }),(reiner:Person { name: 'Rob Reiner' })
    MERGE (oliver)-[:DIRECTED]->(movie:Movie)<-[:ACTED_IN]-(reiner)
    RETURN movie

7，merge子句用于子查询

![复制代码][copycode.gif]

MATCH (person:Person)
    MERGE (city:City { name: person.bornIn })
    RETURN person.name, person.bornIn, city;
    
    MATCH (person:Person)
    MERGE (person)-[r:HAS_CHAUFFEUR]->(chauffeur:Chauffeur { name: person.chauffeurName })
    RETURN person.name, person.chauffeurName, chauffeur;
    
    MATCH (person:Person)
    MERGE (city:City { name: person.bornIn })
    MERGE (person)-[r:BORN_IN]->(city)
    RETURN person.name, person.bornIn, city;

![复制代码][copycode.gif]

八，跟实体相关的函数

1，通过id函数，返回节点或关系的ID

MATCH (:Person { name: 'Oliver Stone' })-[r]->(movie)
    RETURN id(r);

2，通过type函数，查询关系的类型

MATCH (:Person { name: 'Oliver Stone' })-[r]->(movie)
    RETURN type(r);

3，通过lables函数，查询节点的标签

MATCH (:Person { name: 'Oliver Stone' })-[r]->(movie)
    RETURN lables(movie);

4，通过keys函数，查看节点或关系的属性键

MATCH (a)
    WHERE a.name = 'Alice'
    RETURN keys(a)

5，通过properties()函数，查看节点或关系的属性

CREATE (p:Person { name: 'Stefan', city: 'Berlin' })
    RETURN properties(p)

参考文档：

[Chapter 3. Cypher][]

[3.3.16. MERGE][]

作者： [悦光阴][Link 1]

出处： [http://www.cnblogs.com/ljhdo/][Link 1]

本文版权归作者和博客园所有，欢迎转载，但未经作者同意，必须保留此段声明，且在文章页面醒目位置显示原文连接，否则保留追究法律责任的权利。

[628084-20170519164108432-1746174343.png]: /images/20220604/ac68b5ccc47045f0816134a833d28f89.png
[Neo4j]: http://www.cnblogs.com/ljhdo/category/998219.html
[628084-20170519164410228-217751375.png]: /images/20220604/7a30540d98ff4a33ac1f8463353bd054.png
[628084-20170519164808260-281608105.png]: /images/20220604/0bf3f74898814d93b7a4280ea2896f79.png
[628084-20170519164934416-1792994304.png]: /images/20220604/29770bece814411ca6786e3ba9b0254f.png
[628084-20170519165246369-1977734334.png]: /images/20220604/208638bd4f70443193aa20956bda3a40.png
[628084-20170519165345447-1527377171.png]: /images/20220604/6c138a6e957a46dbb7f25610699401f9.png
[628084-20170519165553353-1221761470.png]: /images/20220604/b33e525356084229b0d9f034c9bc5524.png
[628084-20170519170338713-1562983462.png]: /images/20220604/582b05372743407ea32d3a62f34ef11f.png
[628084-20170519170129228-858101407.png]: /images/20220604/02d340a6b7804e22a17f3972958c43eb.png
[628084-20170519170741463-1455419525.png]: /images/20220604/6ae9835b97c7426a9a4673a6e201b5c4.png
[628084-20170519170937275-1539723581.png]: /images/20220604/669c3b126aaf40dcaa5ad1106eceb46c.png
[628084-20170519171232978-1077893210.png]: /images/20220604/cc4f95b5e6054cf48956391787bde2af.png
[628084-20170519171440650-613518319.png]: /images/20220604/3efa0005234343849bf08168e214d2ed.png
[628084-20170519171720932-1997305387.png]: /images/20220604/9c3e95bc1dc14558b34edb922a9d9a5e.png
[628084-20170519172644525-1538391137.png]: /images/20220604/a1e6b1bbba094e9989adf030e39983be.png
[628084-20170519173517119-1418894728.png]: /images/20220604/f69741af9709405ea687989a1149f0c2.png
[628084-20170519174113244-662479972.png]: /images/20220604/99225f41d55944acb45b2d34e5306ff2.png
[copycode.gif]: /images/20220604/d9412af307a54104b61dc97ecf50b7eb.png
[Chapter 3. Cypher]: http://neo4j.com/docs/developer-manual/current/cypher/
[3.3.16. MERGE]: http://neo4j.com/docs/developer-manual/current/cypher/clauses/merge/
[Link 1]: http://www.cnblogs.com/ljhdo/