渐变纹理和遮罩纹理

约定不等于承诺〃 2023-07-07 08:09 7阅读 0赞

*  渐变纹理

纹理不仅可以定义一个物体的颜色，也可以用来存储任何表面属性。比如用渐变纹理 来控制漫反射光照结果。可以通过使用不同的**渐变纹理** 来控制物体的漫反射光照。

Shader "Custom/RampTexture"
    {
        Properties
        {
            _Color ("Color", Color) = (1,1,1,1)
            //渐变纹理
            _RampTex ("Ramp Tex", 2D) = "white" {}
            _Specular("Specular",Color)=(1,1,1,1)
            _Gloss ("Gloss", Range(8,256)) = 20
            
        }
        SubShader
        {
           pass
           {
               Tags{"LightMode"="ForwardBase"}
               CGPROGRAM
    
                #pragma vertex vert
                #pragma fragment frag
                #include "Lighting.cginc"
    
                fixed4 _Color ;
                sampler2D _RampTex;
                float4 _RampTex_ST;
                fixed4 _Specular;
                float _Gloss;
    
                struct a2v
                {
                    float4 vertex :POSITION;
                    float3 normal:NORMAL;
                    float4 texcoord:TEXCOORD0;
    
                };
    
                struct v2f
                {
                    float4 pos:SV_POSITION;
                    float3 worldNormal:TEXCOORD0;
                    float3 worldPos:TEXCOORD1;
                    float2 uv:TEXCOORD2;
                };
    
                v2f vert(a2v v)
                {
                    v2f o;
                    o.pos=UnityObjectToClipPos(v.vertex);
                    o.worldNormal=UnityObjectToWorldNormal(v.normal);
                    o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                    //计算经过平铺 和偏移后的纹理坐标
                    o.uv=TRANSFORM_TEX(v.texcoord,_RampTex);
                    return o;
                }   
    
                fixed4 frag(v2f i):SV_Target
                {
                    fixed3 worldNormal=normalize(i.worldNormal);
                    fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));
                    fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
                    //half Lambert
                    fixed  halfLambert=0.5 * dot(worldNormal,worldLightDir)+0.5;
                    fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;
    
                    fixed3 diffuse=_LightColor0.rgb*diffuseColor;
                    fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
                    fixed3 halfDir=normalize(worldLightDir+viewDir);
                    fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);
    
                    return fixed4(ambient+diffuse+specular,1);
                }
               ENDCG
           }
        }
        FallBack "Specular"
    }

通过使用不同的渐变纹理，来改变 模型风格

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70][]![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70 1][]

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70 2][]

第一张图使用的是 紫色到浅黄色的 渐变纹理。第二张渐变纹理是 中间分界线 微微发红，插画中阴影处是用这样的色调。

第三张通常被用于 卡通风格，色调突变 没有平滑过渡，模拟卡通中的阴影色块。

*  遮罩纹理

允许我们可以保护某些区域不被修改。比如我们 想让 模型的某些区域反光强度强烈一些，某些区域弱一点，这时我们就可以采用一张遮罩纹理来控制光照。还有就是在制作地形材质的时候需要混合多张图片，例如草地的纹理，表现石子的纹理，裸露土地的纹理等，使用遮罩纹理可以控制如何混合这些纹理。

是用遮罩纹理流程：通过采样得到遮罩纹理的纹素值，然后使用其中某个或者 某几个通道的值（比如 texel.r）来与某种表面属性进行相乘，这样当该通道的值为0的时候，可以保护表面不受属性的影响。

Shader "Custom/MaskTexture"
    { 
        Properties
        {
            _Color ("Color", Color) = (1,1,1,1)
            _MainTex ("Main Tex", 2D) = "white" {}
            _BumpMap("Normal Map",2D)="bump" {}
            _BumpScale("Bump Scale",Float)=1
            _SpecularMask("Specular Mask",2D)="white"{}
            _SpecularScale("Specular Scale",Float)=1
            _Specular("Specular",Color)=(1,1,1,1)
            _Gloss ("Gloss", Range(8,256)) = 20
            
        }
        SubShader
        {
           pass
           {
               Tags{"LightMode"="ForwardBase"}
               CGPROGRAM
    
                #pragma vertex vert
                #pragma fragment frag
                #include "Lighting.cginc"
    
                fixed4 _Color ;
                sampler2D _MainTex;
                float4 _MainTex_ST;
                sampler2D _BumpMap;
                float _BumpScale;
                sampler2D _SpecularMask;
                float _SpecularScale;
                fixed4 _Specular;
                float _Gloss;
    
                struct a2v
                {
                    float4 vertex :POSITION;
                    float3 normal:NORMAL;
                    float4 tangent:TANGENT;
                    float4 texcoord:TEXCOORD0;
    
                };
    
                struct v2f
                {
                    float4 pos:SV_POSITION;
                    float2 uv:TEXCOORD0;
                    float3 lightDir:TEXCOORD1;
                    float3 viewDir:TEXCOORD2;
                };
    
                v2f vert(a2v v)
                {
                    v2f o;
                    o.pos=UnityObjectToClipPos(v.vertex);
                    o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
                    TANGENT_SPACE_ROTATION;
                    o.lightDir=mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
                    o.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
    
                    return o;
                }   
    
                fixed4 frag(v2f i):SV_Target
                {
                    fixed3 tangentLightDir=normalize(i.lightDir);
                    fixed3 tangentViewDir=normalize(i.viewDir);
                    fixed3 tangentNormal=UnpackNormal(tex2D(_BumpMap,i.uv));
                    tangentNormal.xy*=_BumpScale;
                    tangentNormal.z=sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
                    fixed3 albedo=tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                    fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
                    fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentLightDir));
                    fixed3 halfDir=normalize(tangentLightDir+tangentViewDir);
                    //获取遮罩值 ，采用r 分量来计算掩码值，来控制高光反射强度
                    fixed3 specularMask=tex2D(_SpecularMask,i.uv).r *_SpecularScale;
                    //计算高光部分，和高光遮罩
                    fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss)*specularMask;
                    //fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
    
                    //return fixed4(ambient+diffuse,1);
                    return fixed4(ambient+diffuse+specular,1);
                }
               ENDCG
           }
        }
        FallBack "Specular"
    }

通过使用高光遮罩纹理 依次得到下面的效果。

![20200221184232234.png][]![20200221184245617.png][]![20200221184300788.png][]

可以让我们 更加精细的控制光照细节，得到更好的效果。

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70]: https://img-blog.csdnimg.cn/20200221183616492.png?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj,size_16,color_FFFFFF,t_70
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70 1]: https://img-blog.csdnimg.cn/20200221183635580.png?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj,size_16,color_FFFFFF,t_70
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj_size_16_color_FFFFFF_t_70 2]: https://img-blog.csdnimg.cn/20200221183653976.png?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2huem1kbGhj,size_16,color_FFFFFF,t_70
[20200221184232234.png]: https://img-blog.csdnimg.cn/20200221184232234.png
[20200221184245617.png]: https://img-blog.csdnimg.cn/20200221184245617.png
[20200221184300788.png]: https://img-blog.csdnimg.cn/20200221184300788.png