【操作系统真象还原系列】5.获取计算机的物理内存

╰+哭是因爲堅強的太久メ 2022-12-29 14:04 298阅读 0赞

### 目录 ###

*  使用BIOS中断int 0x15获取物理内存容量
 *  子功能号0xE820
 *   *  例程调用方法
     *  有问题的代码
     *   *  进入保护模式后Virtualbox崩溃，但bochs正常
     *  最终实验代码
     *  动态效果图

# 使用BIOS中断int 0x15获取物理内存容量 #

BIOS提供了中断0x15来帮助加载器获取计算机实际的物理内存容量。具体方法是由中断0x15的三个子功能来实现的。子功能号需要放在寄存器EAX、AX或AH中。为简便起见，我们就只介绍功能最强的方法。

在介绍之前，需要强调的是，由于BIOS中断是实模式下的方法，所以只能在实模式下使用，进入保护模式后就无法调用了。

# 子功能号0xE820 #

此子功能用于遍历主机上的全部内存。该方法返回的是内存布局信息，内容比较丰富，在这三种方法中功能最为强大。本方法采用迭代查询，每次BIOS只返回一种类型的内存信息。该内存信息是用地址范围描述符（Address Range Descriptor Structure, ARDS）来描述。该格式的具体格式如下所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]  
我们可以看到，此结构中每个字段都是4个字节，一共5个字段。故此结构大小共计20个字节。每次调用int 0x15之后，BIOS就会返回这样一个数据结构。

每段内存的起始地址和长度都使用8个字节来描述。而Type字段则用来描述这段内存的类型。其Type类型的具体值如下所示：  
![在这里插入图片描述][20201222223315683.jpg_pic_center]  
之所以内存会分类型，是因为这段地址空间可能被映射到系统的ROM、设备内存或者ROM使用到了这段内存。

## 例程调用方法 ##

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]

## 有问题的代码 ##

;在使能保护模式之前，先调用BIOS获取物理内存容量
    ;为编程简单起见，我们先迭代获取所有的ARDS之后，再统一遍历
    ;我们先定义ARDS的缓冲区，每个ARDS大小为20字节，暂定为10个
    ARDS_BUFFER times 200 db 0
    ARDS_COUNT dw 0
    
    totalMemCapacity dd 0
    
    align 32
    
    loader_start:
    	cli
    
    	;第一次调用时，ebx必须为0
    	xor ebx, ebx
    	mov di, ARDS_BUFFER
    	;固定签名标记
    	mov edx, 0x534D4150
    e820_queryMemCapacityLoop:
    	;每次循环都要指定子功能号
    	mov eax, 0xE820
    	;指定ARDS字节大小
    	mov ecx, 20
    	int 0x15
    	jc e820_err
    	;指向用于存储下一个ARDS的缓冲区
    	add di, cx
    	;记录当前已经读取过的ARDS的数量
    	inc word [ARDS_COUNT]
    	cmp ebx, 0
    	jnz e820_queryMemCapacityLoop
    	;此时已成功获取所有ARDS
    	mov ecx, [ARDS_COUNT]
    	mov ebx, ARDS_BUFFER
    	xor edx, edx
    find_max_mem:
    	mov eax, [ebx]
    	add eax, [ebx+8]
    	add ebx, 20
    	cmp edx, eax
    	jge find_next_mem
    	mov edx, eax
    find_next_mem:
    	loop find_max_mem
    	mov [totalMemCapacity], edx
    	jmp enter_protection_mode
    e820_err:
    	mov ax, 0xb800
    	mov es, ax
    	mov byte [es:0x0], 'E'
    	mov byte [es:0x1], 0xF
    	
    	mov byte [es:0x2], 'r'
    	mov byte [es:0x3], 0xF
    	
    	mov byte [es:0x4], 'r'
    	mov byte [es:0x5], 0xF
    	
    	mov byte [es:0x6], 'o'
    	mov byte [es:0x7], 0xF
    	
    	mov byte [es:0x8], 'r'
    	mov byte [es:0x9], 0xF
    	jmp $ 
    
    enter_protection_mode:

### 进入保护模式后Virtualbox崩溃，但bochs正常 ###

![在这里插入图片描述][20201224215151725.gif_pic_center]  
由于我们之前遇到的也是这种情况，不过当时是由硬盘读取函数导致的。现在又出现了该现象。首先我们确认loader.bin从硬盘加载是否正常。因此，我们在loader.s开头处加入死循环，用于打印内存中已加载的loader.bin是否正确。  
首先以调试模式启动Virtualbox，如下所示：

