X264中的汇编：sad-a.asm——002

傷城~ 2022-06-10 08:30 202阅读 0赞

http://blog.csdn.net/xiaoyi247/article/details/7913360

版权声明：本文为博主原创文章，未经博主允许不得转载。

1.SAD即绝对误差和（sum of absolute differences),应用非常广泛，是一种测量两个图像块的差异的最简单的办法。顾名思义，其公式为：

![1346074892_4934.jpg][]

2.为什么要优化SAD

SAD在视频编解码中用处非常广泛，

1. intra预测中选择最佳划分，最佳预测方向

2. inter预测中选择最佳划分，运动搜索中对搜索结果的评判。

3. 作为rdo公式的失真项

![1346075931_6523.jpg][]

那为什么要优化sad呢？试想一下，每个宏块在进行intra预测的时候，会由16x16 8x8 4x4四类划分，4x4和8x8分别都有9中预测模式，每一种预测模式都要计算其sad。如果把每一种分块的模式都走完，sad的调用次数将是非常可观的。实际上sad或其类似[算法][Link 1]satd，ssd是整个编码算法中调用次数最多算法。

3.SIMD中的SAD

还好在intel的多媒体指令中，提供了sad的专用指令，可见sad的重要性。mmx和xmm中都提供了sad指令。一条指令可以做8个像素，或者更多像素的sad，大大提高了sad的运算效率。

4.SAD在x264中的实现代码可以在sad-a.asm中找到，下面对一些代码进行简单注释

;=============================================================================  
; SAD MMX  
;=============================================================================  
;两行16像素的sad，结果累加存入mm0中，参考8x8和4x4的代码分析  
%macro SAD\_INC\_2x16P 0  
    movq    mm1,    \[r0\]  
    movq    mm2,    \[r0+8\]  
    movq    mm3,    \[r0+r1\]  
    movq    mm4,    \[r0+r1+8\]  
    psadbw  mm1,    \[r2\]  
    psadbw  mm2,    \[r2+8\]  
    psadbw  mm3,    \[r2+r3\]  
    psadbw  mm4,    \[r2+r3+8\]  
    lea     r0,     \[r0+2\*r1\]  
    paddw   mm1,    mm2  
    paddw   mm3,    mm4  
    lea     r2,     \[r2+2\*r3\]  
    paddw   mm0,    mm1  
    paddw   mm0,    mm3  
%endmacro  
  
  
;两行8像素的sad，结果累加入mm0中  
%macro SAD\_INC\_2x8P 0  
;在r0中取8个像素放入mm132中  
    movq    mm1,    \[r0\]  
;在r0中取8个像素放入mm2中  
    movq    mm2,    \[r0+r1\]  
;mm1和r2进行SAD，结果存入mm1的低16bit中  
    psadbw  mm1,    \[r2\]  
;mm2和r2的下一行进行SAD，结果存入mm2中  
    psadbw  mm2,    \[r2+r3\]  
;r0指向下面两行  
    lea     r0,     \[r0+2\*r1\]  
;将结果累加到mm0  
    paddw   mm0,    mm1  
    paddw   mm0,    mm2  
;r2指向下面两行  
    lea     r2,     \[r2+2\*r3\]  
%endmacro  
  
  
  
  
;两行四个像素的sad，结果累加入mm0中  
%macro SAD\_INC\_2x4P 0  
;将r0中的4个像素放入mm1的低32位，r2中的4个像素放入mm2的低32位  
    movd    mm1,    \[r0\]  
    movd    mm2,    \[r2\]  
;从r0中继续取4个像素放入mm1的高32位，r2中继续取4个像素放入mm2的高32位  
    punpckldq mm1,  \[r0+r1\]  
    punpckldq mm2,  \[r2+r3\]  
;进行byte的SAD,并且将结果放入mm1的低16位中  
    psadbw  mm1,    mm2  
;累加SAD的值到mm0  
    paddw   mm0,    mm1  
;装入新的地址，开始下一次操作  
    lea     r0,     \[r0+2\*r1\]  
    lea     r2,     \[r2+2\*r3\]  
%endmacro  
  
  
;定义x264\_pixel\_sad\_16x16\_mmxext汇编函数  
;-----------------------------------------------------------------------------  
; int x264\_pixel\_sad\_16x16\_mmxext (uint8\_t \*, int, uint8\_t \*, int )  
;-----------------------------------------------------------------------------  
%macro SAD 2  
cglobal x264\_pixel\_sad\_%1x%2\_mmxext, 4,4  
    pxor    mm0, mm0  
