pdm使用经验

ゞ浴缸里的玫瑰 2024-02-18 11:46 59阅读 0赞

### 一. 去掉图表中的网格底线 ###

Tools -> Dispaly Preferences -> General Settings ->  
General标签 -> Diagram ->  
取消勾选Show page delimiter，  
点击OK，

### 二．创建模型及变更模型 ###

操作：file–>new Model…

快捷键：ctrl+n

常用的以下两种：

1.概念模型(conceptual Data Model)

选择categories-->information-->conceptual Data-->ok创建概念模型

2.物理模型(Physical DataModel)

选择categories-->information-->Physical Data-->ok创建物理模型

二．将概念模型转换成物理模型

操作：Tools–>GeneratePhysical Data Model

快捷键：ctrl+shift+p

### 三，显示Comment描述字段 ###

如果要显示Comment描述字段的话，我们需要双击表格，然后进入Columns选项页，点击Customize Columns and Filter按钮，然后勾选Comment即可，如图：  
![在这里插入图片描述][27469c8b408946a7aa490fb6b70a6d7c.png_pic_center]![在这里插入图片描述][1fdfb16c3a9947d4931a13b873b86da7.png]

当我们勾选完Comment并保存后，在Table Properties窗口Columns选项卡页中看到Comment了，如图：  
![在这里插入图片描述][7dc79e7e82d64cf7a95464fc7c04cf5d.png]

但是，保存后回到设计视图，仍没有看到Comment注释信息，这样非常不便我们设计  
![在这里插入图片描述][ab5747d9f5c74162b6f2a04e9e02cc43.png]

此时，我们在工具栏找到模型->Extensions按钮，如图：  
![在这里插入图片描述][391d714558af432b89f92de1028ab1c2.png]

在打开的 List of Extensions 对话框中新建一个，然后点击属性按钮，如图：  
![在这里插入图片描述][bc7eb51f00e94a00bd3a20a0533f5233.png]

在Profile右键，点击Add Metaclasses，如图：  
![在这里插入图片描述][ce3644651e7f4365b95d5a9d5462a65d.png]

选中Column，然后点击OK，如图：  
![在这里插入图片描述][c7da10148ad64b1fb64c52cb53dc5f37.png]

然后选中Column，右键选择 New -> Extended Attribute，如图：  
![在这里插入图片描述][1f07174e221940b1a2d0fcea8e98a530.png]

Name一个名字（例如 AttributeComment ），dataType选择String，选中 Computer、Read only  
注意：名字不能用 Comment，因为这是内置名字，用了会提示你重名，如图：  
![在这里插入图片描述][1809b2719f03434a860b9e40c2775618.png]

切换到Get Method Script tab 将 %Get% = “” 改为 %Get% = Rtf2Ascii (obj.Comment)，如图：  
![在这里插入图片描述][9dd17bedbc454efc9ef1dbd3807db89a.png]

![在这里插入图片描述][3fafcb73497747338f9ac1510d09d39e.png]

确定保存，回到视图界面，在工具栏找到 工具 -> 显示首选项，如图：  
![在这里插入图片描述][355e5be7acf244d195b5916776dbfee6.png]

依次点击 Table->Advanced，如图：  
![在这里插入图片描述][66d2bad3d3b643d5830de22ca9bfa145.png]

选中 Columns，然后在 List Columns 右侧，点击 Select 按钮，如图：  
![在这里插入图片描述][4c38e6fcee584a77a113323ebb1f57e5.png]

找到前面所设置的 AttributeComment ，勾选并保存，如图：  
![在这里插入图片描述][0c8bc1b9d6b1459d9af64039a7e470b6.png]

回到视图界面，这时table就已经能显示出Comment字段了，如图：  
![在这里插入图片描][ab4a4901262a4ebe9a85ebc7b1a4aacb.png]

### 四，批量更新name，code，表名值为中文 ###

工具，图中选项运行修改代码程序  
![在这里插入图片描述][1a4782400ad0478cb3d7e8ddb138b31e.png]![在这里插入图片描述][e13cff91d208406199485ed1dcd6990a.png]

