【操作系统真象还原系列】3. 进入保护模式

分手后的思念是犯贱 2022-12-28 01:45 323阅读 0赞

### 目录 ###

*  实模式与保护模式
 *  全局描述符表
 *  段描述符
 *  选择子
 *  定义描述符表所用到的宏
 *  构造全局描述符表
 *  打开A20地址线
 *  加载GDTR
 *  使能CR0中的PE位
 *  保护模式下字符串打印函数
 *  完整实验代码
 *   *  load.s
     *  mbr.s
 *  Virtualbox不显示字符串或崩溃，但是bochs正常
 *  编译及烧写步骤
 *   *  编译
     *  烧写
 *  实验效果动态图

# 实模式与保护模式 #

在实模式下，操作系统和用户程序属于同一特权级，用户程序所引用的地址都是指向真实的物理地址。用户程序可以自由修改段基址，从而访问所有的内存空间。同时，在实模式下，如果程序需要访问超过64KB的内存区域，就需要切换段基址。而更为致命的一点则是实模式下最多只能访问低1MB的地址空间。

相对于实模式，保护模式提供了一系列复杂的机制，其中最重要的是分段、分页以及中断。其中分段和分页都是为了给编写应用程序的程序员提供更好的地址抽象和内存管理。至于中断的功能实模式也有，但是因为保护模式寻址方式改变，因此为了适应保护模式，在从实模式跳入保护模式的时候要修改中断机制。

总结一下，保护模式是修改了实模式朴素的寻址方式，并基于此提供了分段，分页和（新的）中断机制的CPU工作模式。由于保护模式的中断机制与实模式的没有本质区别，只需要知道如何建立中断描述符（以及对8259A芯片编程）即可。因此理解保护模式的重点在于分段以及分页（寻址）。

# 全局描述符表 #

在保护模式下，段寄存器中保存的再也不是段基址了，而是叫做选择子的内容。选择子其实就是数组下标，用来索引段描述符表中的段描述符。而最主要的描述符是全局描述符表（Global Descriptor Table，GDT）。在进入保护模式之前，必须先定义全局描述符表。全局描述符的起始地址被存储在全局描述符表寄存器GDTR中。该寄存器分为两个部分，分别是32位的线性地址和16位的边界值。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]  
其中，全局描述符表界限值，大小是表内最后1字节的偏移量。第1个字节的偏移量是0，最后1字节的偏移量是表字节大小减1。

理论上，全局描述符表可以位于内存中的任意地址处，不必对齐。但是在进入保护模式之前我们就要设置好GDT，所以最开始GDT必须位于前1MB内存中。为简单起见，我们将GDT放在loader.bin文件的开头处。因为loader.bin文件被加载到LOADER\_BASE\_ADDR，即物理地址0x500处，所以GDT表也位于0x500处。

由于GDT界限为16位，故其大小上限为64KB，即GDT表最大只能有64KB。从0x500开始只有约30KB的可用区域，幸好我们现在的GDT表只有四项，足够用。

由于每一个段描述符大小为8个字节，所以GDT中最多可以容纳的段描述符个数为216/23=2^13=8192个。

# 段描述符 #

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]  
所有的段描述符大小都是连续的8个字节。由于保护模式下的地址宽度是32位，故段基址需要32位地址来表示。  
描述符中指定了32位的段起始线性地址，以及20位的段边界。如果未开启分页功能，那么线性地址就是物理地址。

Type字段中的E位表示扩展方向。对于20位的段界限来说，如果是向上扩展的代码段或数据段，它决定了偏移量的最大值；如果是向下扩展的堆栈段，段界限决定了偏移量的最小值。

G代表段的粒度。若G=0，则表示段界限以字节为单位，此时20位的段界限可以表示从1字节到1MB的范围；若G=1，则表示段界限以4KB为单位，此时20位的段界限可以表示从4KB到4GB的范围。

DPL位表示描述符的特权级（Descriptor Privilege Level，DPL）。这两位用于指定对应段的特权级，即0、1、2、3。其中0级为最高特权级别，3级为最低特权级别。刚进入保护模式时执行的代码具有最高的特权级别。通常0级用于操作系统的代码，3级用于普通用户程序的代码。有些CPU指令只能由0特权级的程序来执行。