> $ VBoxManage startvm “OSLab” -E VBOX\_GUI\_DBG\_AUTO\_SHOW=true -E VBOX\_GUI\_DBG\_ENABLED=true

> $ VBoxManage controlvm “OSLab” resume

使用VBoxDbg输出VirtualBox内存中的loader.bin镜像，同时使用hexdump输出loader.bin文件内容，对比可以看到loader.bin文件加载无误。之前VirtualBox崩溃的原因可以排除。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]  
在loader.bin文件加载正确的情况下，我们就可以开始使用 jmp $死循环开始调试，用以发现从哪里开始程序还是崩溃。  
以此将jmp $死循环语句向后移动，发现当使能了保护模式之后，程序就崩溃了。  
由此我们第一反应就是没有关中断。因为在保护模式下，我们还没有设置中断描述符表IDT，所以当发生中断时，程序必然崩溃。

但是再一细想，我们在loader.s开头处就已经cli关中断了。应该不是中断没关的原因吧？  
再仔细审阅代码，发现为了获取物理内存的布局数据，我们使用了int 0x15 BIOS中断。会不会是调用0x15 BIOS中断过程中调用了sti使能了中断？  
为此，我们先停在调用int 0x15之前，看一下EFLAGS寄存器中中断是否已被关闭，再在调用之后看一下中断是否被BIOS打开。  
下图是调用BIOS中断之前的EFLAGS寄存器状态：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]

下图是调用BIOS中断之后的EFLAGS寄存器状态：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]  
而x86的EFLAGS寄存器结构如下所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]  
我们看到，进入BIOS之前的EFLAGS为0x00200046，进入BIOS之后的EFLAGS为0x00200246。

而IF开关标志在bit 9处，IF为1表示中断允许，CPU可以响应外部可屏蔽中断。

因此，这意味着在进入BIOS之前，CPU已经关中断，而调用int 0x15返回之后，中断被BIOS打开了。因此在进入保护模式之后，由于还未设置中断描述符表，程序崩溃成为必然。

原因找到，解决方法自然就有了。我们在开启保护模式之前，需要再次关中断。修改后再次烧写运行，一切又恢复了正常。

## 最终实验代码 ##

;mbr.s
    VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    video_ram_segment   equ  0xB800
    
    mbr_ram_segment equ 0x7C0
    
    LOADER_BASE_ADDR equ 0x500
    
    [bits 16]
    
    ;设置实模式下的堆栈
    segment mbrLoader align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov ds, ax
    	mov sp, 0x7c00
    
    	
    ;关中断
    	cli
    	mov eax, loadLoaderMsg
    	call printString
    	
    	;从LBA扇区1开始读取三个扇区
    	mov esi, 1
    	mov cx, 1
    	mov di, LOADER_BASE_ADDR
    	call readSectorFromDisk_m16
    	
    	mov esi, 2
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16
    	
    	mov esi, 3
    	mov cx, 1
    	add di, 512
    	call readSectorFromDisk_m16
    	
    	mov eax, LoaderDoneMsg
    	call printString
    	
    	jmp LOADER_BASE_ADDR
    	jmp $
    	
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, video_ram_segment
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, video_ram_segment
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret	
    	
    readSectorFromDisk_m16:
    	;注意待读取的字节数不要让di寄存器溢出
    	;保护模式下从硬盘读取指定数量的逻辑扇区
    	;esi=起始逻辑扇区号LBA28
    	;ds:di=目标缓冲区地址
    	;cl中存放的是待读取的扇区数
    
    DataRegister equ 0x1F0
    FeatureRegister equ 0x1F1
    SectorRegister equ 0x1F2
    LBAlowRegister equ 0x1F3
    LBAmidRegister equ 0x1F4
    LBAhighRegister equ 0x1F5
    DeviceRegister equ 0x1F6
    CommandRegister equ 0x1F7
    
    ReadCMD	equ 0x20
    WriteCMD	equ 0x30
    IDCMD		equ 0xEC
    
    	push eax
    	push ebx
    	push ecx
    	push edx
    	push edi
    
    	mov eax, esi
    	
    	mov dx, LBAlowRegister
    	out dx, al
    
    	mov dx, LBAmidRegister
    	shr eax, 8
    	out dx, al
    
    	mov dx, LBAhighRegister
    	shr eax, 16
    	out dx, al
    	
    	mov dx, DeviceRegister
    	;LBA28 mode, master disk
    	and ah, 0x0F
    	mov al, 0xe0
    	or al, ah
    	out dx, al
    	
    	mov dx, SectorRegister
    	mov al, cl
    	out dx, al
    	
    	mov dx, CommandRegister 
    	mov al, ReadCMD
    	out dx, al
    	
    .wait4Ready:
    	in al, dx
    	and al, 0x88
    	cmp al, 0x08
    	jnz .wait4Ready
    	
    	;计算待循环的总次数
    	;一个扇区512字节，由于每次读取2个字节，所以一个扇区要读取256次
    	mov ax, 256
    	;如果是8位乘法，结果默认放在AX中
    	;如果是16位乘法，结果高位默认在DX中存放，低位在AX中存放
    	;乘以待读取的扇区数
    	mul cx
    	
    	;由于cl中存储的是待读取的扇区数，所以扇区数不超过255
    	;所以乘积不会超过65536，ax寄存器足以放得下乘积结果
    	mov cx, ax
    
    	mov dx, DataRegister
    .readSectorData:
    	in ax, dx
    	mov word [di], ax
    	add di, 2
    	loop .readSectorData
    
    	pop edi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
    
    	ret
    	
    loadLoaderMsg: db 'Loading loader...', 0xA, 0xD, 0
    LoaderDoneMsg: db 'Now transfer control to loader...', 0xA, 0xD, 0
    
    times 510-($-$$) db 0
    db 0x55,0xaa