![在这里插入图片描述][b787395326354926b32837b3a2e74530.png]选中要运行的vbs文件，点击RUN  
![在这里插入图片描述][37571e6003594c8bbdb92f6551680b30.png]VBS脚本

'******************************************************************************
    '* File:     comment2code.vbs
    '* Purpose: 在PowerDesigner的PDM图形窗口中显示数据列的中文注释
    '* Title:    将字段的comment赋值到字段的code中
    '* Category: 打开物理模型，运行本脚本（Ctrl+Shift+X）
    '* Copyright:foxzz@163.com,2006/07/25 .
    '* Author:   foxzz
    '* Created:
    '* Modified:
    '* Version: 1.0
    '* Comment: 遍历物理模型中的所有表，将字段的comment赋值到字段的code中。
    '            在将code置换为comment过程中，需要考虑的问题
    '            1、code必须唯一，而comment有可能不唯一。
    '               处理办法是如果字段的comment重复，则字段的code=comment+1、2、3...
    '            2、comment值有可能为空，这种情况下对字段的code不处理。
    '               针对Oracle数据库,将comment on column 字段名称 is '';添加到C:\pdcomment.txt文件中。
    '               在补充comment完毕后，便于在数据库中执行      
    '******************************************************************************
     
     
    Option Explicit
    ValidationMode = True
    InteractiveMode = im_Batch
     
     
    Dim system, file
    Set system = CreateObject("Scripting.FileSystemObject")
    Dim ForReading, ForWriting, ForAppending   '打开文件选项
    ForReading   = 1 ' 只读
    ForWriting   = 2 ' 可写
    ForAppending = 8 ' 可写并追加
    '打开文本文件
    Set file = system.OpenTextFile("D:\pdcomment.txt", ForWriting, true)
    '判断当前model是否物理数据模型
    Dim mdl
    Set mdl = ActiveModel
    If (mdl Is Nothing) Then
       MsgBox "处理对象无模型"
    ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
       MsgBox "当前模型不是物理数据模型"
    Else
       ProcessFolder mdl,file
    End If
    file.Close
     
     
     
     
    '******************************************************************************
    Private sub ProcessFolder(folder,file)
    Dim i,j,k
    i=0:j=0:k=0
    '列数组，记录字段里不重复的comment
    Dim ColumnComment()
    Dim ColumnCommentNumber()
    ReDim Preserve ColumnComment(i)
    ReDim Preserve ColumnCommentNumber(i)
     
     
    Dim tbl   '当前表
    Dim col   '当前字段
    dim curComment '当前字段comment
    dim str
    '处理模型中的表
    for each tbl in folder.tables
        if not tbl.isShortcut then
           if len(trim(tbl.comment))<>0 then
              '可以在这里显示table的comment
              'tbl.code = tbl.code+"("+trim(tbl.comment)+")"
           end if 
     
    		tbl.name = tbl.comment
    		tbl.code = tbl.comment
     
           '处理表中的列
           for each col in tbl.columns
               k = 0
    		   str=trim(col.comment)
    		   'curComment=left(str,instrrev(str,";"))
    		   curComment=str
               if len(curComment)<>0 then
                  '遍历相异的comment数组
                  for j = 0 to i
                      if ColumnComment(j) = curComment then
                         '如果找到相同的comment,则相关计数器加1
                         ColumnCommentNumber(j) = ColumnCommentNumber(j) + 1
                         k = j
                      end if
                  Next
                  '如果没有相同的comment,则k=0,此时ColumnCommentNumber(0)也为0
                  '否则ColumnCommentNumber(k)不为0
                  if ColumnCommentNumber(k) <> 0 then
                     col.name = curComment & cstr(ColumnCommentNumber(k))
    				 col.code = curComment & cstr(ColumnCommentNumber(k))
                  else
                     col.name = curComment
    				 col.code = curComment
                     'ColumnComment(0)、ColumnCommentNumber(0)永远为空
                     '将相异的comment记录添加到数组中
                     i = i + 1
                     ReDim Preserve ColumnComment(i)
                     ReDim Preserve ColumnCommentNumber(i)
                     ColumnComment(i) = curComment
                     ColumnCommentNumber(i) = 0
                  end if
               else
                  '写入文件中
                  file.WriteLine "comment on column "+ tbl.code+"."+col.name+" is '';"         
               end if
           next
        end if
        '由于不同表的code允许相同,因此此时重新初始化。
        '因为ColumnComment(0)、ColumnCommentNumber(0)为空，可以保留
        ReDim Preserve ColumnComment(0)
        ReDim Preserve ColumnCommentNumber(0)
        i=0:j=0:k=0
     
     
    next
     
     
    Dim view '当前视图
    for each view in folder.Views
        if not view.isShortcut then
           '可以在这里显示view的comment
           'view.code = view.comment
        end if
    next
    '对子目录进行递归
    Dim subpackage 'folder
    For Each subpackage In folder.Packages
        if not subpackage.IsShortcut then
           ProcessFolder subpackage , file
        end if
    Next
    end sub
    '******************************************************************************

