从文件夹中批量抽取（复制or剪切）文件批处理脚本

深藏阁楼爱情的钟 2022-09-05 11:22 142阅读 0赞

@echo off
    color 2
    cd /d "%~dp0"
    echo ************************************************************************************************
    echo *                                                                                              *
    echo * 本程序复制/剪切当前目录下文件名中含有特定关键字的特定类型文件                                *
    echo *                                                                                              *
    echo ************************************************************************************************
    echo * 操作步骤：                                                                                   *
    echo * 1、将本批处理程序放到要处理的源目录下                                                        *
    echo * 2、在源目录下新建list.txt文本文件，将要批量抽取（复制/剪切）的文件名关键字放到文本文件中     *
    echo * 3、运行本程序开始操作                                                                        *
    echo * 注意：目标目录文件覆盖不提示，请小心操作                                                     *
    echo * 注意：关键字列表（list.txt）不要有空格、空行、空回车，关键字不要带有文件名后缀，             *
    echo * 一个关键字为一行                                                                             *
    echo ************************************************************************************************
    echo 按任意键开始操作....
    pause > NUL
    
    if not exist list.txt (echo.
      echo 请先将关键字列表保存为list.txt...
      pause > NUL
      exit
    )
    echo.
    echo 选择要进行的操作：
    set /p opt=复制(c) or 剪切(x):
    if %opt% NEQ c if %opt% NEQ x (
      echo 没有选项，byebye!
      pause >NUL
      exit
    )
    set /p ext=指定文件扩展名（不含"."，比如pdf，不指定请输入*）:
    set /p url=目标文件夹路径（不可在当前目录内）：
    if not exist %url% md %url%
    if %opt%==c set task=复制
    if %opt%==x set task=剪切
     
    set count=0
    for /f "tokens=*" %%i in (list.txt) do (
      for /r %%j in (*%%i*.%ext%) do (
        echo 正在%task% %%j 到 %url%
        if %opt%==c (copy "%%j" %url% >NUL)
        if %opt%==x (move "%%j" %url% >NUL)
        set /a count+=1
      )
    )
    
    echo.
    echo 任务完成！共%task%了%count%个文件
    echo.
    pause >NUL
    exit