P表示段存在位（Segment Present）。P位用于指示描述符所对应的段是否存在。当P=0时，表示段位于硬盘中；当P=1时，表示段位于内存中。

D/B位表示默认操作设大小。当为0时表示是16位的，当为1时表示是32位的。

L位是64位代码段标志，为1表示是64位。

S位用于表示描述符的类型。当S=0时，表示这是一个系统段；当S=1时，表示这是一个代码段或数据段。所谓系统段，就是硬件运行所需要用到的段，比如调用门、任务门等。

Type字段则需要和S位配合在一起才能确定其确切类型。也就是说，只有当S位的值确定之后，Type字段的值才有具体意义。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]

对于代码段，C位表示该段是否是特权级依从。C=0表示非依从段，即该代码段只能从与它特权级相同的代码段调用，或者通过门调用；C=1则表示允许从低特权级的程序转移到该段执行。R位表示该代码段是否可读。

E位表示扩展方向位。E为1表示向下扩展，E为0表示向上扩展。

A位表示该段最近是否被访问过，每当该段被访问时，CPU会自动将该位置置1。

AVL位是用户自定义位，通常由操作系统来使用。

# 选择子 #

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]  
段基址在段描述符中，用给定的段选择子索引到描述符后，CPU会自动从该段描述符中取出段基址。段选择子为16位，最低的两位用来存储RPL，即请求特权级，可以表示0、1、2、3四种特权级。而选择子中的第2位是TI位，用来指示选择子是在GDT中，还是LDT中索引描述符。TI为0表示在GDT中索引描述符，TI为1表示在LDT中索引描述符。

由于选择子的索引值部分共有13位，故最多可以索引213=8192个段，这和GDT中最多定义8192个描述符是匹配的。

# 定义描述符表所用到的宏 #

我们把loader的加载地址定在0x500处，并把GDT表构建在loader的开头处。为了映射整个4GB的虚拟内存地址空间，我们将粒度设置为4KB：

DESC_G_4K equ (0x1 << 23)
    DESC_G_1B equ (0x0 << 23)

设置D/B为1，表示是32位：

DESC_D_32 equ (0x1 << 22)

L位是64位代码段标志，设置为0：

DESC_L equ (0x0 << 21)

AVL位是用户自定义位，通常由操作系统来使用，这里我们暂设置为0：

DESC_AVL equ (0x0 << 20)

我们把数据段和代码段都设置为整个4GB的地址空间  
设置代码段的限长的最高4位：

DESC_LIMIT_CODE_High4 equ (0xF << 16)

设置数据段的限长的最高4位：

DESC_LIMIT_DATA_High4 equ (0xF << 16)

由于用于文本模式的显存地址范围是0xB8000~0xBFFFF，一共32KB(215)大小，故显存段界限为0x7FFF，又由于段粒度为1B，所以段界限长度为0x7FFF，即最高的4位是0：

DESC_LIMIT_VIDEO_High4 equ (0x0 << 16)

段存在位P用于指示描述符所对应的段是否存在。当P=1时，表示段位于内存中：

DESC_P equ (0x1 << 15)

4个特权级描述符：

DESC_DPL_0 equ (0x0 << 13)
    DESC_DPL_1 equ (0x1 << 13)
    DESC_DPL_2 equ (0x2 << 13)
    DESC_DPL_3 equ (0x3 << 13)

S位用于表示描述符的类型。当S=0时，表示这是一个系统段；当S=1时，表示这是一个代码段或数据段。

DESC_S_CODE_OR_DATA equ (0x1 << 12)
    DESC_S_SYSTEM equ (0x0 << 12)

我们设置代码段为可执行、不可读、非一致性，访问位清零：

DESC_TYPE_CODE equ (0x8 << 8)

我们设置数据段为不可执行、可读可写、向上扩展，访问位清零：

DESC_TYPE_DATA equ (0x2 << 8)

我们设置代码段和数据段映射整个4GB地址空间：

DESC_CODE_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_CODE_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_CODE + 0x00
    
    DESC_DATA_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_DATA_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x00
    
    DESC_VIDEO_HIGH32 equ (0x00 << 24) + DESC_G_1B + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_VIDEO_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x00