%rep %2/2;一次做两行，所以这里必须/2  
    SAD\_INC\_2x%1P  
%endrep  
    movd    eax, mm0  
    RET  
%endmacro  
  
  
;定义16x16 16x8 8x16 8x8 8x4 4x8 4x4的使用mmx指令集的sad函数  
SAD 16, 16  
SAD 16,  8  
SAD  8, 16  
SAD  8,  8  
SAD  8,  4  
SAD  4,  8  
SAD  4,  4  
  
  
  
  
  
  
;=============================================================================  
; SAD XMM  
;=============================================================================  
  
  
%macro SAD\_END\_SSE2 0  
    movhlps m1, m0  
    paddw   m0, m1  
    movd   eax, m0  
    RET  
%endmacro  
  
  
; SAD\_W16指定使用SSE SSE2等指令集  
%macro SAD\_W16 1  
;-----------------------------------------------------------------------------  
; int x264\_pixel\_sad\_16x16\_sse2 (uint8\_t \*, int, uint8\_t \*, int )  
;-----------------------------------------------------------------------------  
;使用SSE2指令集做16x16的SAD  
cglobal x264\_pixel\_sad\_16x16\_%1, 4,4,8;使用4个参数，4个寄存器，8个XMM寄存器  
    movdqu  m0, \[r2\]  
    movdqu  m1, \[r2+r3\];分别存入两行数据到m0和m1中  
    lea     r2, \[r2+2\*r3\]  
    movdqu  m2, \[r2\]  
    movdqu  m3, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\];分别存入两行数据到m2和m3中  
    psadbw  m0, \[r0\];m0和dst的第1行做sad  
    psadbw  m1, \[r0+r1\];m1和dst的第二行做sad  
    lea     r0, \[r0+2\*r1\];r0指向第三行  
      
    movdqu  m4, \[r2\];载入第5行  
    paddw   m0, m1  
    psadbw  m2, \[r0\];m2和dst的第三行做SAD  
    psadbw  m3, \[r0+r1\];m3和dst的第四行做SAD  
    lea     r0, \[r0+2\*r1\];r0指向第5行  
    movdqu  m5, \[r2+r3\];载入第6行  
    lea     r2, \[r2+2\*r3\];r2指向第7行.....  
    paddw   m2, m3  
    movdqu  m6, \[r2\]  
    movdqu  m7, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m0, m2  
    psadbw  m4, \[r0\]  
    psadbw  m5, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    movdqu  m1, \[r2\]  
    paddw   m4, m5  
    psadbw  m6, \[r0\]  
    psadbw  m7, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    movdqu  m2, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m6, m7  
    movdqu  m3, \[r2\]  
    paddw   m0, m4  
    movdqu  m4, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m0, m6  
    psadbw  m1, \[r0\]  
    psadbw  m2, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    movdqu  m5, \[r2\]  
    paddw   m1, m2  
    psadbw  m3, \[r0\]  
    psadbw  m4, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    movdqu  m6, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m3, m4  
    movdqu  m7, \[r2\]  
    paddw   m0, m1  
    movdqu  m1, \[r2+r3\]  
    paddw   m0, m3  
    psadbw  m5, \[r0\]  
    psadbw  m6, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    paddw   m5, m6  
    psadbw  m7, \[r0\]  
    psadbw  m1, \[r0+r1\]  
    paddw   m7, m1  
    paddw   m0, m5  
    paddw   m0, m7  
    SAD\_END\_SSE2  
  
  
;-----------------------------------------------------------------------------  
; int x264\_pixel\_sad\_16x8\_sse2 (uint8\_t \*, int, uint8\_t \*, int )  
;-----------------------------------------------------------------------------  
;使用SSE2做16x8的指令集  
cglobal x264\_pixel\_sad\_16x8\_%1, 4,4  
    movdqu  m0, \[r2\]  
    movdqu  m2, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    movdqu  m3, \[r2\]  
    movdqu  m4, \[r2+r3\]  
    psadbw  m0, \[r0\]  
    psadbw  m2, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    psadbw  m3, \[r0\]  
    psadbw  m4, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m0, m2  
    paddw   m3, m4  
    paddw   m0, m3  
    movdqu  m1, \[r2\]  
    movdqu  m2, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    movdqu  m3, \[r2\]  
    movdqu  m4, \[r2+r3\]  
    psadbw  m1, \[r0\]  
    psadbw  m2, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    psadbw  m3, \[r0\]  
    psadbw  m4, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    lea     r2, \[r2+2\*r3\]  
    paddw   m1, m2  
    paddw   m3, m4  
    paddw   m0, m1  
    paddw   m0, m3  
    SAD\_END\_SSE2  