[27469c8b408946a7aa490fb6b70a6d7c.png_pic_center]: https://img-blog.csdnimg.cn/27469c8b408946a7aa490fb6b70a6d7c.png#pic_center
[1fdfb16c3a9947d4931a13b873b86da7.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/1b034f5ddce64eb09c131d5213c6e90a.png
[7dc79e7e82d64cf7a95464fc7c04cf5d.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/4a153c6087f74a18b47ac4809a3124a1.png
[ab5747d9f5c74162b6f2a04e9e02cc43.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/e214612b678544e98cb700e2f49e8cff.png
[391d714558af432b89f92de1028ab1c2.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/fd779b3521e6432981d86e44a738460e.png
[bc7eb51f00e94a00bd3a20a0533f5233.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/b45fff5022f1482481d5a937400c0730.png
[ce3644651e7f4365b95d5a9d5462a65d.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/7eccf1f8e963415ea5034156dffd6520.png
[c7da10148ad64b1fb64c52cb53dc5f37.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/828a9574dc6f465dbfcb0732e7f8bf9f.png
[1f07174e221940b1a2d0fcea8e98a530.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/5b8ad583e62d416b87ebdc6f5cb25948.png
[1809b2719f03434a860b9e40c2775618.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/4ca3eaa74da849bba225dbfafe739244.png
[9dd17bedbc454efc9ef1dbd3807db89a.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/6530ecd127704b71858b30419a61f9c0.png
[3fafcb73497747338f9ac1510d09d39e.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/b3230bd7cce445289b72dcd322af9fc8.png
[355e5be7acf244d195b5916776dbfee6.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/1819ce116d9742848b4f0c3717f90d06.png
[66d2bad3d3b643d5830de22ca9bfa145.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/bfd5ddb8a2b84fea8fdc73e237970abd.png
[4c38e6fcee584a77a113323ebb1f57e5.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/f63f7a6f29514f35ba45a082d0c6e944.png
[0c8bc1b9d6b1459d9af64039a7e470b6.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/80ccdb0fc7d34f819f0d1d0e394cd4f4.png
[ab4a4901262a4ebe9a85ebc7b1a4aacb.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/3314314fc3eb4fd6b1890d9a3e837861.png
[1a4782400ad0478cb3d7e8ddb138b31e.png]: https://img-blog.csdnimg.cn/1a4782400ad0478cb3d7e8ddb138b31e.png
[e13cff91d208406199485ed1dcd6990a.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/55c084e6101949c69cb118cd446da418.png
[b787395326354926b32837b3a2e74530.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/2248ad2d3edd4b65835e961de517136b.png
[37571e6003594c8bbdb92f6551680b30.png]: https://image.dandelioncloud.cn/pgy_files/images/2024/02/18/a213cd0d66824a43b0fa3d0209107ab4.png