此外，我们还需要设置选择子的属性：

RPL0 equ (0x0)
    RPL1 equ (0x1)
    RPL2 equ (0x2)
    RPL3 equ (0x3)
    
    TI_GDT equ (0x0 << 2)
    TI_LDT equ (0x1 << 2)

# 构造全局描述符表 #

为方便起见，我们将全局描述符表放置在loader的开头部分，如下所示：

section loader vstart=LOADER_BASE_ADDR
    ;栈底设置在0x7C00处，满减栈
    LOADER_STACK_TOP equ 0x7c00
    jmp loader_start
    
    GDT_BASE:
    	dd 0x0
    	dd 0x0
    CODE_DESC:
    	dd 0xFFFF
    	dd DESC_CODE_HIGH32
    DATA_STACK_DESC:
    	dd 0xFFFF
    	dd DESC_DATA_HIGH32 
    VIDEO_DESC:
    	;我们把显存段基址设置为0xB8000，由于显存范围是0xB8000-0xBFFFF
    	;故显存段的段限长为 0x7FFF
    	dd 0x80007FFF
    	dd DESC_VIDEO_HIGH32 
    
    GDT_SIZE equ $ - GDT_BASE
    GDT_LIMIT equ GDT_SIZE - 1
    ;此处预留60个描述符的空位，以备后续使用
    times 60 dq 0
    
    ;定义三个段描述符选择子
    SELECTOR_CODE equ (0x1 << 3) + TI_GDT + RPL0
    SELECTOR_DATA equ (0x2 << 3) + TI_GDT + RPL0
    SELECTOR_VIDEO equ (0x3 << 3) + TI_GDT + RPL0
    
    gdt_ptr：
    	dw GDT_LIMIT
    	dd GDT_BASE
    
    loader_start:
    ...

# 打开A20地址线 #

绝大多数IBM PC兼容机默认的A20 Gate是被禁止的。由于在当时没有更好的方法来解决这个问题，所以IBM使用了键盘控制器来操作A20 Gate，但这只是一种黑客行为，毕竟A20 Gate和键盘操作没有任何关系。在许多新型PC上存在着一种通过芯片来直接控制A20 Gate的BIOS功能。从性能上，这种方法比通过键盘控制器来控制A20 Gate要稍微好一点。

当使用键盘控制器芯片来控制A20 Gate信号时，我们称之为Normal模式；当使用主板上的芯片来控制A20 Gate信号时，我们称之为Fast模式。这在BIOS也有体现，设定Gate A20 Option，有Fast和Normal两个选项。

这里我们只使用Fast模式来开启A20地址线，即将端口0x92的第1位设置为1即可。代码如下所示：

in al, 0x92          ;南桥芯片内的端口 
    or al, 0x2
    out 0x92, al         ;打开A20

# 加载GDTR #

CPU为了跟踪全局描述符表，处理器内部有一个48位的寄存器，称为全局描述符表寄存器（GDTR）。该寄存器分为两部分，即16位的边界和32位的线性地址。

全局描述符表的界限值是表内最后1字节的偏移量，首字节的偏移量是0，最后一个字节的偏移量是表的大小减1。因为GDT的界限值是16位的，所以表的最大值是216=64KB，又由于一个段描述符占8个字节，所以GDT中最多有8K（8192）个描述符。

我们首先定义一个6字节的内存区域，用于存储GDT的大小和线性基地址。之后使用lgdt 48位内存数据，即可将GDT加载到GDTR中。具体代码如下所示：

lgdt  [gdt_ptr]

# 使能CR0中的PE位 #

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]  
上述各位的具体含义如下表所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]  
我们将CR0寄存器的第0位，即PE位置1后，CPU就进入了保护模式。代码如下所示：

mov eax, cr0
    or eax, 0x1
    mov cr0, eax
    
    ;之后，我们需要使用跳转指令来刷新流水线
    jmp dword SELECTOR_CODE : protectionMode_start
    [bits 32]
    protectionMode_start:

# 保护模式下字符串打印函数 #

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, SELECTOR_VIDEO
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, SELECTOR_VIDEO
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret

# 完整实验代码 #

## load.s ##

LOADER_BASE_ADDR equ 0x500
    
    ;定义描述符表所用到的宏
    DESC_G_4K equ (0x1 << 23)
    DESC_G_1B equ (0x0 << 23)
    
    ;设置D/B为1，表示是32位
    DESC_D_32 equ (0x1 << 22)
    
    
    ;L位是64位代码段标志，设置为0
    DESC_L equ (0x0 << 21)
    
    
    ;AVL位是用户自定义位，通常由操作系统来使用，这里我们暂设置为0
    DESC_AVL equ (0x0 << 20)
    
    ;设置代码段的限长的最高4位
    DESC_LIMIT_CODE_High4 equ (0xF << 16)
    
    ;设置数据段的限长的最高4位
    DESC_LIMIT_DATA_High4 equ (0xF << 16)
    
    ;用于文本模式的显存地址范围是0xB8000~0xBFFFF，一共32KB(215)大小，故显存段界限为0x7FFF，又由于段粒度为1B，所以段界限长度为0x7FFF，即最高的4位是0
    DESC_LIMIT_VIDEO_High4 equ (0x0 << 16)
    
    
    ;段存在位P用于指示描述符所对应的段是否存在。当P=1时，表示段位于内存中
    DESC_P equ (0x1 << 15)
    
    ;4个特权级
    DESC_DPL_0 equ (0x0 << 13)
    DESC_DPL_1 equ (0x1 << 13)
    DESC_DPL_2 equ (0x2 << 13)
    DESC_DPL_3 equ (0x3 << 13)
    
    ;S位用于表示描述符的类型。当S=0时，表示这是一个系统段；当S=1时，表示这是一个代码段或数据段
    DESC_S_CODE_OR_DATA equ (0x1 << 12)
    DESC_S_SYSTEM equ (0x0 << 12)
    
    ;设置代码段为可执行、不可读、非一致性，访问位清零
    DESC_TYPE_CODE equ (0x8 << 8)
    
    
    ;设置数据段为不可执行、可读可写、向上扩展，访问位清零
    DESC_TYPE_DATA equ (0x2 << 8)
    
    
    ;设置代码段和数据段映射整个4GB地址空间
    DESC_CODE_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_CODE_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_CODE + 0x00
    
    DESC_DATA_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_DATA_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x00
    
    DESC_VIDEO_HIGH32 equ (0x00 << 24) + DESC_G_1B + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_VIDEO_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x0B
    
    RPL0 equ (0x0)
    RPL1 equ (0x1)
    RPL2 equ (0x2)
    RPL3 equ (0x3)
    
    TI_GDT equ (0x0 << 2)
    TI_LDT equ (0x1 << 2)
    
    ;loader的入口
    ;构造全局描述符表
    section loader vstart=LOADER_BASE_ADDR
    ;栈底设置在0x7C00处，满减栈
    LOADER_STACK_TOP equ 0x7c00
    jmp loader_start
    
    GDT_BASE:
    	dd 0x0
    	dd 0x0
    CODE_DESC:
    	dd 0xFFFF
    	dd DESC_CODE_HIGH32
    DATA_STACK_DESC:
    	dd 0xFFFF
    	dd DESC_DATA_HIGH32 
    VIDEO_DESC:
    	;我们把显存段基址设置为0xB8000，由于显存范围是0xB8000-0xBFFFF
    	;故显存段的段限长为 0x7FFF
    	dd 0x80007FFF
    	dd DESC_VIDEO_HIGH32 
    
    GDT_SIZE equ $ - GDT_BASE
    GDT_LIMIT equ GDT_SIZE - 1
    ;此处预留60个描述符的空位，以备后续使用
    times 60 dq 0
    
    ;定义三个段描述符选择子
    SELECTOR_CODE equ (0x1 << 3) + TI_GDT + RPL0
    SELECTOR_DATA equ (0x2 << 3) + TI_GDT + RPL0
    SELECTOR_VIDEO equ (0x3 << 3) + TI_GDT + RPL0
    
    gdt_ptr:
    	dw GDT_LIMIT
    	dd GDT_BASE
    
    loader_start:
    ;打开A20地址线
    in al, 0x92          ;南桥芯片内的端口 
    or al, 0x2
    out 0x92, al         ;打开A20
    
    
    ;加载GDTR
    lgdt  [gdt_ptr]
    
    ;使能CR0中的PE位
    mov eax, cr0
    or eax, 0x1
    mov cr0, eax
    
    ;之后，我们需要使用跳转指令来刷新流水线
    jmp SELECTOR_CODE : protectionMode_start
    [bits 32]
    protectionMode_start:
    
    	mov eax, SELECTOR_DATA
    	mov ds, eax
    	mov es, eax
    	mov ss, eax
    	mov esp, LOADER_STACK_TOP
    	mov eax, SELECTOR_VIDEO
    	mov gs, eax
    
    	mov eax, MsgInPE
    	call printString
    
    
    	jmp $
    
    MsgInPE: db 'Now running in protection mode!', 0xA, 0xD, 0
    
    
    
    VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, SELECTOR_VIDEO
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, SELECTOR_VIDEO
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret

