OO实现ALV 聚合，排序，过滤

叁歲伎倆 2022-09-30 06:14 216阅读 0赞

在ALV提供的标准工具栏上我们可以实现输出结果的聚合（最大值，最小值，汇总，平均数），排序，过滤功能，同样在程序里也可以达到这些功能。  
   
1.       声明聚合，排序，过滤所需要的变量。  
DATA: lr\_aggregations TYPE REF TO cl\_salv\_aggregations,  
          lr\_filters       TYPE REF TO cl\_salv\_filters,  
          lr\_sorts          type ref to cl\_salv\_sorts.

2.       汇总

lr\_aggregations->add\_aggregation(  
          columnname = 'DISTANCE'  
          aggregation = if\_salv\_c\_aggregation=>total  
        ).

3.     最小值

lr\_aggregations->add\_aggregation(  
          columnname = 'FLTIME'  
          aggregation = if\_salv\_c\_aggregation=>minimum  
    ).

4.       过滤

lr\_filters->add\_filter(  
          columnname = 'CITYFROM'  
          sign = 'I'  
          option = 'NE'  
          low = 'ROM'  
          high = ''  
).

5.       排序

lr\_sorts->add\_sort(  
          columnname = 'CITYFROM'  
          sequence = if\_salv\_c\_sort=>sort\_down  
          subtotal = 'X'  
          obligatory = 'X'  
).

![1633553594804375000.jpg][]

下面是程序的所有代码:

REPORT  y\_xin\_002.  
   
\*变量定义  
TYPES: BEGIN OF gs\_spfli,  
        mandt       TYPE spfli-mandt,  
        carrid      TYPE spfli-carrid,  
        connid      TYPE spfli-connid,  
        countryfr   TYPE spfli-countryfr,  
        cityfrom    TYPE spfli-cityfrom,  
        airpfrom    TYPE spfli-airpfrom,  
        countryto   TYPE spfli-countryto,  
        cityto      TYPE spfli-cityto,  
        airpto      TYPE spfli-airpto,  
        fltime      TYPE spfli-fltime,  
        deptime     TYPE spfli-deptime,  
        arrtime     TYPE spfli-arrtime,  
        distance    TYPE spfli-distance,  
        distid      TYPE spfli-distid,  
        fltype      TYPE spfli-fltype,  
        period      TYPE spfli-period,  
END OF gs\_spfli.

TYPES  ty\_spfli TYPE gs\_spfli OCCURS 0.  
   
\*----------------------------------------------------------------------\*  
\*       CLASS lcl\_alv DEFINITION  
\*----------------------------------------------------------------------\*  
\*       ALV操作类（定义）  
\*----------------------------------------------------------------------\*  
CLASS lcl\_alv DEFINITION.  
  PUBLIC SECTION.  
    METHODS: getdata               "取得要显示的数据  
               RETURNING value(lt\_tab) TYPE ty\_spfli,  
             alv\_full              "全屏Grid列表处理方法  
               IMPORTING value(lt\_tab) TYPE ty\_spfli.  
  PRIVATE SECTION.  
    DATA: gr\_table TYPE REF TO cl\_salv\_table.  
ENDCLASS.                    "lcl\_alv DEFINITION  
   
\*----------------------------------------------------------------------\*  
\*       CLASS lcl\_alv IMPLEMENTATION  
\*----------------------------------------------------------------------\*  
\*       ALV操作类（实现）  
\*----------------------------------------------------------------------\*  
CLASS lcl\_alv IMPLEMENTATION.  
\*取得要显示的数据  
  METHOD getdata.  
    SELECT \* INTO CORRESPONDING FIELDS OF TABLE lt\_tab FROM spfli.  
  ENDMETHOD.                    "getdata  
   
\*输出全屏网格列表的方法  
  METHOD alv\_full.  
    DATA: lr\_functions    TYPE REF TO cl\_salv\_functions\_list,  
          lr\_aggregations TYPE REF TO cl\_salv\_aggregations,  
          lr\_filters      TYPE REF TO cl\_salv\_filters,  
          lr\_sorts        type ref to cl\_salv\_sorts.  
   
    "创建实例  
    TRY.  
        cl\_salv\_table=>factory(  
          IMPORTING  
            r\_salv\_table = gr\_table  
          CHANGING  
            t\_table      = lt\_tab  
        ).  
      CATCH cx\_salv\_msg.  
    ENDTRY.  
    "ALV标准功能  
    lr\_functions = gr\_table->get\_functions( ).  
    lr\_functions->set\_all( 'X' ).  
   
    lr\_aggregations = gr\_table->get\_aggregations( ).  
    lr\_filters      = gr\_table->get\_filters( ).  
    lr\_sorts        = gr\_table->get\_sorts( ).  
    TRY.  
        "汇总  
        lr\_aggregations->add\_aggregation(  
          columnname = 'DISTANCE'  
          aggregation = if\_salv\_c\_aggregation=>total  
        ).  
        "最小值  
        lr\_aggregations->add\_aggregation(  
          columnname = 'FLTIME'  
          aggregation = if\_salv\_c\_aggregation=>minimum  
        ).  
        "过滤  
        lr\_filters->add\_filter(  
          columnname = 'CITYFROM'  
          sign = 'I'  
          option = 'NE'  
          low = 'ROM'  
          high = ''  
        ).  
        "排序  
        lr\_sorts->add\_sort(  
          columnname = 'CITYFROM'  
          sequence = if\_salv\_c\_sort=>sort\_down  
          subtotal = 'X'  
          obligatory = 'X'  
        ).  
      CATCH cx\_salv\_data\_error.  
      CATCH cx\_salv\_existing.  
      CATCH cx\_salv\_not\_found.  
    ENDTRY.  
   
    "显示列表  
    gr\_table->display( ).  
  ENDMETHOD.                    "alv\_full  
ENDCLASS.                    "lcl\_alv IMPLEMENTATION  
   
   
\*&---------------------------------------------------------------------\*  
\*&      Form  f\_main  
\*&---------------------------------------------------------------------\*  
\*       整合数据，执行  
\*----------------------------------------------------------------------\*  
FORM f\_main.  
  DATA: lt\_tab TYPE ty\_spfli,  
        lr\_alv TYPE REF TO lcl\_alv.  
   
  CREATE OBJECT lr\_alv.  
   
  "取得要显示的数据  
  lt\_tab = lr\_alv->getdata( ).  
   
  lr\_alv->alv\_full( lt\_tab ).  
ENDFORM.                    "f\_main  
   
\*执行动作  
START-OF-SELECTION.  
  PERFORM f\_main.

本文来自CSDN博客，转载请标明出处：[http://blog.csdn.net/lhx20/archive/2008/08/26/2833234.aspx][http_blog.csdn.net_lhx20_archive_2008_08_26_2833234.aspx]

[1633553594804375000.jpg]: /images/20220708/c03e4a4aade842c68c78219e5b5459cc.png
[http_blog.csdn.net_lhx20_archive_2008_08_26_2833234.aspx]: http://blog.csdn.net/lhx20/archive/2008/08/26/2833234.aspx