%endmacro  
  
  
INIT\_XMM  
SAD\_W16 sse2  
%define movdqu lddqu  
SAD\_W16 sse3  
%define movdqu movdqa  
SAD\_W16 sse2\_aligned  
%undef movdqu  
  
  
;使用SSE做4x8的SAD  
%macro SAD\_INC\_4x8P\_SSE 1  
    movq    m1, \[r0\]  
    movq    m2, \[r0+r1\]  
    lea     r0, \[r0+2\*r1\]  
    movq    m3, \[r2\]  
    movq    m4, \[r2+r3\]  
    lea     r2, \[r2+2\*r3\]  
    movhps  m1, \[r0\]  
    movhps  m2, \[r0+r1\]  
    movhps  m3, \[r2\]  
    movhps  m4, \[r2+r3\]  
    lea     r0, \[r0+2\*r1\]  
    psadbw  m1, m3  
    psadbw  m2, m4  
    lea     r2, \[r2+2\*r3\]  
%if %1  
    paddw   m0, m1  
%else  
    SWAP    m0, m1  
%endif  
    paddw   m0, m2  
%endmacro

[1346074892_4934.jpg]: https://img-my.csdn.net/uploads/201208/27/1346074892_4934.jpg
[1346075931_6523.jpg]: https://img-my.csdn.net/uploads/201208/27/1346075931_6523.jpg
[Link 1]: http://lib.csdn.net/base/datastructure

发表评论取消回复

表情：

评论列表（有 0 条评论，202人围观）

还没有评论，来说两句吧...

相关阅读

相关 QT x264

废了我4天总算在win平台下 QT上实现x264编码成功，对于那个bug 认为还是要先了解程序的原理才好排错，但是正是这个bug让我学到了很多，学会了如何可以将lib编译成可以

小灰灰/ 2022年08月10日 13:58/ 0 赞/ 141 阅读

相关 X264 命令相关

==============================================================================

古城微笑少年丶/ 2022年07月21日 01:57/ 0 赞/ 160 阅读

相关 x264直接编码

http://blog.csdn.net/subfate/article/details/48437693 版权声明：本文为迟思堂主人李迟原创文章，

墨蓝/ 2022年06月11日 23:27/ 0 赞/ 204 阅读

相关 x264中的汇编：DCT变换 dct-a.asm——004

http://blog.csdn.net/xiaoyi247/article/details/7918719 版权声明：本文为博主原创文章，未经博主允许不得转载。

红太狼/ 2022年06月10日 08:36/ 0 赞/ 140 阅读

相关 X264中的汇编：sad-a.asm——002

http://blog.csdn.net/xiaoyi247/article/details/7913360 版权声明：本文为博主原创文章，未经博主允许不得转

傷城~/ 2022年06月10日 08:30/ 0 赞/ 203 阅读

相关 x264中的汇编：cpu-a.asm——003

http://blog.csdn.net/xiaoyi247/article/details/7917537 版权声明：本文为博主原创文章，未经博主允许不得转

淡淡的烟草味﹌/ 2022年06月10日 08:30/ 0 赞/ 129 阅读

相关 x264中的汇编：x86inc.asm——001

http://blog.csdn.net/xiaoyi247/article/details/7904906 版权声明：本文为博主原创文章，未经博主允许不得转

爱被打了一巴掌/ 2022年06月10日 08:30/ 0 赞/ 321 阅读

相关 C代码调用汇编&使用指令集优化——x264汇编代码原理

http://www.cnblogs.com/JeroZeng/p/4782438.html 　　最近研究x264汇编代码，感觉使用到的优化思想和手法非常不错

小咪咪/ 2022年06月10日 08:25/ 0 赞/ 257 阅读

相关编译安装x264

网上也有相应的教程，之所以在这里重申一遍，是因为我试了网上很多的编译方法，都出现了问题，为此将此编译安装方法记录下来。首先是获取x264的网站：[http://

你的名字/ 2022年06月03日 00:12/ 0 赞/ 219 阅读

相关 x264编译-2、集成x264库

1、编写Android.mk x264 include $(CLEAR_VARS) LOCAL_MODULE := x264 LOCAL

川长思鸟来/ 2022年05月26日 12:19/ 0 赞/ 208 阅读