## mbr.s ##

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    video_ram_segment   equ  0xB800
    
    mbr_ram_segment equ 0x7C0
    
    LOADER_BASE_ADDR equ 0x500
    
    [bits 16]
    
    ;设置实模式下的堆栈
    segment mbrLoader align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov ds, ax
    	mov sp, 0x7c00
    
    	
    ;关中断
    	cli
    	mov eax, loadLoaderMsg
    	call printString
    	
    	;从LBA扇区1开始读取三个扇区
    	mov esi, 1
    	mov cx, 1
    	mov di, LOADER_BASE_ADDR
    	call readSectorFromDisk_m16
    	
    	mov esi, 2
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16
    	
    	mov esi, 3
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16
    	
    	mov eax, LoaderDoneMsg
    	call printString
    	
    	jmp LOADER_BASE_ADDR
    	jmp $
    	
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, video_ram_segment
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, video_ram_segment
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret	
    	
    readSectorFromDisk_m16:
    	;注意待读取的字节数不要让di寄存器溢出
    	;保护模式下从硬盘读取指定数量的逻辑扇区
    	;esi=起始逻辑扇区号LBA28
    	;ds:di=目标缓冲区地址
    	;cl中存放的是待读取的扇区数
    
    DataRegister equ 0x1F0
    FeatureRegister equ 0x1F1
    SectorRegister equ 0x1F2
    LBAlowRegister equ 0x1F3
    LBAmidRegister equ 0x1F4
    LBAhighRegister equ 0x1F5
    DeviceRegister equ 0x1F6
    CommandRegister equ 0x1F7
    
    ReadCMD	equ 0x20
    WriteCMD	equ 0x30
    IDCMD		equ 0xEC
    
    	push eax
    	push ebx
    	push ecx
    	push edx
    	push edi
    
    	mov eax, esi
    	
    	mov dx, LBAlowRegister
    	out dx, al
    
    	mov dx, LBAmidRegister
    	shr eax, 8
    	out dx, al
    
    	mov dx, LBAhighRegister
    	shr eax, 16
    	out dx, al
    	
    	mov dx, DeviceRegister
    	;LBA28 mode, master disk
    	and ah, 0x0F
    	mov al, 0xe0
    	or al, ah
    	out dx, al
    	
    	mov dx, SectorRegister
    	mov al, cl
    	out dx, al
    	
    	mov dx, CommandRegister 
    	mov al, ReadCMD
    	out dx, al
    	
    .wait4Ready:
    	in al, dx
    	and al, 0x88
    	cmp al, 0x08
    	jnz .wait4Ready
    	
    	;计算待循环的总次数
    	;一个扇区512字节，由于每次读取2个字节，所以一个扇区要读取256次
    	mov ax, 256
    	;如果是8位乘法，结果默认放在AX中
    	;如果是16位乘法，结果高位默认在DX中存放，低位在AX中存放
    	;乘以待读取的扇区数
    	mul cx
    	
    	;由于cl中存储的是待读取的扇区数，所以扇区数不超过255
    	;所以乘积不会超过65536，ax寄存器足以放得下乘积结果
    	mov cx, ax
    
    	mov dx, DataRegister
    .readSectorData:
    	in ax, dx
    	mov word [di], ax
    	add di, 2
    	loop .readSectorData
    
    	pop edi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
    
    	ret
    	
    loadLoaderMsg: db 'Loading loader...', 0xA, 0xD, 0
    LoaderDoneMsg: db 'Now transfer control to loader...', 0xA, 0xD, 0
    
    times 510-($-$$) db 0
    db 0x55,0xaa