;loader.s
    LOADER_BASE_ADDR equ 0x500
    
    ;定义描述符表所用到的宏
    DESC_G_4K equ (0x1 << 23)
    DESC_G_1B equ (0x0 << 23)
    
    ;设置D/B为1，表示是32位
    DESC_D_32 equ (0x1 << 22)
    
    
    ;L位是64位代码段标志，设置为0
    DESC_L equ (0x0 << 21)
    
    
    ;AVL位是用户自定义位，通常由操作系统来使用，这里我们暂设置为0
    DESC_AVL equ (0x0 << 20)
    
    ;设置代码段的限长的最高4位
    DESC_LIMIT_CODE_High4 equ (0xF << 16)
    
    ;设置数据段的限长的最高4位
    DESC_LIMIT_DATA_High4 equ (0xF << 16)
    
    ;用于文本模式的显存地址范围是0xB8000~0xBFFFF，一共32KB(215)大小，故显存段界限为0x7FFF，又由于段粒度为1B，所以段界限长度为0x7FFF，即最高的4位是0
    DESC_LIMIT_VIDEO_High4 equ (0x0 << 16)
    
    
    ;段存在位P用于指示描述符所对应的段是否存在。当P=1时，表示段位于内存中
    DESC_P equ (0x1 << 15)
    
    ;4个特权级
    DESC_DPL_0 equ (0x0 << 13)
    DESC_DPL_1 equ (0x1 << 13)
    DESC_DPL_2 equ (0x2 << 13)
    DESC_DPL_3 equ (0x3 << 13)
    
    ;S位用于表示描述符的类型。当S=0时，表示这是一个系统段；当S=1时，表示这是一个代码段或数据段
    DESC_S_CODE_OR_DATA equ (0x1 << 12)
    DESC_S_SYSTEM equ (0x0 << 12)
    
    ;设置代码段为可执行、不可读、非一致性，访问位清零
    DESC_TYPE_CODE equ (0x8 << 8)
    
    
    ;设置数据段为不可执行、可读可写、向上扩展，访问位清零
    DESC_TYPE_DATA equ (0x2 << 8)
    
    
    ;设置代码段和数据段映射整个4GB地址空间
    DESC_CODE_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_CODE_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_CODE + 0x00
    
    DESC_DATA_HIGH32 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_DATA_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x00
    
    DESC_VIDEO_HIGH32 equ (0x00 << 24) + DESC_G_1B + DESC_D_32 + DESC_L + \
    DESC_AVL + DESC_LIMIT_VIDEO_High4 + DESC_P + DESC_DPL_0 + DESC_S_CODE_OR_DATA + \
    DESC_TYPE_DATA + 0x0B
    
    RPL0 equ (0x0)
    RPL1 equ (0x1)
    RPL2 equ (0x2)
    RPL3 equ (0x3)
    
    TI_GDT equ (0x0 << 2)
    TI_LDT equ (0x1 << 2)
    
    ;loader的入口
    ;构造全局描述符表
    section loader vstart=LOADER_BASE_ADDR
    ;栈底设置在0x7C00处，满减栈
    LOADER_STACK_TOP equ 0x7c00
    jmp loader_start
    
    GDT_BASE:
    	dd 0x0
    	dd 0x0
    CODE_DESC:
    	dd 0xFFFF
    	dd DESC_CODE_HIGH32
    DATA_STACK_DESC:
    	dd 0xFFFF
    	dd DESC_DATA_HIGH32 
    VIDEO_DESC:
    	;我们把显存段基址设置为0xB8000，由于显存范围是0xB8000-0xBFFFF
    	;故显存段的段限长为 0x7FFF
    	dd 0x80007FFF
    	dd DESC_VIDEO_HIGH32 
    
    GDT_SIZE equ $ - GDT_BASE
    GDT_LIMIT equ GDT_SIZE - 1
    ;此处预留60个描述符的空位，以备后续使用
    times 60 dq 0
    
    ;定义三个段描述符选择子
    SELECTOR_CODE equ (0x1 << 3) + TI_GDT + RPL0
    SELECTOR_DATA equ (0x2 << 3) + TI_GDT + RPL0
    SELECTOR_VIDEO equ (0x3 << 3) + TI_GDT + RPL0
    
    gdt_ptr:
    	dw GDT_LIMIT
    	dd GDT_BASE
    
    ;在使能保护模式之前，先调用BIOS获取物理内存容量
    ;为编程简单起见，我们先迭代获取所有的ARDS之后，再统一遍历
    ;我们先定义ARDS的缓冲区，每个ARDS大小为20字节，暂定为10个
    ARDS_BUFFER times 200 db 0
    ARDS_COUNT dw 0
    
    totalMemCapacity dd 0
    
    align 32
    
    loader_start:
    	cli
    
    	;第一次调用时，ebx必须为0
    	xor ebx, ebx
    	mov di, ARDS_BUFFER
    	;固定签名标记
    	mov edx, 0x534D4150
    e820_queryMemCapacityLoop:
    	;每次循环都要指定子功能号
    	mov eax, 0xE820
    	;指定ARDS字节大小
    	mov ecx, 20
    	int 0x15
    	jc e820_err
    	;指向用于存储下一个ARDS的缓冲区
    	add di, cx
    	;记录当前已经读取过的ARDS的数量
    	inc word [ARDS_COUNT]
    	cmp ebx, 0
    	jnz e820_queryMemCapacityLoop
    	;此时已成功获取所有ARDS
    	mov ecx, [ARDS_COUNT]
    	mov ebx, ARDS_BUFFER
    	xor edx, edx
    find_max_mem:
    	mov eax, [ebx]
    	add eax, [ebx+8]
    	add ebx, 20
    	cmp edx, eax
    	jge find_next_mem
    	mov edx, eax
    find_next_mem:
    	loop find_max_mem
    	mov [totalMemCapacity], edx
    	jmp enter_protection_mode
    e820_err:
    	mov ax, 0xb800
    	mov es, ax
    	mov byte [es:0x0], 'E'
    	mov byte [es:0x1], 0xF
    	
    	mov byte [es:0x2], 'r'
    	mov byte [es:0x3], 0xF
    	
    	mov byte [es:0x4], 'r'
    	mov byte [es:0x5], 0xF
    	
    	mov byte [es:0x6], 'o'
    	mov byte [es:0x7], 0xF
    	
    	mov byte [es:0x8], 'r'
    	mov byte [es:0x9], 0xF
    	jmp $ 
    
    enter_protection_mode:
    cli    ;此处关中断至关重要
    
    ;打开A20地址线
    in al, 0x92          ;南桥芯片内的端口 
    or al, 0x2
    out 0x92, al         ;打开A20
    
    ;加载GDTR
    lgdt  [gdt_ptr]
    
    ;使能CR0中的PE位
    mov eax, cr0
    or eax, 0x1
    mov cr0, eax
    
    ;之后，我们需要使用跳转指令来刷新流水线
    jmp SELECTOR_CODE : protectionMode_start
    [bits 32]
    protectionMode_start:
    	mov eax, SELECTOR_DATA
    	mov ds, eax
    	mov es, eax
    	mov ss, eax
    	mov esp, LOADER_STACK_TOP
    	mov eax, SELECTOR_VIDEO
    	mov gs, eax
    
    	mov eax, MsgInPE
    	call printString
    
    	mov eax, totalMemCapacity
    	mov ebx, 4
    	
    	call printByteInHex
    	jmp $
    
    MsgInPE: db 'Now running in protection mode!', 0xA, 0xD, 0
    
    
    
    VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, SELECTOR_VIDEO
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, SELECTOR_VIDEO
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret	
    
    ;ax start address
    ;bx bytes	
    printByteInHex:
    	;对本函数中使用到的寄存器入栈保存
    	push eax
    	push di
    	push cx
    	push es
    	push si
    	push bx
    	push dx
    	
    	;si寄存器用于保存当前待打印的字节所在的地址
    	mov si, ax
    	mov cx, bx
    	;dx寄存器用于计数，每行打印16个字符后换行
    	mov dx, 0
    
    	;初始化显存 段寄存器
    	mov eax, SELECTOR_VIDEO
    	mov es, eax
    
    	;di用于显存的索引
    	xor di, di
    	;begin with another line
    	;add di, 160
    myloop:
    	;取出待打印的当前字节到寄存器al中
    	mov al, [si]
    	inc si
    	;将al字节的高4位放到bl的低4位中
    	mov bl, 0xF0
    	and bl, al
    	shr bl, 4
    	;将高4位对应的数字转换为 数字字符形式
    	add bl, 0x30
    	;如果该数字超过10，则使用A~F来表示
    	cmp bl, 0x3A
    	jl @number0
    	add bl, 7
    @number0:
    	;将转换好的高4位以十六进制字符形式输出到显存上
    	mov [es:di], bl
    	inc di
    	mov byte [es:di], 0x07
    	inc di
    	;按照上述步骤 同样处理本字节的低4位
    	mov bl, 0xF
    	and bl, al
    	add bl, 0x30
    	cmp bl, 0x3A
    	jl @number1
    	add bl, 7
    @number1:
    	mov [es:di], bl
    	inc di
    	mov byte [es:di], 0x07
    	inc di
    	;之后添加空格
    	mov byte [es:di], 0x20
    	inc di
    	mov byte [es:di], 0x07
    	inc di
    	
    	;统计每行已打印的字节数，满16个字节换行
    	inc dx
    	cmp dx, 0x10
    	jne noNewLine
    	;因为文本模式每行可显示80个字符，而 一个字节对应两个十六进制的字符外加一个空格
    	;所以当打印完毕16个字节后，本行已打印的字符数为16*3=48，故本行还剩余的字符数为80-48=32
    	;又由于一个字符对应显存的两个字节位置，所以本行需要的偏移值为32*2=64
    	add di, 64
    	mov dx, 0
    noNewLine:	
    	loop myloop
    
    	;全部字节打印完毕，弹栈
    	pop dx
    	pop bx
    	pop si
    	pop es
    	pop cx
    	pop di
    	pop eax
    	ret

