用80x86汇编语言编程：分类统计字符个数

以你之姓@ 2022-08-20 00:29 214阅读 0赞

;从键盘输入一行字符，统计字母、空格、数字、其他字符的个数，并显示  
;用80x86汇编语言编程如下：  
;---------------------------------------------------  
DATA SEGMENT  
    PARS  DB 100                ;准备接收100个字符.  
    NNN   DB ?                  ;用于存放实际输入的个数.  
    III   DB 100 DUP(?)         ;100字节的空间.

N\_N   DB ?  
    S\_N   DB ?  
    C\_N   DB ?  
    O\_N   DB ?

MESG1  DB  13, 10, 'Input STR  : $   ' ;用于提示.  
    MES\_C  DB  13, 10, 'Char  N is : $   ' ;用于提示.  
    MES\_S  DB  13, 10, 'Space N is : $   ' ;用于提示.  
    MES\_N  DB  13, 10, 'Num   N is : $   ' ;用于提示.  
    MES\_O  DB  13, 10, 'Other N is : $   ' ;用于提示.  
    MES\_T  DB  13, 10, 'All   N is : $   ' ;用于提示.  
DATA ENDS  
;---------------------------------------------------  
CODE SEGMENT  
    ASSUME  CS:CODE, DS:DATA  
START:  
    MOV  AX, DATA  
    MOV  DS, AX

MOV  N\_N, 0  
    MOV  S\_N, 0  
    MOV  C\_N, 0  
    MOV  O\_N, 0

MOV  DX, OFFSET MESG1  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  DX, OFFSET PARS  
    MOV  AH, 10              ;10号功能调用，接收键盘输入.  
    INT  21H  
;---------------------------------------------------  
    MOV  CL, NNN             ;收到字符的个数.  
    MOV  CH, 0  
    CMP  CX, 0  
    JNZ  DO\_IT  
    JMP  EXIT  
DO\_IT:  
    LEA  SI, III             ;收到字符的起始地址.  
;----------------------------下面开始循环统计.  
AGAIN:  
    MOV  AL, \[SI\]  
    CMP  AL, ' '             ;- ' '  
    JNZ  N\_num               ;  
    INC  S\_N  
    JMP  NEXT  
N\_num:  
    CMP  AL, ':'             ;- ':'  
    JNC  N\_C\_B               ;> '9'  
    CMP  AL, '0'  
    JC   N\_C\_B               ;< '0'  
    INC  N\_N                 ;数字个数加一.  
    JMP  NEXT  
N\_C\_B:  
    CMP  AL, '\['             ;- '\['  
    JNC  N\_C                 ;> 'Z'  
    CMP  AL, 'A'  
    JC   N\_C                 ;< 'A'  
    INC  C\_N                 ;大写，加一.  
    JMP  NEXT  
N\_C:  
    CMP  AL, '\{'             ;- '\{'  
    JNC  OTHER               ;> 'z'  
    CMP  AL, 'a'  
    JC   OTHER               ;< 'a'  
    INC  C\_N                 ;小写，加一.  
    JMP  NEXT  
OTHER:  
    INC  O\_N                 ;其它.  
NEXT:  
    INC  SI  
    LOOP AGAIN  
;----------------------------统计结束  
    MOV  DX, OFFSET MES\_N  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  AL, N\_N  
    CALL DISP\_AL

MOV  DX, OFFSET MES\_S  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  AL, S\_N  
    CALL DISP\_AL

MOV  DX, OFFSET MES\_C  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  AL, C\_N  
    CALL DISP\_AL

MOV  DX, OFFSET MES\_O  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  AL, O\_N  
    CALL DISP\_AL

MOV  DX, OFFSET MES\_T  
    MOV  AH, 9               ;9号功能调用，显示提示.  
    INT  21H  
    MOV  AL, NNN  
    CALL DISP\_AL  
;----------------------------显示结束.  
EXIT:  
    MOV  AH, 4CH  
    INT  21H  
;============================  
DISP\_AL:  ;以3位十进制数形式显示AL中的内容.  
    MOV  AH, 0

MOV  BL, 100  
    DIV  BL  
    ADD  AL, 30H  
    MOV  DL, AL  
    MOV  BH, AH  
    MOV  AH, 2  
    INT  21H

MOV  AH, 0  
    MOV  AL, BH  
    MOV  BL, 10  
    DIV  BL  
    ADD  AL, 30H  
    MOV  DL, AL  
    MOV  BH, AH  
    MOV  AH, 2  
    INT  21H

ADD  BH, 30H  
    MOV  DL, BH  
    MOV  AL, AH  
    MOV  AH, 2  
    INT  21H

RET  
;============================  
CODE  ENDS  
    END  START  
;----------------------------  
提问者对于答案的评价：谢谢  
;============================================  
原题网址：[http://zhidao.baidu.com/question/282581070.html][http_zhidao.baidu.com_question_282581070.html]  
本答案，已经被网友选为“精彩回答”。  
;============================================

[http_zhidao.baidu.com_question_282581070.html]: http://zhidao.baidu.com/question/282581070.html