# Virtualbox不显示字符串或崩溃，但是bochs正常 #

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]

本来按照正常的IDE控制器逻辑，端口寄存器Sector Count就是用于存放待操作的扇区数。这是一个8位的寄存器，可表示的数值范围是\[0, 255\]，其中0表示256个扇区。  
若要读取3个扇区，则直接将cl中赋值3即可。这在bochs中调试一切正常，但是当切换到Virtualbox上时，发现程序随机出错，有时候无法显示待打印的字符串，有时候Virtualbox直接崩溃，通过调试打印Virtualbox的内存也可以看到，从第2个扇区开始，读出来的字节随机变化。从而可以确定，Virtualbox的IDE硬盘控制器不太支持一次读取超过一个扇区。

因此，将mbr.s中代码改为每次读取1个扇区，接连读取三次，从而在Virtualbox中一切恢复正常。

;从LBA扇区1开始读取三个扇区
    	mov esi, 1
    	mov cx, 1
    	mov di, LOADER_BASE_ADDR
    	call readSectorFromDisk_m16
    	
    	mov esi, 2
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16
    	
    	mov esi, 3
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16

# 编译及烧写步骤 #

## 编译 ##

> $ nasm -f bin mbr.s -o mbr.bin

> $ nasm -f bin loader.s -o loader.bin

由于loader.bin文件比较大，大约有887个字节，超过了一个扇区的大小，故我们在mbr中从LBA第1扇区开始连续加载三个扇区的数据到0x500处。

这里有一个很坑爹的地方，我调试花了一天的时间才定位到。mbr.s代码中的readSectorFromDisk\_m16函数，是用于在实模式下将硬盘指定扇区上的数据加载到内存中，其各个入参说明如下所示：

> ;注意待读取的字节数不要让di寄存器溢出  
> ;保护模式下从硬盘读取指定数量的逻辑扇区  
> ;esi=起始逻辑扇区号LBA28  
> ;ds:di=目标缓冲区地址  
> ;cl中存放的是待读取的扇区数

## 烧写 ##

我们既可以使用我自己写的FixedVhdEditor来烧写两个bin文件到vhd文件，也可以直接使用dd命令来烧些。为简单通用起见，我们使用dd命令来烧些。

> $ dd if=mbr.bin of=…/OSLab.vhd bs=512 count=1 conv=notrunc  
> 1+0 records in  
> 1+0 records out  
> 512 bytes copied, 0.000432864 s, 1.2 MB/s

> $ dd if=loader.bin of=…/OSLab.vhd bs=512 count=20 conv=notrunc seek=1  
> 1+1 records in  
> 1+1 records out  
> 887 bytes copied, 0.000235811 s, 3.8 MB/s

其中，count指定最多写入多少个块，seek指定跳过前面的几个块之后开始写入，conv=notrunc指定写入后不要截断抛掉后面的原数据。

# 实验效果动态图 #

![在这里插入图片描述][20201220163118245.gif_pic_center]

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]: /images/20221120/a0a52cbee98c44f6b136dbc20a23b9f5.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]: /images/20221120/514321cc06884fb4ae116bfc34116c47.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]: https://img-blog.csdnimg.cn/20201216002613109.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]: https://img-blog.csdnimg.cn/20201215223158898.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]: https://img-blog.csdnimg.cn/20201217234409729.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]: https://img-blog.csdnimg.cn/20201217234545178.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]: https://img-blog.csdnimg.cn/20201220163829892.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]: https://img-blog.csdnimg.cn/20201220163628115.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[20201220163118245.gif_pic_center]: https://img-blog.csdnimg.cn/20201220163118245.gif#pic_center