## 动态效果图 ##

![在这里插入图片描述][2020122423121356.gif_pic_center]  
从图上可以看到，我们获取到的内存上限是0x04000000，即226B=26MB=64MB，与虚拟机实际配置的参数相同，如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]  
为再次验证，我们将虚拟机的内存配置为100MB，再次启动虚拟机，如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]

0x640 0000 B = 104,857,600B = (104,857,600/1024)KB = 102400KB=100MB  
故再次验证符合。

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]: /images/20221120/0bfee45b8b434a468ce040386ee6c884.png
[20201222223315683.jpg_pic_center]: https://img-blog.csdnimg.cn/20201222223315683.jpg#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]: https://img-blog.csdnimg.cn/202012222241218.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[20201224215151725.gif_pic_center]: https://img-blog.csdnimg.cn/20201224215151725.gif#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]: https://img-blog.csdnimg.cn/20201224221920378.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]: https://img-blog.csdnimg.cn/20201224225032273.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]: https://img-blog.csdnimg.cn/20201224225418506.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]: https://img-blog.csdnimg.cn/20201224225643889.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[2020122423121356.gif_pic_center]: https://img-blog.csdnimg.cn/2020122423121356.gif#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]: https://img-blog.csdnimg.cn/20201224231710536.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]: https://img-blog.csdnimg.cn/20201224232312860.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center